Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|                   wAddBuildStandard               |
'|                                                   |
'=====================================================
%>
<%
Option explicit
Response.Expires = 0
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/_popup_window_common.asp"-->
<!--#include file="common/_form_window_common.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_general.asp"-->
<!--#include file="_access_control_login.asp"-->
<%
'------------ VARIABLE DEFINITION -------------
Dim rsQry
Dim sMessage
Dim GBE_BS
Dim GBE_BSA_NAME
Dim Query_String
'------------ CONSTANTS DECLARATION -----------
'------------ VARIABLE INIT -------------------
sMessage = NULL
Set objFormCollector = CreateObject("Scripting.Dictionary")
'------------ CONDITIONS ----------------------
'----------------------------------------------
%>
<%
' Populate a form selection with Build Standards
'   sbm_id - Select this bm_id
sub getBuildStandardOptions( sbs_id )
    Dim rsQry
    Dim bs_id, bs_name, selected

    Response.write("<option value="""">- Select One -</option>")
    Set rsQry = OraDatabase.DbCreateDynaset( "SELECT * FROM BUILD_STANDARDS ORDER BY BS_NAME", ORADYN_DEFAULT )
    While (NOT rsQry.BOF) AND (NOT rsQry.EOF)
        bs_id = rsQry("BS_ID")
        bs_name = rsQry("BS_NAME")
        If bs_id = sbs_id Then
            selected = " selected"
        Else
            selected = ""
        End If
        %>
          <option value="<%=bs_id%>"<%=selected%>><%=bs_name%></option>
        <%
        rsQry.MoveNext()
    Wend
    rsQry.Close()
end sub
%>
<%
'------------ RUN BEFORE PAGE RENDER ----------


If CBool(Request("action")) Then

   ' Update an existing entry
   If Request("bsa_id") <> "" Then

      Query_String = _
      "   SELECT * FROM BUILD_STANDARDS_ADDENDUM WHERE BSA_ID <> " & Request("bsa_id") & " AND UPPER(BSA_NAME) = UPPER('"& Request("GBE_BSA_NAME") &"')"

      Set rsQry = OraDatabase.DbCreateDynaset( Query_String, cint(0))

      If rsQry.RecordCount = 0 Then

         OraDatabase.Parameters.Add "BSA_ID",       Request("bsa_id"),       ORAPARM_INPUT, ORATYPE_NUMBER
         OraDatabase.Parameters.Add "BSA_NAME",     Request("GBE_BSA_NAME"), ORAPARM_INPUT, ORATYPE_VARCHAR2
         OraDatabase.Parameters.Add "BS_ID",        Request("GBE_BS"),       ORAPARM_INPUT, ORATYPE_NUMBER

         objEH.ErrorRedirect = FALSE
         objEH.TryORA ( OraSession )
         On Error Resume Next

         OraDatabase.ExecuteSQL _
         "BEGIN  UPDATE BUILD_STANDARDS_ADDENDUM SET BSA_NAME = :BSA_NAME, BS_ID = :BS_ID WHERE BSA_ID = :BSA_ID;  END;"

         objEH.CatchORA ( OraSession )

         OraDatabase.Parameters.Remove "BSA_ID"
         OraDatabase.Parameters.Remove "BSA_NAME"
         OraDatabase.Parameters.Remove "BS_ID"

         If objEH.Finally Then
            Call OpenInParentWindow ("admin_gbe_buildstandard.asp")
            Call CloseWindow()
         End If

      Else
         sMessage = "A Build Standard Addendum of that name already exists"
      End If

      rsQry.Close
      Set rsQry = nothing

   Else

      ' Create a new entry
      '
      Query_String = _
      "   SELECT * FROM BUILD_STANDARDS_ADDENDUM WHERE UPPER(BSA_NAME) = UPPER('"& Request("GBE_BSA_NAME") &"')"

      Set rsQry = OraDatabase.DbCreateDynaset( Query_String, cint(0))

      If rsQry.RecordCount = 0 Then

         OraDatabase.Parameters.Add "BSA_NAME",     Request("GBE_BSA_NAME"), ORAPARM_INPUT, ORATYPE_VARCHAR2
         OraDatabase.Parameters.Add "BS_ID",        Request("GBE_BS"),       ORAPARM_INPUT, ORATYPE_NUMBER

         objEH.ErrorRedirect = FALSE
         objEH.TryORA ( OraSession )
         On Error Resume Next

         OraDatabase.ExecuteSQL _
         "BEGIN  INSERT INTO BUILD_STANDARDS_ADDENDUM (BSA_NAME, BS_ID) VALUES( :BSA_NAME, :BS_ID);  END;"

         objEH.CatchORA ( OraSession )

         OraDatabase.Parameters.Remove "BSA_NAME"
         OraDatabase.Parameters.Remove "BS_ID"

         If objEH.Finally Then
            Call OpenInParentWindow ("admin_gbe_buildstandard.asp")
            Call CloseWindow()
         End If

      Else
         sMessage = "A Build Standard Addendum of that name already exists"
      End If

      rsQry.Close
      Set rsQry = nothing

   End If

End If


'----------------------------------------------
%>
<html>
<head>
<title>Release Manager</title>
<link rel="shortcut icon" href="<%=FavIcon%>"/>
<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link href="images/release_manager_style.css?ver=<%=VixVerNum%>" rel="stylesheet" type="text/css">
<script language="JavaScript" src="images/common.js?ver=<%=VixVerNum%>"></script>
</head>

<body leftmargin="0" topmargin="0" onLoad="self.focus();FormName.GBE_BSA_NAME.focus();">
<div id='divProgressBar' class='vixSpinner' style='visibility:hidden;'></div>
<table width="100%"  border="0" cellspacing="0" cellpadding="10">
   <tr>
      <td class="body_txt">
         Add a new Build Standard or edit an existing Build Standard.
      </td>
   </tr>
   <%
   '-- FROM START --------------------------------------------------------------------------------------------------------------
   objFormComponent.FormName = "FormName"
   objFormComponent.FormClass = "form_tight"
   objFormComponent.Action = ScriptName
   objFormComponent.OnSubmit = "MM_validateForm(""GBE_BSA_NAME"",""Build Standard Addendum"",""RLength4:"",""GBE_BS"",""Build Standard"",""R"");return document.MM_returnValue"
   Call objFormComponent.FormStart()

   %>
   <tr>
      <td class="form_field_bg" >
         <!-- LOCAL MESSAGES ++++++++++++++++++++++++++++++++++++++++++++ -->
         <%Call Messenger ( sMessage , 3, "100%" )%>
         <!-- MESSAGE +++++++++++++++++++++++++++++++++++++++++++++++++++ -->
         <!--#include file="messages/_msg_inline.asp"-->

         <table width="50%" border="0">
            <%
            GBE_BS = Request("GBE_BS")
            GBE_BSA_NAME = Request("GBE_BSA_NAME")
            
            If Request("bsa_id") <> "" Then
               %>
               <input type="hidden" name="bsa_id" value="<%=Request("bsa_id")%>">
               <%

               Dim rsTemp

               Query_String = "SELECT * FROM BUILD_STANDARDS BS, BUILD_STANDARDS_ADDENDUM BSA WHERE BSA.BS_ID=BS.BS_ID(+) AND BSA_ID = " & Request("bsa_id")

               Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

               GBE_BS = rsTemp("BS_ID")
               GBE_BSA_NAME = rsTemp("BSA_NAME")

               rsTemp.Close()
               Set rsTemp = Nothing
            End   If
            %>
            <tr>
               <td><span class="body_txt nowrap">Build Standard</span></td>
               <td>
                    <select id="FRbs"  name="GBE_BS" class="form_item">
                    <%getBuildStandardOptions(GBE_BS)%>
                    </select>
               </td>
            </tr>

            <tr>
               <td><span class="body_txt">Addendum</span></td>
               <td><input name="GBE_BSA_NAME" type="text" class="body_txt" value="<%=GBE_BSA_NAME%>"></td>
            </tr>
            </tr>
         </table>
      </td>
   </tr>
   <tr>
        <td align="right">
                <input name="btn" type="submit" class="form_btn" value="Add/Update">
                <input name="btn" type="reset" class="form_btn" value="Cancel" onclick="parent.closeIFrame();">
        </td>
   </tr>
   <%=objPMod.ComposeHiddenTags()%>
   <input type="hidden" name="action" value="true">
   <%
   Call objFormComponent.FormEnd()
   '-- FROM END ----------------------------------------------------------------------------------------------------------------
   %>
</table>
</body>
</html>
<%
'------------ RUN AFTER PAGE RENDER -----------
Set objFormCollector = Nothing
'----------------------------------------------
Call Destroy_All_Objects
%>