Subversion Repositories DevTools

Rev

Rev 6579 | Blame | Compare with Previous | Last modification | View Log | RSS feed 

<%@LANGUAGE="VBSCRIPT"%>
<%
Option explicit
Response.Expires = 0   ' always load the page, dont store
%>
<%
'=====================================================
'               Change Owner
'=====================================================
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/common_dbedit.asp"-->
<!--#include file="common/_popup_window_common.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_login.asp"-->
<!--#include file="_access_control_general.asp"-->
<!--#include file="_access_control_project.asp"-->
<%
'------------ Variable Definition -------------
Dim parPv_id
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
Set pkgInfoHash = CreateObject("Scripting.Dictionary")
parPv_id = QStrPar("pv_id")
'----------------------------------------------
%>
<%
Sub Get_Pkg_Info_With_Owner ( NNpv_id )
   Dim rsTemp, Query_String

   Query_String = _
   " SELECT pkg.pkg_name, pv.pkg_version, pv.owner_id"&_
   "   FROM packages pkg, package_versions pv"&_
   "  WHERE pkg.pkg_id = pv.pkg_id"&_
   "    AND pv.pv_id = "& NNpv_id

   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

   If ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF)) Then
      pkgInfoHash.Add "pkg_name", (rsTemp.Fields("pkg_name"))
      pkgInfoHash.Add "pkg_version", (rsTemp.Fields("pkg_version"))
      pkgInfoHash.Add "owner_id", (rsTemp.Fields("owner_id"))
   End If

   rsTemp.Close
   Set rsTemp = nothing
End Sub


Function Users_List ( )
   Users_List = _
   " SELECT usr.user_id, usr.full_name"&_
    "   FROM users usr"&_
   "  WHERE usr.IS_DISABLED IS NULL"&_
   "  ORDER BY UPPER(usr.full_name)"
End Function

Sub Update_Owner ( NNpv_id, NNown_id )
   Dim rsTemp, Query_String, sComments, previousOwner
   Dim objWSH, sPackage


   '-- Get package details
   Query_String = _
   " SELECT pv.owner_id, pv.dlocked, pkg.pkg_name, pv.pkg_version"&_
   " FROM package_versions pv, packages pkg"&_
   " WHERE pv.pv_id = "& NNpv_id &_
   "   AND pv.pkg_id = pkg.pkg_id" &_
   "   AND pv.owner_id != " & NNown_id

   Set rsTemp = OraDatabase.CreateDynaset( Query_String, cint(0))
   If rsTemp.RecordCount <> 0 Then
       previousOwner = rsTemp.Fields("owner_id").Value

       sPackage = rsTemp("pkg_name") &" "& rsTemp("pkg_version")

       '-- Update database to change the owner
       objEH.TryORA ( OraSession )
       On Error Resume Next

       OraDatabase.ExecuteSQL _
          " UPDATE PACKAGE_VERSIONS pv SET "&_
          " pv.owner_id = "& NNown_id &_
          " WHERE pv.pv_id = "& NNpv_id

       objEH.CatchORA ( OraSession )

       If objEH.LastOraFailed = FALSE Then
          '-- Notify new owner
          Call Send_Email ( "Release Manager Notification", ADMIN_EMAIL, GetUserEmail( NNown_id ), "You are now the owner of """& sPackage &"""", Empty, NULL )

          '-- Log the change
          sComments = "Changed from "& GetUsername(previousOwner) &" to "& GetUsername(NNown_id)
          call Log_Action ( NNpv_id, "owner_change", sComments )
       End If
   End If

   rsTemp.Close
   Set rsTemp = nothing
End Sub
%>
<%
'Process submition
If CBool(QStrPar("action")) AND objAccessControl.UserLogedIn Then
   Call Update_Owner ( parPv_id, Request("own_id") )
   Call ReloadParentWindow
   Call CloseWindow
End If
%>
<%
Call Get_Pkg_Info_With_Owner ( parPv_id )
%>
<html>
<head>
<title>Release Manager</title>
<link rel="shortcut icon" href="<%=FavIcon%>"/>
<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link rel="stylesheet" href="images/release_manager_style.css?ver=<%=VixVerNum%>" type="text/css">
<link rel="stylesheet" href="images/navigation.css?ver=<%=VixVerNum%>" type="text/css">
<script language="JavaScript" src="images/tipster.js?ver=<%=VixVerNum%>"></script>
<script language="JavaScript" src="images/_help_tips.js?ver=<%=VixVerNum%>"></script>
<script language="JavaScript" src="images/common.js?ver=<%=VixVerNum%>"></script>
</head>
<body bgcolor="#FFFFFF" text="#000000" leftmargin="0" topmargin="0" onload="self.focus();">
<form name="chowner" method="post" action="<%=scriptName%>" class="form_tight">
  <table border="0" cellspacing="0" cellpadding="2" width="100%">
    <tr>
      <td valign="top" nowrap colspan="3" class="wform_ttl" background="images/bg_form_lightgray.gif">
        <table width="100%" border="0" cellspacing="1" cellpadding="2">
          <tr>
            <td width="1%" nowrap class="form_field" background="images/bg_form_lightbluedark.gif">Package</td>
            <td nowrap width="100%" background="images/bg_form_lightbluedark.gif" class="form_txt">
              <%=pkgInfoHash.Item ("pkg_name") &" "& pkgInfoHash.Item ("pkg_version")%></td>
          </tr>
          <tr>
            <td width="1%" nowrap class="form_field" background="images/bg_form_lightbluedark.gif">Owner</td>
            <td nowrap width="100%" background="images/bg_form_lightbluedark.gif">
         <select name="own_id" class="form_item">
<%
         Dim rsUsers
         Set rsUsers = OraDatabase.DbCreateDynaset( Users_List( ), cint(0))
         While ((NOT rsUsers.BOF) AND (NOT rsUsers.EOF))%>
                <option <%If CInt(rsUsers("user_id")) = CInt(pkgInfoHash.Item("owner_id")) Then%>selected<%End If%> value="<%=rsUsers.Fields("user_id")%>"><%=rsUsers.Fields("full_name")%></option>
<%            rsUsers.MoveNext
         WEnd
         rsUsers.Close
         set rsUsers = nothing
         %>
         </select>
            <input type="hidden" name="pv_id" value="<%=parPv_id%>">
         <input type="hidden" name="rtag_id" value="<%=parRtag_id%>">
         <input type="hidden" name="action" value="true">
            </td>
          </tr>
        </table>
      </td>
    </tr>
    <tr>
      <td align="right">
        <input type="submit" name="btn" value="Update" class="form_btn_comp">
        <input type="reset" name="btn" value="Cancel" class="form_btn_comp" onclick="parent.closeIFrame();">
      </td>
    </tr>
  </table>
</form>
</body>
</html>
<!-- DESTRUCTOR ------->
<!--#include file="common/destructor.asp"-->