Subversion Repositories DevTools

Rev

Rev 5506 | Rev 6676 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | RSS feed 

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|                   wAddLicence                     |
'|                                                   |
'=====================================================
%>
<%
Option explicit
Response.Expires = 0
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/_form_window_common.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_general.asp"-->
<!--#include file="_access_control_login.asp"-->
<%
'------------ VARIABLE DEFINITION -------------
Dim rsQry
Dim sMessage
Dim LICENCE_NAME
Dim Query_String
Dim dual
Dim LICENCE_ID
Dim Query_Stringx
'------------ CONSTANTS DECLARATION -----------
'------------ VARIABLE INIT -------------------
sMessage = NULL
Set objFormCollector = CreateObject("Scripting.Dictionary")
'------------ CONDITIONS ----------------------
'----------------------------------------------
'------------ RUN BEFORE PAGE RENDER ----------

If CBool(Request("action")) Then

   If Request("LICENCE_NAME") = "" Then

      sMessage = "Cannot add an empty string as a licence name"

   Else
      Query_String = _
      "   SELECT * FROM licences WHERE UPPER(name) = UPPER('"& Request("LICENCE_NAME") &"')"

      Set rsQry = OraDatabase.DbCreateDynaset( Query_String, cint(0))

      If rsQry.RecordCount = 0 Then

         Query_Stringx = _
            "SELECT seq_gbe_id.NEXTVAL FROM DUAL"

         Set dual = OraDatabase.DbCreateDynaset(Query_Stringx,cint(0))
         LICENCE_ID = dual("NEXTVAL")
         dual.Close()
         Set dual = Nothing

         OraDatabase.Parameters.Add "LICENCE", LICENCE_ID, ORAPARM_INPUT, ORATYPE_NUMBER
         OraDatabase.Parameters.Add "NAME",    Request("LICENCE_NAME"),   ORAPARM_INPUT, ORATYPE_VARCHAR2

         objEH.ErrorRedirect = FALSE
         objEH.TryORA ( OraSession )
         On Error Resume Next
         OraDatabase.ExecuteSQL ("begin INSERT INTO licences (licence, name) VALUES (:LICENCE, :NAME); end;")
         objEH.CatchORA ( OraSession )

         OraDatabase.Parameters.Remove "LICENCE"
         OraDatabase.Parameters.Remove "NAME"

         If objEH.Finally Then
            Call OpenInParentWindow ("admin_licences.asp")
            Call CloseWindow()
         End If

      Else
         sMessage = "Licence already exists"
      End If

      rsQry.Close
      Set rsQry = nothing
   End If

End If
'----------------------------------------------
%>
<html>
<head>
<title>Release Manager</title>
<link rel="shortcut icon" href="<%=FavIcon%>"/>
<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link href="images/release_manager_style.css" rel="stylesheet" type="text/css">
<script language="JavaScript" src="scripts/common.js"></script>
</head>
<body leftmargin="0" topmargin="0" onLoad="self.focus();FormName.LICENCE_NAME.focus();">
<table width="100%"  border="0" cellspacing="0" cellpadding="10">
   <tr>
      <td class="body_txt">
         Add a new licence.
      </td>
   </tr>
   <%
   '-- FROM START --------------------------------------------------------------------------------------------------------------
   objFormComponent.FormName = "FormName"
   objFormComponent.FormClass = "form_tight"
   objFormComponent.Action = ScriptName
   objFormComponent.OnSubmit = "ShowProgress();"
   Call objFormComponent.FormStart()
   %>
   <tr>
      <td class="form_field_bg" >
         <!-- NEW PRODUCT ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
         <%Call Messenger ( sMessage , 3, "100%" )%>
         <!-- MESSAGE +++++++++++++++++++++++++++++++++++++++++++++++++++ -->
         <!--#include file="messages/_msg_inline.asp"-->
         <table width="70%" border="0">
            <tr>
               <td><span class="body_txt nowrap">Licence Name</span></td>
               <td><input name="LICENCE_NAME" type="text" class="body_txt" value="<%=LICENCE_NAME%>" size=70 maxlength=50></td>
            </tr>
         </table>
      </td>
   </tr>
   <tr>
      <td>
         <table class="full_table">
            <tr>
               <td><%=ProgressBar()%></td>
               <td align="right">
                    <input name="btn" type="submit" class="form_btn" value="Add">
                    <input name="btn" type="reset" class="form_btn" value="Cancel" onclick="parent.closeIFrame();">
               </td>
            </tr>
         </table>
      </td>
   </tr>
   <%=objPMod.ComposeHiddenTags()%>
   <input type="hidden" name="action" value="true">
   <%
   Call objFormComponent.FormEnd()
   '-- FROM END ----------------------------------------------------------------------------------------------------------------
   %>
</table>
</body>
</html>
<%
'------------ RUN AFTER PAGE RENDER -----------
Set objFormCollector = Nothing
'----------------------------------------------
Call Destroy_All_Objects
%>