Subversion Repositories DevTools

<%
'=============================================================
'//
'//                                             noteManager
'//
'// version:            1.0.1
'//     last modified:  08-Sep-2004 by Matthew Brown
'=============================================================
%>
<%
'------------------------------------------------------------------------------------------------------------------
Function Get_Package_Note ()
        Get_Package_Note = _
        "   SELECT description, last_user, last_date "&_
        "         FROM note_manager note"&_
        "        WHERE note.nid = :NOTE_ID"
End Function
'------------------------------------------------------------------------------------------------------------------

'------------------------------------------------------------------------------------------------------------------
Sub drawNote(nPv_id, nRtag_id, redirectionDestination, last_user, visiblePageArray) 
        Dim noteContents, lastUser, lastDate, rsNote
        
        noteContents = ""
        
        OraDatabase.Parameters.Add "NOTE_ID",   nPv_id, ORAPARM_INPUT, ORATYPE_VARCHAR2
        Set rsNote = OraDatabase.DbCreateDynaset( Get_Package_Note (), cint(0))
        If rsNote.RecordCount = 1 Then
                noteContents = rsNote("description")
                lastUser = rsNote("last_user")
                lastDate = rsNote("last_date")
        Else
        End If
        OraDatabase.Parameters.remove "NOTE_ID"
        rsNote.close
        set     rsNote = nothing
        

        Response.write "<script type='text/javascript' src='notemanager/scripts/stickynotes.js'></script>"
        Response.write "<LINK href='notemanager/styles/stickynotes.css' rel='stylesheet' type='text/css'>"
        Response.write "<DIV id='notebox'>"
        Response.write "<table class='noteboxhead' width='100%' bgcolor='#DAD7C8'>"
        Response.write "<tr height='30'>"
        Response.write "<td align='left' valign='center'>"
        Response.write "<a href='#' onClick='saveNote();return false'><img src='notemanager/images/save.gif'></a>"
        Response.write "<img src='images/spacer.gif' height='1' width='10'>"
        Response.write "<a href='#' onClick='saveBlankNote();return false'><img src='notemanager/images/delete.gif'></a>"
        Response.write "</td>"
        Response.write "<td align='right' valign='top'>"
        Response.write "<span class='help_ttl'><b>note</b>manager</span><a href='#' onClick='showHideNote();return false'><img src='notemanager/images/close.gif'></a>"
        Response.write "</td>"
        Response.write "</tr>"
        Response.write "</table>"
        If (Request("saved") = "true") Then
                Response.write "<span class='pass_alert'><center>Note Saved</center></span>"
        ElseIf (Request("saved") = "false") Then
                Response.write "<span class='err_alert'><center>Note Not Saved</center></span>"
        Else 
                Response.write "<span class='err_alert'><center>&nbsp;</center></span>"
        End If
        Response.write "<center><span class='noteboxbody'>"
        Response.write "<FORM name='noteManagerForm' method='GET' action='notemanager/save_note.asp'>"
        Response.write "<input type='hidden' value='"& redirectionDestination &"' name='redirectionDestination'>"
        Response.write "<input type='hidden' value='"& last_user &"' name='last_user'>"
        Response.write "<input type='hidden' value='"& nPv_id &"' name='pv_id'>"
        Response.write "<input type='hidden' value='"& nRtag_id &"' name='rtag_id'>"
        Response.write "<textarea name='description' id='noteboxcontents' cols='32' rows='12'>"
        If not noteContents = "" Then
                Response.write Server.HTMLEncode(noteContents)
        End If
        Response.write "</textarea>"
        Response.write "</span></center>"
        Response.write "</FORM>"
        If not isnull(noteContents) Then
                Response.write "<span class='rep_small' align='right'>&nbsp;&nbsp;"& lastUser &" - "& lastDate &"</span>"
        End If
        Response.write "</DIV>"

        If (not noteContents = "") and ((inArray(scriptName, visiblePageArray)) or (Request("saved") = "true")) Then
                Response.write "<script language='Javascript'>noteVisibility='visible'</script>"
        Else 
                Response.write "<script language='Javascript'>noteVisibility='hidden'</script>"
        End If

End Sub
'------------------------------------------------------------------------------------------------------------------

Dim allowedPageArray, visiblePageArray

allowedPageArray = array("dependencies.asp", "fixed_issues.asp", "runtime_dependencies.asp", "used_by.asp", "build_order.asp", "patches.asp", "documentation.asp", "action_log.asp")
visiblePageArray = array("dependencies.asp")

If inArray(scriptName, allowedPageArray) Then
        Dim redirectionTarget, last_user
        
        last_user = NULL
        If objAccessControl.UserLogedIn Then last_user = objAccessControl.UserName
        
        redirectionTarget = scriptName & "?rtag_id="& Request("rtag_id") &"&pv_id="& Request("pv_id")
        Call drawnote(Request("pv_id"), Request("rtag_id"), redirectionTarget, last_user, visiblePageArray)
End If

%>