Subversion Repositories DevTools

@echo off
setlocal
REM Used to setup the buildtool
REM     ABT_HOME    - Where the ABT config files are to be fornd
REM                 - Where the ABT fixed JARs are to be found
REM     ABT_JARS    - Where the buildtool distribution is to be found
REM                 - JAR file will be copied from here
REM     ABT_WORK    - Working directory for the buildtool
REM                 - The CWD of the buildtool execution
REM
REM Used by the buildtool
REM     GBE_ABT                 - Indicates the JATS that it is running an an ABT environment
REM     GBE_LOG                 - Path to the builtool logging directory
REM     GBE_UNC                 - Web server path for error logs
REM     GBE_RM_USERNAME         - Release Manager credentials
REM     GBE_RM_PASSWORD         - Allowing write access to Release Manager
REM     GBE_DPKG_SSH_PROPERTIES - path to ssh properties file holding ssh credentials
REM
REM Internal
REM     JAR                     - Path to the buildtool jar
REM
set ABT_HOME=D:\work\buildtool
set ABT_JARS=V:\dpkg_archive\buildtool\latest\etc
set ABT_WORK=F:\abt
set GBE_ABT=1
set GBE_LOG=V:\abtlog
set GBE_UNC=http://auperaarc01/devl/abtlog
set GBE_RM_USERNAME=build_user
set GBE_RM_PASSWORD=frog123
set GBE_DPKG_SSH_PROPERTIES=%GBE_DPKG%\.dpkg_archive\fragments.properties

set JAR=%ABT_HOME%\abtdD.jar

if "%GBE_RM_LOCATION%" == "" (
    echo Error: Program abtlaunch.bat
    echo Error: EnvVar GBE_RM_LOCATION not set
    echo Error: Run in a jats shell eg jats eprog abtlaunch
    exit /B 1
)

if "%JAVA_HOME_1_6%" == "" (
    echo Error: Program abtlaunch.bat
    echo Error: EnvVar JAVA_HOME_1_6 not set
    echo Error: Run in a jats shell eg jats eprog abtlaunch
    exit /B 1
)

if not exist "%JAVA_HOME_1_6%\bin\java.exe" (
    echo Error: Program abtlaunch.bat
    echo Error: The java program does not exist
    echo Error: Location: "%JAVA_HOME_1_6%\bin\java"
    exit /B 1
)

if not exist "%ABT_JARS%" (
    echo Error: Program abtlaunch.bat
    echo Error: %ABT_JARS% does not exist
    exit /B 1
)

if not exist "%ABT_HOME%" (
    echo Error: Program abtlaunch.bat
    echo Error: %ABT_HOME% does not exist
    exit /B 1
)

if not exist "%ABT_WORK%" (
    echo Error: Program abtlaunch.bat
    echo Error: The ABT work directory does not exist
    echo Error: Dir: %ABT_WORK%
    exit /B 1
)

REM
REM Copy in the latest JARS
REM
echo Copy in JAR files
copy %ABT_JARS%\*.jar %ABT_HOME%
if ERRORLEVEL 1 (
    echo Error: Program abtlaunch.bat
    echo Error: Error occured copying latest builtool executables
    exit /B 1
)

if not exist "%JAR%" (
    echo Error: Program abtlaunch.bat
    echo Error: Required Jar does not exist: %JAR%
    exit /B 1
)

set PATH=%ABT_HOME%;%PATH%
rem change drive and folder
cd /D %ABT_WORK%
echo %DATE% %TIME% AbtLaunch. Start jar
"%JAVA_HOME_1_6%\bin\java" -jar %JAR%
echo %DATE% %TIME% AbtLaunch. End jar

endlocal