WebSVN – DevTools – /ManagerSuite/Release_Manager/trunk/web/wAddSchedule.asp

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|                    wAddSchedule
'|                                                   |
'=====================================================
%>
<%
Option explicit
Response.Expires = 0
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/_form_window_common.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_general.asp"-->
<!--#include file="_access_control_login.asp"-->
<%
'------------ VARIABLE DEFINITION -------------
Dim rsQry
Dim rsTemp
Dim sMessage
Dim Query_String
'------------ CONSTANTS DECLARATION -----------
'------------ VARIABLE INIT -------------------
sMessage = NULL

Set objFormCollector = CreateObject("Scripting.Dictionary")
'------------ CONDITIONS ----------------------
'----------------------------------------------
%>
<%
'--------------------------------------------------------------------------------------------------------------------------
Function GetMachType ( ngbe_id )
    Dim rsQry, query
    
    OraDatabase.Parameters.Add "gbe_id",   ngbe_id, ORAPARM_INPUT, ORATYPE_NUMBER 
    
    query = GetQuery ("GBE_MACHTYPECombo.sql")
    
    Set rsQry = OraDatabase.DbCreateDynaset( query, ORADYN_DEFAULT )
    If (NOT rsQry.BOF) AND (NOT rsQry.EOF) Then
        GetMachType = rsQry.GetRows()
    Else
        GetMachType = NULL
        
    End If
    
    rsQry.Close()
    Set rsQry = Nothing
    
    OraDatabase.Parameters.Remove "gbe_id"
End Function
'--------------------------------------------------------------------------------------------------------------------------
Sub RenderRepeatCombo( cRepeat )
    Response.Write "<select name='repeat_combo' class='form_item'>" 
    Response.write "<option value='0'>Once Only</option>"
    Response.write "<option value='1'>Daily</option>"
    Response.write "<option value='7'>Weekly</option>"
    Response.Write "</select>"  
End Sub
'--------------------------------------------------------------------------------------------------------------------------
%>
<%
'------------ RUN BEFORE PAGE RENDER ----------
If CBool(Request("action")) Then

    If Len(Request("repeat_combo")) > 1 Then
    
        Call DisplayInfo ( "REPEAT_SCHEDULE_NOT_SELECTED", "100%" )
    
    Else
        On Error Resume Next
        OraDatabase.Parameters.Add "SCHEDULED_PAUSE",   Request("scheduled_pause"),     ORAPARM_INPUT, ORATYPE_VARCHAR2
        OraDatabase.Parameters.Add "SCHEDULED_RESUME",  Request("scheduled_resume"),    ORAPARM_INPUT, ORATYPE_VARCHAR2
        OraDatabase.Parameters.Add "REPEAT",            Request("repeat_combo"),        ORAPARM_INPUT, ORATYPE_CHAR
        OraDatabase.Parameters.Add "INDEFINITE_PAUSE",  Request("indefinite_pause"),    ORAPARM_INPUT, ORATYPE_CHAR
        
        objEH.TryORA ( OraSession )
        
        OraDatabase.ExecuteSQL _
           "BEGIN PK_BUILDAPI.Insert_Schedule_Info ( " &_
                "TO_DATE(:SCHEDULED_PAUSE,'DD-MM-YYYY HH24:MI:SS'), " &_
                "TO_DATE(:SCHEDULED_RESUME,'DD-MM-YYYY HH24:MI:SS'), " &_
                ":REPEAT, " &_
                ":INDEFINITE_PAUSE );" &_
            "END;"
        
        objEH.CatchORA ( OraSession )

        OraDatabase.Parameters.Remove "SCHEDULED_PAUSE"
        OraDatabase.Parameters.Remove "SCHEDULED_RESUME"
        OraDatabase.Parameters.Remove "REPEAT"
        OraDatabase.Parameters.Remove "INDEFINITE_PAUSE"

        If objEH.Finally Then
            Call OpenInParentWindow ("admin_build_service.asp")
            Call CloseWindow()
        End If

        rsQry.Close()
        Set rsQry = nothing
    End If
        
