Subversion Repositories DevTools

Rev

Rev 7395 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | RSS feed 

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|                  Edit Release                     |
'|                                                   |
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0   ' always load the page, dont store
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/_form_window_common.asp"-->
<%
' Set rfile parameter. This is a return page after Login
Call objPMod.StoreParameter ( "rfile", "rtree.asp" )
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_login_optional.asp"-->
<!--#include file="_access_control_general.asp"-->
<!--#include file="_access_control_project.asp"-->
<%
'------------ Variable Definition -------------
Dim rsQry
Dim ctrlDisabled, bCanEdit
Dim returnUrl

'------------ Constants Declaration -----------
'------------ Variable Init -------------------
If canActionControlInProject("CreateNewRelease") or canActionControlInProject("ConfigureRelease") Then
   ctrlDisabled = ""
   bCanEdit = TRUE
Else
   ctrlDisabled = "disabled"
   bCanEdit = FALSE
End If

' Maintain the page to goto after we process this one
'   Go back from whence we came
' Grab the referre on the first call so that postback does not confuse us
returnUrl = Request("returnUrl")
If returnUrl = "" Then
    returnUrl = Request.ServerVariables ("HTTP_REFERER")

    ' It MUST have an rtag id
    If InStr(returnUrl,"rtag_id") = 0 Then
        Dim joiner : joiner = "?"
        If InStr(returnUrl,"?") <> 0 Then joiner = "&"
        returnUrl = returnUrl & joiner & "rtag_id=" & Request("rtag_id")
    End If
End If

'----------------------------------------------
%>
<%
'--------------------------------------------------------------------------------------------------------------------------
' Clean up a check box value to True or False
Function CheckBoxValue( val )
    If IsNull(val) Then
        CheckBoxValue = FALSE
    ElseIf Ucase(val) = "Y" Then
        CheckBoxValue = TRUE
    ElseIf Ucase(val) = "ON" Then
        CheckBoxValue = TRUE
    Else
        CheckBoxValue = FALSE
    End If
End Function
'--------------------------------------------------------------------------------------------------------------------------
Sub GetFormDetails ( nRtagId, ByRef outobjDetails )
   Dim rsQry, query

   OraDatabase.Parameters.Add "RTAG_ID",  nRtagId,    ORAPARM_INPUT, ORATYPE_NUMBER

   query = _
   " SELECT rt.* "&_
   " FROM   RELEASE_TAGS rt"&_
   " WHERE  rt.RTAG_ID = :RTAG_ID"

   Set rsQry = OraDatabase.DbCreateDynaset( query, ORADYN_DEFAULT )

   OraDatabase.Parameters.Remove "RTAG_ID"

   If rsQry.RecordCount > 0 Then
      outobjDetails.Item ("rtag_id") = rsQry("rtag_id")
      outobjDetails.Item ("proj_id") = rsQry("proj_id")
      outobjDetails.Item ("rtag_name") = rsQry("rtag_name")
      outobjDetails.Item ("description") = rsQry("description")
      outobjDetails.Item ("parent_rtag_id") = rsQry("parent_rtag_id")
      outobjDetails.Item ("config_spec_branch") = rsQry("config_spec_branch")
      outobjDetails.Item ("owner_email") = rsQry("owner_email")
      outobjDetails.Item ("product_state_used") = rsQry("product_state_used")
      outobjDetails.Item ("build_age") = rsQry("build_age")
      outobjDetails.Item ("lxr") = rsQry("lxr")
      outobjDetails.Item ("s3sync") = rsQry("s3sync")
      If rsQry("assoc_mass_ref") <> "" Then
      outobjDetails.Item ("massref_rtag_id") = rsQry("assoc_mass_ref")
      End If
   Else
      Err.Raise 8, "Sub GetFormDetails in "& ScriptName, "Empty record set returned. nRtagId="& nRtagId

   End If

   rsQry.Close
   Set rsQry = Nothing
