Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'   build_replication_status.asp
'
'   Display the replication configuration
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0  ' always load the page, dont store
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/_form_window_common.asp"-->
<!--#include file="common/common_daemon.asp"-->
<% '------------ ACCESS CONTROL ------------------ %>
<!--#include file="_access_control_login_optional.asp"-->
<!--#include file="_access_control_general.asp"-->
<%
'------------ Variable Definition -------------
Dim rsQry
'------------ RUN BEFORE PAGE RENDER ----------
'------------------------------------------------------------------------------
Sub SidePanelContent
%>
<%
End Sub
'------------------------------------------------------------------------------
Sub ShowMainPanel
%>
<table width="10" class="embedded_table" style="margin-bottom:10px">
  <tr>
    <td>
        <table class="rounded_box rounded_box_std embedded_table" width="100%" >
            <caption>Package Replication Summary</caption>
          <tr>
             <td>
            <!-- MESSAGE +++++++++++++++++++++++++++++++++++++++++++++++++++ -->
            <!--#include file="messages/_msg_inline.asp"-->
            <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
            <table width="100%" border="0" cellspacing="1" cellpadding="1" class=stdGrey>
               <thead>
                      <!-- Status Table Header -->
                      <th>Target</th>
                      <th>Enabled</th>
                      <th>Mode</th>
                      <th>Project</th>
                      <th>Release</th>
               </thead>

               <!-- Status Table Body -->
                <%
                Set rsQry = OraDatabase.DbCreateDynaset( GetQuery("ReplicaStatus.sql"), cint(0))
                Dim showWarn, showWarnText, hasProjectReplication
                While ((NOT rsQry.BOF) AND (NOT rsQry.EOF))
                    %><tr class="body_rowg2"><%

                    Dim enabledControl
                    enabledControl = "<input type='checkbox' disabled "& IIF(rsQry("ENABLED") =  "Y", "checked","")  &" >"
                    Select Case rsQry("etype")
                        ' Server entry
                        Case 0 
                            Dim replicationMode 
                            If rsQry("BLAT_MODE") = "P" Then
                                replicationMode = "All Projects"
                                showWarn = true
                                showWarnText = "Covered by replication of All Projects"
                            ElseIf rsQry("BLAT_MODE") = "E" Then
                                replicationMode = "Entire Archive"
                                showWarnText = "Covered by replication of Entie Archive"
                                showWarn = true
                            Else
                                replicationMode = "Normal"
                                showWarn = false
                            End If
                            hasProjectReplication = false
                        %>
                            <td class="body_row" nowrap><a href=admin_blat_machines.asp?server_id=<%=rsQry("blat_id")%>><%=rsQry("blat_display_name")%></a></td>
                            <td><%=enabledControl%></td>
                            <td class="body_row" nowrap colspan=3><%=replicationMode%></td>
                        <%

                        ' No longer used
                        Case 1%>
                            <td></td>
                            <td><%=enabledControl%></td>
                            <td class="body_row" nowrap colspan=3>Full Archive Replication</td>
                        <%

                        ' Project Entry
                        Case 2
                            hasProjectReplication = true
                            %>
                            <td></td>
                            <td><%=enabledControl%></td>
                            <td class="body_row" nowrap>Project
                                <%If showWarn Then%>
                                    <img src='images/s_warning.gif' width='14' height='13' border='0' title='<%=showWarnText%>' style='vertical-align: bottom;'>
                                <%End If%>    
                            </td>
                            <td class="body_row" nowrap><a href=form_project_replication.asp?proj_id=<%=rsQry("PROJ_ID")%>><%=rsQry("PROJ_NAME")%></a></td>
                            <td class="body_row" nowrap></td>
                        <%
                        ' Release Entry - has xref to containing project
                        Case 3
                            Dim noReplicaTxt : noReplicaTxt = ""
                            If rsQry("OFFICIAL") = "A" Then
                                noReplicaTxt = "Release is in a state that will not be replicated"
                            End If
                            %>
                            <td></td>
                            <td><%=enabledControl%></td>
                            <td class="body_row" nowrap>Release
                                <%If showWarn Then%>
                                    <img src='images/s_warning.gif' width='14' height='13' border='0' title='<%=showWarnText%>' style='vertical-align: bottom;'>
                                <%End If%>    
                                <%If noReplicaTxt <> "" Then%>
                                    <img src='images/s_warning.gif' width='14' height='13' border='0' title='<%=noReplicaTxt%>' style='vertical-align: bottom;'>
                                <%End If%>
                                <%If hasProjectReplication Then%>
                                    <img src='images/s_warning.gif' width='14' height='13' border='0' title='Covered by Project Replication' style='vertical-align: bottom;'>
                                <%End If%>
                            </td>
                            <td class="body_row" nowrap><a href=form_project_replication.asp?proj_id=<%=rsQry("PROJ_ID")%>><%=rsQry("PROJ_NAME")%></a></td>
                            <td class="body_row" nowrap><%=ReleaseIcon(rsQry("OFFICIAL"))%>
                            <a href=form_release_replication.asp?rtag_id=<%=rsQry("RTAG_ID")%>><%=rsQry("RTAG_NAME")%></a></td>
                        <%

                    End Select
                    %></tr><%
                    rsQry.MoveNext
                WEnd
                rsQry.Close
                Set rsQry = Nothing
                %>
            </table>
             </td>
           </tr>
        </table>
      </td>
  </tr>
</table>
<%
End Sub
%>
<html>
   <head>
      <title>Release Manager</title>
      <link rel="shortcut icon" href="<%=FavIcon%>"/>
      <meta http-equiv="Pragma" content="no-cache">
      <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
      <link rel="stylesheet" href="images/release_manager_style.css?ver=<%=VixVerNum%>" type="text/css">
      <link rel="stylesheet" href="images/navigation.css?ver=<%=VixVerNum%>" type="text/css">
      <script language="JavaScript" src="images/common.js?ver=<%=VixVerNum%>"></script>
      <!--#include file="_jquery_includes.asp"-->
      <!-- DROPDOWN MENUS -->
      <!--#include file="_menu_def.asp"-->
      <script language="JavaScript1.2" src="images/popup_menu.js?ver=<%=VixVerNum%>"></script>
   </head>
   <body bgcolor="#FFFFFF" text="#000000" leftmargin="0" topmargin="0">
      <!-- HEADER -->
      <!--#include file="_header.asp"-->
      <!-- BODY ---->
      <table class="full_table">
         <tr>
            <td width="146px" class="panel_bg" valign="top">
                <%Call SidePanelContent%>
            </td>
            <td width="100%" rowspan="2" align="center" valign="top" bgcolor="#EEEFEF">
                <%Call ShowMainPanel%>
            </td>
         </tr>
         <tr>
            <td class="panel_bg" valign="bottom" align="center" height="350">
                <img src="images/img_gears.png" vspace="20" hspace="30"></td>
         </tr>
      </table>
      <!-- FOOTER -->
      <!--#include file="_footer.asp"-->
   </body>
</html>