End If


'----------------------------------------------
%>
<html>
    <head>
        <title>Release Manager</title>
        <link rel="shortcut icon" href="<%=FavIcon%>"/>
        <meta http-equiv="Pragma" content="no-cache">
        <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
        <link href="images/release_manager_style.css" rel="stylesheet" type="text/css">
        <script language="JavaScript" src="scripts/common.js"></script>
        <script language="JavaScript" src="images/ts_picker.js"></script>
    </head>
    <body background="images/bg_bage_0.gif" leftmargin="0" topmargin="0" onload="self.focus();">
        <table width="100%" border="0" cellspacing="0" cellpadding="10">
            <%
            '-- FROM START --------------------------------------------------------------------------------------------------------------
            objFormComponent.FormName = "run_level_schedule"
            objFormComponent.FormClass = "form_tight"
            objFormComponent.Action = ScriptName
            objFormComponent.OnSubmit = "ShowProgress();"
            Call objFormComponent.FormStart()
            %>
            <tr>
                <td>
                    <!-- NEW SCHEDULE ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++  -->
                    <%Call Messenger ( sMessage , 3, "100%" )%>
                    <!-- MESSAGE +++++++++++++++++++++++++++++++++++++++++++++++++++ -->
                    <!--#include file="messages/_msg_inline.asp"-->
                    <br>
                    <table width="50%" border="0">
                        <tr>
                            <td nowrap class="form_iname">SCHEDULED PAUSE</td>
                            <td class="form_item"><%=objFormComponent.TextBox ("scheduled_pause", "", "size='20' class='form_ivalue'" )%></td>
                            <td class="form_item" width="1">
                                <a href="javascript:show_calendar('document.run_level_schedule.scheduled_pause', document.run_level_schedule.scheduled_pause.value);">
                                    <img src="images/cal.gif" width="16" height="16" border="0" alt="Click here to select the time to pause">
                                </a>
                            </td>
                        </tr>
                        <tr>
                            <td nowrap class="form_iname">SCHEDULED RESUME</td>
                            <td class="form_item"><%=objFormComponent.TextBox ("scheduled_resume", "", "size='20' class='form_ivalue'" )%></td>
                            <td class="form_item">
                                <a href="javascript:show_calendar('document.run_level_schedule.scheduled_resume', document.run_level_schedule.scheduled_resume.value);">
                                    <img src="images/cal.gif" width="16" height="16" border="0" alt="Click Here to select the time to resume">
                                </a>
                            </td>
                        </tr>
                        <tr>
                            <td nowrap class="form_iname">REPEAT SCHEDULED DOWNTIME</td>
                            <td colspan="2"><% Call RenderRepeatCombo("")%></td>
                        </tr>
                    </table>
                </td>
            </tr>
            <%=objPMod.ComposeHiddenTags()%>
            <input type="hidden" name="action" value="true">
            <%
            Call objFormComponent.FormEnd()
            '-- FROM END ----------------------------------------------------------------------------------------------------------------
            %>
            <tr>
                <td background="images/bg_login.gif">
                    <table width="100%" border="0" cellspacing="0" cellpadding="0">
                        <tr>
                            <td><%=ProgressBar()%></td>
                            <td align="right">
                                <input name="btn" type="submit" class="form_btn" value="Add">
                                <input name="btn" type="reset" class="form_btn" value="Cancel" onclick="parent.closeIFrame();"></td>
                        </tr>
                    </table>
                </td>
            </tr>
        </table>
    </body>
</html>
<%
'------------ RUN AFTER PAGE RENDER -----------
Set objFormCollector = Nothing
'----------------------------------------------
Call Destroy_All_Objects
%>
Subversion Repositories DevTools

(root)/ManagerSuite/Release_Manager/trunk/web/wAddSchedule.asp – Rev 5590