End Sub
'--------------------------------------------------------------------------------------------------------------------------
Sub UpdateReleaseDetails ()

   Dim State    : State    = Iif(CheckBoxValue(request("product_state_used")),"Y",NULL)
   Dim lxrState : lxrState = Iif(CheckBoxValue(request("lxr")),"Y","N")
   Dim s3State  : s3State = Iif(CheckBoxValue(request("s3sync")),"Y","N")
   Dim bAge     : bAge = Request("build_age")
   If NiceInt(bAge,0) = 0 Then bAge = NULL  

   OraDatabase.Parameters.Add "RTAG_ID",            Request("rtag_id"),   ORAPARM_INPUT, ORATYPE_NUMBER
   OraDatabase.Parameters.Add "RTAG_NAME",          Trim(Request("rtag_name")),      ORAPARM_INPUT, ORATYPE_VARCHAR2
   OraDatabase.Parameters.Add "RTAG_DESCRIPTION",   Trim(Request("rtag_description")), ORAPARM_INPUT, ORATYPE_VARCHAR2
   OraDatabase.Parameters.Add "CONFIG_SPEC_BRANCH", Trim(Request("config_spec_branch")), ORAPARM_INPUT, ORATYPE_VARCHAR2
   OraDatabase.Parameters.Add "OWNER_EMAIL",        Trim(Request("owner_email")),    ORAPARM_INPUT, ORATYPE_VARCHAR2
   OraDatabase.Parameters.Add "USER_ID",            objAccessControl.UserId,   ORAPARM_INPUT, ORATYPE_NUMBER
   OraDatabase.Parameters.Add "PARENT_RTAG_ID",     Request("parent_rtag_id"),    ORAPARM_INPUT, ORATYPE_NUMBER
   OraDatabase.Parameters.Add "MASSREF_RTAG_ID",    Request("massref_rtag_id"),   ORAPARM_INPUT, ORATYPE_NUMBER
   OraDatabase.Parameters.Add "STATE",              State,   ORAPARM_INPUT, ORATYPE_VARCHAR
   OraDatabase.Parameters.Add "BUILD_AGE",          bAge,   ORAPARM_INPUT, ORATYPE_NUMBER
   OraDatabase.Parameters.Add "LXR",                lxrState,   ORAPARM_INPUT, ORATYPE_CHAR
   OraDatabase.Parameters.Add "S3SYNC",             s3State,   ORAPARM_INPUT, ORATYPE_CHAR

   objEH.ErrorRedirect = FALSE
   On Error Resume Next
   objEH.TryORA ( OraSession )

   OraDatabase.ExecuteSQL _
   "BEGIN   PK_RELEASE.UPDATE_RELEASE ( " &_
               " :RTAG_ID, " &_
               " :RTAG_NAME," &_
               " :RTAG_DESCRIPTION," &_
               " :PARENT_RTAG_ID," &_
               " :MASSREF_RTAG_ID," &_
               " :CONFIG_SPEC_BRANCH," &_
               " :OWNER_EMAIL," &_
               " :USER_ID," &_
               " :STATE," &_
               " :BUILD_AGE," &_
               " :LXR," &_
               " :S3SYNC" &_
   "); END;"

   objEH.CatchORA ( OraSession )

   OraDatabase.Parameters.Remove "RTAG_ID"
   OraDatabase.Parameters.Remove "RTAG_NAME"
   OraDatabase.Parameters.Remove "RTAG_DESCRIPTION"
   OraDatabase.Parameters.Remove "CONFIG_SPEC_BRANCH"
   OraDatabase.Parameters.Remove "OWNER_EMAIL"
   OraDatabase.Parameters.Remove "USER_ID"
   OraDatabase.Parameters.Remove "PARENT_RTAG_ID"
   OraDatabase.Parameters.Remove "MASSREF_RTAG_ID"
   OraDatabase.Parameters.Remove "STATE"
   OraDatabase.Parameters.Remove "BUILD_AGE"
   OraDatabase.Parameters.Remove "LXR"
   OraDatabase.Parameters.Remove "S3SYNC"

End Sub
'--------------------------------------------------------------------------------------------------------------------------
%>
<%
'------------ RUN BEFORE PAGE RENDER ----------
' --- Get Form details from DB ---
Call GetFormDetails ( Request("rtag_id"), objFormCollector )

' --- Load Validation Rules ---
objForm.UpdateRules ("id='rtag_name' IsRequired='Y' IsName='Y' MinStringLength='2' MaxStringLength='150'")
objForm.UpdateRules ("id='rtag_description' IsRequired='Y' MaxStringLength='4000' MinStringLength='10'")
objForm.UpdateRules ("id='config_spec_branch' IsRequired='N' IsName='Y' MaxStringLength='4000' MinStringLength='10'")
objForm.UpdateRules ("id='build_age' IsRequired='N' IsNumeric='Y' MinNumericValue='0' MaxNumericValue='365'")

' --- Enter Form Validation Rule Changes here... ----
'----------------------------------------------------

' --- RUN onPostBack ---
If Request("action") <> "" Then
   If objForm.IsValidOnPostBack Then
      ' --- Form is Valid ---
      If bCanEdit Then
         Call UpdateReleaseDetails()
         If objEH.Finally Then
            Call OpenInWindow ( returnUrl )
         End If
      Else
         Call OpenInWindow ( returnUrl )
      End If
   End If
End If

'----------------------------------------------
%>

<html>
<head>
<title>Release Manager</title>
<link rel="shortcut icon" href="<%=FavIcon%>"/>
<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link rel="stylesheet" href="images/release_manager_style.css?ver=<%=VixVerNum%>" type="text/css">
<link rel="stylesheet" href="images/navigation.css?ver=<%=VixVerNum%>" type="text/css">
<script language="JavaScript" src="images/common.js?ver=<%=VixVerNum%>"></script>
<!-- DROPDOWN MENUS -->
<!--#include file="_jquery_includes.asp"-->
<!--#include file="_menu_def.asp"-->
<script language="JavaScript1.2" src="images/popup_menu.js?ver=<%=VixVerNum%>"></script>

</head>
<body bgcolor="#FFFFFF" text="#000000" leftmargin="0" topmargin="0" onLoad="FormName.rtag_name.focus();">
<!-- HEADER -->
<!--#include file="_header.asp"-->
<!-- BODY ---->

<table width="100%" border="0" cellspacing="0" cellpadding="0">
   <%
   '-- FROM START ---------------------------------------------------------------------------------------------------------
   objFormComponent.FormName = "FormName"
   objFormComponent.Action = ScriptName
   If NOT bCanEdit Then
      objFormComponent.IsReadonlyAction = enumDB_YES
   End If
   Call objFormComponent.FormStart()
   %>
   <tr>
      <td class='bg_panel'></td>
      <td width="100%" rowspan="2" align="center" valign="top" bgcolor="#EEEFEF">
         <table width="10" border="0" cellspacing="0" cellpadding="0">
            <tr>
               <td width="1%"></td>
               <td width="100%">
                  <table width="100%" border="0" cellspacing="0" cellpadding="0">
                     <tr>
                        <%If bCanEdit Then%>
                           <td nowrap class="form_ttl">EDIT RELEASE DETAILS </td>
                        <%Else%>
                           <td nowrap class="form_ttl">VIEW RELEASE DETAILS </td>
                        <%End If%>
                        <td align="right" valign="bottom"></td>
                     </tr>
                  </table>
               </td>
               <td width="1%"></td>
            </tr>
            <tr>
               <td align="left" valign="top" background="images/lbox_bg_blue.gif"><img src="images/lbox_tl_cnr_b.gif" width="13" height="13"></td>
               <td background="images/lbox_bg_blue.gif" class="lbox_ttl_w"><img src="images/h_trsp_dot.gif" width="600" height="15"></td>
               <td align="right" valign="top"  background="images/lbox_bg_blue.gif"><img src="images/lbox_tr_cnr_b.gif" width="13" height="13"></td>
            </tr>
            <tr>
               <td bgcolor="#FFFFFF"><img src="images/h_trsp_dot.gif" width="10" height="100"></td>
               <td bgcolor="#FFFFFF" valign="top">
                  <!-- MESSAGE +++++++++++++++++++++++++++++++++++++++++++++++++++ -->
                  <!--#include file="messages/_msg_inline.asp"-->
                  <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
                  <br>
                  <table width="100%"  border="0" cellspacing="2" cellpadding="0">
                     <tr>
                        <td valign="top" nowrap class="form_iname">Release Name </td>
                        <td valign="top" nowrap>
                           <%=objFormComponent.TextBox ( "rtag_name", objForm.GetValue( "rtag_name", objFormCollector.Item("rtag_name") ), "class='form_ivalue' size='60'" )%>
                        </td>
                        <td valign="top"><%=objForm.Validate ("rtag_name")%></td>
                     </tr>
                     <tr>
                        <td nowrap class="form_iname" valign="top">Parent Release </td>
                        <td valign="top" nowrap class="form_iname">
                           <%
                           OraDatabase.Parameters.Add "PROJ_ID", objFormCollector.Item("proj_id"),    ORAPARM_INPUT, ORATYPE_NUMBER
                           OraDatabase.Parameters.Add "USER_ID",  objAccessControl.UserId,  ORAPARM_INPUT, ORATYPE_NUMBER

                           Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("ReleaseVersionTree.sql") , ORADYN_DEFAULT )

                           OraDatabase.Parameters.Remove "USER_ID"
                           OraDatabase.Parameters.Remove "PROJ_ID"
                           %>
                           <select name="parent_rtag_id" class="form_item" <%=ctrlDisabled%>>
                              <option value="<%=objFormCollector.Item("rtag_id")%>">---ROOT---</option>
                              <%While (NOT rsQry.BOF) AND (NOT rsQry.EOF)%>
                                    <option value="<%=rsQry("rtag_id")%>" <%If ( cLng( rsQry("rtag_id") ) = cLng(objFormCollector.Item("parent_rtag_id")) ) Then%>selected<%End If%>><%=rsQry("rtag_name")%></option>
                                 <%
                                 rsQry.MoveNext
                              WEnd%>
                           </select>
                        </td>
                        <td valign="top"></td>
                     </tr>
                     <tr>
                        <td valign="top" nowrap class="form_iname">Comments</td>
                        <td valign="top"><%=objFormComponent.TextArea ( "rtag_description", objForm.GetValue( "rtag_description", objFormCollector.Item("description") ), 10, 60, "class='form_ivalue'" )%></td>
                        <td valign="top"><%=objForm.Validate ("rtag_description")%></td>
                     </tr>
                     <tr>
                        <td valign="top" nowrap class="form_iname">Clearcase Support Profile Branch</td>

                        <td valign="top" nowrap><%=objFormComponent.TextBox ( "config_spec_branch", objForm.GetValue( "config_spec_branch", objFormCollector.Item("config_spec_branch") ), "class='form_ivalue' size='60'" )%></td>
                        <td valign="top"><%=objForm.Validate ("config_spec_branch")%></td>
                     </tr>
                     <tr>
                        <td valign="top" nowrap class="form_iname">Autobuild Notification Emails</td>

                        <td valign="top" nowrap><%=objFormComponent.TextBox ( "owner_email", objForm.GetValue( "owner_email", objFormCollector.Item("owner_email") ), "class='form_ivalue' size='60'" )%></td>
                        <td valign="top"></td>
                     </tr>
                     <tr>
                        <%If objFormCollector.Item("proj_id") <> 2 Then%>
                           <td nowrap class="form_iname" valign="top">Associated MASS REF </td>
                           <td valign="top" nowrap class="form_iname">
                              <%
                              OraDatabase.Parameters.Add "PROJ_ID", 2,   ORAPARM_INPUT, ORATYPE_NUMBER
                              OraDatabase.Parameters.Add "USER_ID",  objAccessControl.UserId,  ORAPARM_INPUT, ORATYPE_NUMBER

                              Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("ReleaseVersionTree.sql") , ORADYN_DEFAULT )

                              OraDatabase.Parameters.Remove "USER_ID"
                              OraDatabase.Parameters.Remove "PROJ_ID"
                              %>
                              <select name="massref_rtag_id" class="form_item" disabled <%=ctrlDisabled%>>
                                 <option value="">---None---</option>
                                 <%While (NOT rsQry.BOF) AND (NOT rsQry.EOF)%>
                                    <option value="<%=rsQry("rtag_id")%>" 
                                        <%If ( cLng( rsQry("rtag_id") ) = cLng(objFormCollector.Item("massref_rtag_id")) ) Then%>
                                            selected
                                        <%End If%>
                                        >
                                        <%=rsQry("rtag_name")%>
                                    </option>
                                    <%
                                    rsQry.MoveNext
                                 WEnd%>
                              </select> [No longer supported]
                           </td>
                           <td valign="top"></td>
                        <%End If%>
                     </tr>
                     <tr>
                        <td valign="top" nowrap class="form_iname">Configured To Use Product States</td>
                        <td valign="top"><input type="checkbox" name="product_state_used" <%=iif(CheckBoxValue(objForm.GetValue( "product_state_used", objFormCollector.Item("product_state_used") )), "checked ","")%><%=ctrlDisabled%>></td>
                        <td valign="top"></td>
                     </tr>

                     <tr>
                        <td valign="top" nowrap class="form_iname">Build Age before warning</td>

                        <td valign="top" nowrap>
                            <%=objFormComponent.TextBox ( "build_age", objForm.GetValue( "build_age", objFormCollector.Item("build_age") ), "class='form_ivalue' size='5'" )%></td>
                        <td valign="top"><%=objForm.Validate ("build_age")%></td>

                     </tr>

                     <tr>
                        <td valign="top" nowrap class="form_iname">LXR Support</td>

                        <td valign="top" nowrap>
                            <input type="checkbox" name="lxr"  <%=iif(CheckBoxValue(objForm.GetValue( "lxr", objFormCollector.Item("lxr") )), "checked ","")%><%=ctrlDisabled%> >
                        </td>
                        <td valign="top"></td>

                     </tr>

                                         <tr>
                        <td valign="top" nowrap class="form_iname">Sync to S3</td>

                        <td valign="top" nowrap>
                            <input type="checkbox" name="s3sync"  <%=iif(CheckBoxValue(objForm.GetValue( "s3sync", objFormCollector.Item("s3sync") )), "checked ","")%><%=ctrlDisabled%> >
                        </td>
                        <td valign="top"></td>

                     </tr>

                     <tr>
                        <td class="form_iname">&nbsp;</td>
                        <td>&nbsp;</td>
                        <td class="val_err"></td>
                     </tr>
                  </table>
               </td>
               <td background="images/lbox_bgside_white.gif">&nbsp;</td>
            </tr>

            <tr>
               <td class='bg_dialog'></td>
               <td align="right" class='bg_dialog' >
                  <%If bCanEdit Then%>
                     <%=objFormComponent.SubmitButton ( "Submit", "class='form_btn'" )%>&nbsp;
                  <%End If%>
                  <%=objFormComponent.CancelButton ( "Cancel", "class='form_btn'", returnUrl )%>
                  <%=objPMod.ComposeHiddenTags()%>
                  <input type="hidden" name="returnUrl" value="<%=returnUrl%>">
                  <input type="hidden" name="action" value="true">
               </td>
               <td class='bg_dialog'><img src="images/h_trsp_dot.gif" width="5" height="30"></td>
            </tr>
            <tr>
               <td background="images/lbox_bg_blue.gif" valign="bottom"><img src="images/lbox_bl_cnr_b.gif" width="13" height="13"></td>
               <td background="images/lbox_bg_blue.gif"></td>
               <td background="images/lbox_bg_blue.gif" valign="bottom" align="right"><img src="images/lbox_br_cnr_b.gif" width="13" height="13"></td>
            </tr>
         </table>

         <!-- ACTION BUTTONS ---------------------------------------------->
         <!-- ACTION BUTTONS END  ------------------------------------------>
      </td>
      <td width="1" valign="top"><img src="images/h_trsp_dot.gif" width="1" height="1"></td>
   </tr>
   <tr>
      <td class='bg_panel_btm'><img src="images/img_vtree.gif" width="86" height="99" vspace="20" hspace="30"></td>
      <td background="images/bg_lght_gray.gif" valign="top"><img src="images/h_trsp_dot.gif" width="1" height="500"></td>
   </tr>
   <%
   Call objFormComponent.FormEnd()
   '-- FROM END ----------------------------------------------------------------------------------------------------------------
   %>
</table>
<!-- FOOTER -->
<!--#include file="_footer.asp"-->
</body>
</html>