Subversion Repositories DevTools

Rev

Rev 6876 | Rev 7249 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | RSS feed 

<%
'=====================================================
'                                       Dependency Changes
'=====================================================
%>
<%
'------------ Variable Definition -------------
Dim parFileDiff
Dim parComparePvId
Dim parFileFilter
Dim dFileFilter
Dim parDepFilter
Dim dDepFilter
Dim preVerText
'------------ Constants Declaration -----------
Const LIMG_UPDATED = "<img src='images/i_updated.gif' width='11' height='11' border='0' hspace='2' align='absmiddle' title='Updated'>"
Const LIMG_ADDED = "<img src='images/i_added.gif' width='11' height='11' border='0' hspace='2' align='absmiddle' title='Added'>"
Const LIMG_REMOVED = "<img src='images/i_removed.gif' width='11' height='11' border='0' hspace='2' align='absmiddle' title='Removed'>"
Const LIMG_FILTER_ON = "<img src='images/i_data_table.gif' border='0' align='absmiddle' hspace='0' title='Filter in use.'>"
Const LIMG_FILTER_OFF = "<img src='images/i_data_table_off.gif' border='0' align='absmiddle' hspace='0' title='Filter not in use.'>"
Const LIMG_NEW_WINDOW = "<img src='images/i_new_window.gif' width='16' height='16' hspace='3' border='0' align='absmiddle' >"
Const LIMG_DROP_DOWN_ARROW = "<img src='images/i_drop_down_arrow.gif' width='5' height='15' hspace='1' border='0' align='absmiddle'>"
'------------ Variable Init -------------------
parFileDiff = Request("filediff")
parComparePvId = Request("compare_pv_id")
parFileFilter = Request("filefilter")
parDepFilter = Request("depfilter")
'----------------------------------------------
Set dDepFilter = CreateObject("Scripting.Dictionary")
Set dFileFilter = CreateObject("Scripting.Dictionary")

' Define version to compare
If parComparePvId = "" Then
        If NOT IsNull( pkgInfoHash.Item("last_pv_id") )  OR  pkgInfoHash.Item("last_pv_id") <> "" Then 
                parComparePvId = pkgInfoHash.Item("last_pv_id")
        Else
                parComparePvId = 0
        End If
End If
'-----------------------------------------------------------------------------------------------------------------
Sub GetFileFilterValues ( outFileFilter )
        Dim FilterVal, aFilterValues
        
        If Request.Cookies(enum_RELMGR_COOKIE_DOMAIN)(COOKIE_HIDE_FILES_FILTER) <> "" Then
                
                aFilterValues = Split( Replace( Request.Cookies(enum_RELMGR_COOKIE_DOMAIN)(COOKIE_HIDE_FILES_FILTER), " ", ""), ",") 
                
                For Each FilterVal In aFilterValues
                        
                        outFileFilter.Item (CStr( FilterVal )) = ""
                        
                Next
                
        End If
        
End Sub
'-----------------------------------------------------------------------------------------------------------------
Sub GetDepFilterValues ( outDepFilter )
        Dim FilterVal, aFilterValues
        
        If Request.Cookies(enum_RELMGR_COOKIE_DOMAIN)(COOKIE_HIDE_DEPS_FILTER) <> "" Then
                
                aFilterValues = Split( Replace( Request.Cookies(enum_RELMGR_COOKIE_DOMAIN)(COOKIE_HIDE_DEPS_FILTER), " ", ""), ",") 
                
                For Each FilterVal In aFilterValues
                        
                        outDepFilter.Item (CStr( FilterVal )) = ""
                        
                Next
                
        End If
        
End Sub
'-----------------------------------------------------------------------------------------------------------------
Function GetIsDepFilterInUseIcon()
        GetIsDepFilterInUseIcon = LIMG_FILTER_OFF & LIMG_DROP_DOWN_ARROW
        
        If dDepFilter.Count > 0 Then
                GetIsDepFilterInUseIcon = LIMG_FILTER_ON & LIMG_DROP_DOWN_ARROW
        End If
        
End Function
'-----------------------------------------------------------------------------------------------------------------
Function GetIsFileFilterInUseIcon()
        GetIsFileFilterInUseIcon = LIMG_FILTER_OFF & LIMG_DROP_DOWN_ARROW
        
        If dFileFilter.Count > 0 Then
                GetIsFileFilterInUseIcon = LIMG_FILTER_ON & LIMG_DROP_DOWN_ARROW
        End If
        
End Function
'-----------------------------------------------------------------------------------------------------------------
Function GetIsFileFilterChecked( nFilterId )
        
        If dFileFilter.Exists ( CStr(nFilterId)  ) Then
                GetIsFileFilterChecked = "checked"
        End If
        
End Function
'-----------------------------------------------------------------------------------------------------------------
Function GetIsDepFilterChecked( nFilterId )
        
        If dDepFilter.Exists ( CStr(nFilterId)  ) Then
                GetIsDepFilterChecked = "checked"
        End If
        
End Function
'-----------------------------------------------------------------------------------------------------------------
Sub RowStyle ( sStatus, ByRef outIcon, ByRef outStyle, ByRef outText )
        
        Select Case CInt(sStatus)
                Case enumDB_NUM_DIFF_NO_CHANGE
                        outStyle = "body_rowg"
                        outIcon = NULL
            outText = "No Change"
                        
                Case enumDB_NUM_DIFF_UPDATED
                        outStyle = "body_rowbold"
                        outIcon = LIMG_UPDATED
            outText = "Changed"
                        
                Case enumDB_NUM_DIFF_NEW
                        outStyle = "body_rowbold"
                        outIcon = LIMG_ADDED
            outText = "Added"
                        
                Case enumDB_NUM_DIFF_REMOVED
                        outStyle = "body_rowthru"
                        outIcon = LIMG_REMOVED
            outText = "Removed"
                        
        End Select
        
End Sub
'-----------------------------------------------------------------------------------------------------------------
Sub DisplayComparePvIdCombo()
        Dim rsQry, isOfficial
        
        
        OraDatabase.Parameters.Add "COMPARE_PV_ID", parComparePvId,     ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "PKG_ID",            pkgInfoHash.Item("pkg_id"),     ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "V_EXT",             EmptyToNull(pkgInfoHash.Item("v_ext")), ORAPARM_INPUT, ORATYPE_VARCHAR2 
        
        Set rsQry = OraDatabase.DbCreateDynaset( GetQuery("AllPackageVersions.sql"), cint(0))
        
        Response.write "<option value=''></option>"
        
    While ((NOT rsQry.BOF) AND (NOT rsQry.EOF))
                
                If rsQry("dlocked") = "Y" Then
                        isOfficial = "R&nbsp;"
                Else
                        isOfficial = "&nbsp;&nbsp;&nbsp;&nbsp;"
                End If

        If rsQry("selected") <> "" Then
            preVerText = rsQry("pkg_version") 
        End If
                
                Response.write "<option value='"& rsQry("pv_id") &"' "& rsQry("selected") &" >"& isOfficial & rsQry("pkg_version") &"</option>"& VBNewLine
                
                rsQry.MoveNext
    WEnd
        
        ' Clean up
        rsQry.Close()
        Set rsQry = nothing
        
        OraDatabase.Parameters.Remove "COMPARE_PV_ID"
        OraDatabase.Parameters.Remove "PKG_ID"
        OraDatabase.Parameters.Remove "V_EXT"
        
End Sub
'-----------------------------------------------------------------------------------------------------------------
Sub DisplayCompareReleasePvIdCombo()
        Dim rsQry, isOfficial
        
        
        OraDatabase.Parameters.Add "COMPARE_PV_ID", parComparePvId,     ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "PKG_ID",            pkgInfoHash.Item("pkg_id"),     ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "V_EXT",             EmptyToNull(pkgInfoHash.Item("v_ext")), ORAPARM_INPUT, ORATYPE_VARCHAR2 
        
        Set rsQry = OraDatabase.DbCreateDynaset( GetQuery("ReleasePackageVersions.sql"), cint(0))
        
    Response.Write "<!-- " & parComparePvId & "," & pkgInfoHash.Item("pkg_id") & "," & EmptyToNull(pkgInfoHash.Item("v_ext")) & " -->" & VBNewLine
        Response.write "<option value='-1'  disabled selected>Not in a Release</option>"
        
    While ((NOT rsQry.BOF) AND (NOT rsQry.EOF))
                
                Response.write "<option value='"& rsQry("pv_id") &"' "& rsQry("selected") &" >"& rsQry("text") &"</option>"& VBNewLine
                
                rsQry.MoveNext
    WEnd
        
        ' Clean up
        rsQry.Close()
        Set rsQry = nothing
        
        OraDatabase.Parameters.Remove "COMPARE_PV_ID"
        OraDatabase.Parameters.Remove "PKG_ID"
        OraDatabase.Parameters.Remove "V_EXT"
        
End Sub

'-----------------------------------------------------------------------------------------------------------------
Sub DisplayDiffSummary( orsQry )
        Dim dDiffSummary
        Set dDiffSummary = CreateObject("Scripting.Dictionary")
        
        dDiffSummary.Item ("UPDATED") = 0
        dDiffSummary.Item ("REMOVED") = 0
        dDiffSummary.Item ("ADDED") = 0
        
        
        While ((NOT orsQry.BOF) AND (NOT orsQry.EOF))
                
                Select Case CInt( orsQry("status") )
                        Case enumDB_NUM_DIFF_UPDATED
                                dDiffSummary.Item ("UPDATED") = CInt( dDiffSummary.Item ("UPDATED") ) + 1
                                
                        Case enumDB_NUM_DIFF_REMOVED
                                dDiffSummary.Item ("REMOVED") = CInt( dDiffSummary.Item ("REMOVED") ) + 1
                                
                        Case enumDB_NUM_DIFF_NEW
                                dDiffSummary.Item ("ADDED") = CInt( dDiffSummary.Item ("ADDED") ) + 1
                                
                End Select
                
                orsQry.MoveNext
        WEnd
        
        
        ' Reset cursor
        orsQry.MoveFirst()
        
        
        ' Display Summary
        Response.write dDiffSummary.Item ("UPDATED") &" -<img src='images/i_updated.gif' width='11' height='11' hspace='3'>Updated, "
        Response.write dDiffSummary.Item ("ADDED") &" -<img src='images/i_added.gif' width='11' height='11' hspace='3'>Added, "
        Response.write dDiffSummary.Item ("REMOVED") &" -<img src='images/i_removed.gif' width='11' height='11' hspace='3'>Removed"
        
End Sub
'-----------------------------------------------------------------------------------------------------------------
Sub DisplayComponentChanges( nPvId, nComparePvId )
        Dim rsComp, sSize, sIcon, sDiffStateIcon, sStyle
        
        '''''Response.write nPvId &" "& nComparePvId
        
        OraDatabase.Parameters.Add "PV_ID", nPvId,      ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "COMPARE_PV_ID", nComparePvId,       ORAPARM_INPUT, ORATYPE_NUMBER 
        
        Set rsComp = OraDatabase.DbCreateDynaset( GetQuery("ModuleComponentDiff.sql"), cint(0))
        
        OraDatabase.Parameters.Remove "PV_ID"
        OraDatabase.Parameters.Remove "COMPARE_PV_ID"
        
        %>
        
          <%If rsComp.Recordcount < 1 Then%>
                                                
                                                
                                          
          <%Else%>
          
          <table width="100%"  border="0" cellspacing="1" cellpadding="3" class=stdGrey>
          <thead>
                  <tr class="form_field_bg">
                    <th width="1"  ></th>
                    <th width="1"  ></th>
                    <th width="50%">Name</th>
                    <th width="50%" align="right">Byte Size</th>
                  </tr>
          </thead>
                        <%
                        While ((NOT rsComp.BOF) AND (NOT rsComp.EOF)) 
                                
                                Call GetDiffStateIcon( rsComp("diff_state"), sDiffStateIcon, sStyle )
                                
                                ' Find if this is file or folder
                                If IsNull( rsComp("crc_cksum") )  AND  (rsComp("byte_size") = 0) Then 
                                        sSize = ""
                                        sIcon = "<img src='images/rex_images/_folder.gif' border='0' hspace='3' align='absmiddle'>"
                                Else
                                        sSize = rsComp("byte_size")
                                        sIcon = "<img src='images/rex_images/ext_blank.gif' border='0' hspace='3' align='absmiddle'>"
                                End If
                                
                        %>
                          <%If NOT dFileFilter.Exists ( CStr(rsComp("diff_state")) ) Then%>
              <tr>
                                <td nowrap><%=sDiffStateIcon%></td>
                                <td nowrap><%=sIcon%></td>
                <td nowrap class="<%=sStyle%>"><%=rsComp("name")%></td>
                <td nowrap align="right"><%=sSize%></td>
              </tr>
                          <%End If%>
                <%
                        rsComp.MoveNext
                WEnd
                rsComp.Close()
                Set rsComp = nothing
                %>
       </table><br>
          <%End If%>
<%End Sub

'--------------------------------------------------------------------------------------------------------------------------------------
Sub GetDiffStateIcon( nDiffState, outIcon, outStyle )
        Select Case CInt( nDiffState )
                Case enumDB_NUM_DIFF_UPDATED
                        outIcon  = LIMG_UPDATED
                        outStyle = "body_rowbold"
                        
                Case enumDB_NUM_DIFF_REMOVED
                        outIcon = LIMG_REMOVED
                        outStyle = "body_rowthru"
                        
                Case enumDB_NUM_DIFF_NEW
                        outIcon = LIMG_ADDED
                        outStyle = "body_rowbold"
                        
                Case Else
                        outIcon = ""
                        outStyle = ""
                        
        End Select
        
End Sub
'-----------------------------------------------------------------------------------------------------------------
Sub DisplayFileFilter
    If parFileDiff <> "" Then%>
    <!-- FILE FILTER -->                
    <fieldset>
        <legend>
            <span class="body_scol nowrap pointer" onClick="ToggleDisplay('divFileFilter');" ><%=GetIsFileFilterInUseIcon() %>&nbsp;Hide&nbsp;Files&nbsp;and&nbsp;Folders...</span>
        </legend>
        <div name="divFileFilter" id="divFileFilter" class="body_txt" style="display:none;">
              <table width="100%"  border="0" cellspacing="1" cellpadding="3">
                <tr>
                  <td width="1" class='bg_dialog'><input name="filefilter" type="checkbox" value="<%=enumDB_NUM_DIFF_UPDATED%>" <%=GetIsFileFilterChecked(enumDB_NUM_DIFF_UPDATED)%>></td>
                  <td width="50" nowrap class="bg_dialog form_field"><%=LIMG_UPDATED%>Updated</td>
                </tr>
                <tr>
                  <td class='bg_dialog'><input type="checkbox" name="filefilter" value="<%=enumDB_NUM_DIFF_NEW%>" <%=GetIsFileFilterChecked(enumDB_NUM_DIFF_NEW)%>></td>
                  <td nowrap class="bg_dialog form_field"><%=LIMG_ADDED%>Added</td>
                </tr>
                <tr>
                  <td class='bg_dialog'><input type="checkbox" name="filefilter" value="<%=enumDB_NUM_DIFF_REMOVED%>" <%=GetIsFileFilterChecked(enumDB_NUM_DIFF_REMOVED)%>></td>
                  <td nowrap class="bg_dialog form_field"><%=LIMG_REMOVED%>Removed</td>
                </tr>
                <tr>
                  <td class='bg_dialog'><input type="checkbox" name="filefilter" value="<%=enumDB_NUM_DIFF_NO_CHANGE%>" <%=GetIsFileFilterChecked(enumDB_NUM_DIFF_NO_CHANGE)%>></td>
                  <td nowrap class="bg_dialog form_field">Unchanged</td>
                </tr>
                <tr>
                  <td class='bg_dialog'>&nbsp;</td>
                  <td class='bg_dialog'><input name="btn" type="submit" class="form_btn" id="btn" value="Hide"></td>
                </tr>
              </table>
        </div>
    </fieldset>
    <!-- END FILE FILTER -->            
    <%End If
End Sub
'-----------------------------------------------------------------------------------------------------------------
Sub displayDepFilter %>
    <!-- DEPENDENCY FILTER -->   
    <fieldset>
          <legend>
            <span class="body_scol nowrap pointer" onClick="ToggleDisplay('divDependencyFilter');" ><%=GetIsDepFilterInUseIcon() %>&nbsp;Hide&nbsp;Dependencies...</span>
          </legend>
          <div name="divDependencyFilter" id="divDependencyFilter" class="body_txt" style="display:none;">
            <table width="100%"  border="0" cellspacing="1" cellpadding="3">
              <tr>
                <td width="1" class='bg_dialog'><input name="depfilter" type="checkbox" value="<%=enumDB_NUM_DIFF_UPDATED%>" <%=GetIsDepFilterChecked(enumDB_NUM_DIFF_UPDATED)%>></td>
                <td width="50" nowrap class="bg_dialog form_field"><%=LIMG_UPDATED%>Updated</td>
              </tr>
              <tr>
                <td class='bg_dialog'><input type="checkbox" name="depfilter" value="<%=enumDB_NUM_DIFF_NEW%>" <%=GetIsDepFilterChecked(enumDB_NUM_DIFF_NEW)%>></td>
                <td nowrap class="bg_dialog form_field"><%=LIMG_ADDED%>Added</td>
              </tr>
              <tr>
                <td class='bg_dialog'><input type="checkbox" name="depfilter" value="<%=enumDB_NUM_DIFF_REMOVED%>" <%=GetIsDepFilterChecked(enumDB_NUM_DIFF_REMOVED)%>></td>
                <td nowrap class="bg_dialog form_field"><%=LIMG_REMOVED%>Removed</td>
              </tr>
              <tr>
                <td class='bg_dialog'><input type="checkbox" name="depfilter" value="<%=enumDB_NUM_DIFF_NO_CHANGE%>" <%=GetIsDepFilterChecked(enumDB_NUM_DIFF_NO_CHANGE)%>></td>
                <td nowrap class="bg_dialog form_field">Unchanged</td>
              </tr>
              <tr>
                <td class='bg_dialog'>&nbsp;</td>
                <td class='bg_dialog'><input name="btn2" type="submit" class="form_btn" id="btn2" value="Hide"></td>
              </tr>
            </table>
        </div>
    </fieldset>
    <!-- END DEPENDENCY FILTER -->   
<%End Sub
%>
<%
'------------------------- MAIN LINE ---------------------------

Call GetDepFilterValues ( dDepFilter )
Call GetFileFilterValues ( dFileFilter )

'---------------------------------------------------------------
%>
<!-- MAIN PAGE ------------------------------------------>
        
        <a name="MODULECHANGES"></a>
    <script>
        function setRefVersion(sel) {
            var el = document.getElementsByName("compare_pv_id")[0];
            var val = sel.value;
            el.value = val;

            var el = document.getElementById("showVersion1");
            el.value = val;

            var el = document.getElementById("showVersion2");
            el.value = val;
            if ( el.value != val ) {
                el.value = -1;
                }
            }
    </script>
        <form name="modulechanges" method="get" action="<%=ScriptName%>?#MODULECHANGES" onSubmit="ProgressBar.style.visibility='visible';">
                <%

                ' Make database connection
                OraDatabase.Parameters.Add "PV_ID",             parPv_id,       ORAPARM_INPUT, ORATYPE_NUMBER 
                OraDatabase.Parameters.Add "OLD_PV_ID",         parComparePvId,         ORAPARM_INPUT, ORATYPE_NUMBER 
                
                Set rsTemp = OraDatabase.DbCreateDynaset( GetQuery ( "diff_dependencies.sql" ), cint(0))
                
                OraDatabase.Parameters.Remove "PV_ID"
                OraDatabase.Parameters.Remove "OLD_PV_ID"
                
                %>
                <%If rsTemp.Recordcount > 0 Then%>
                <table width="100%"  border="0" cellspacing="0" cellpadding="10">
            <tr>
              <td nowrap class="bg_dialog body_txt">
                  <table>
                      <tr nowrap class="bg_dialog body_txt">
                        <td class=nowrap>Show differences since version in release</td>
                        <td>
                            <select id=showVersion2 class="form_item" onChange="setRefVersion(this)">
                                            <%Call DisplayCompareReleasePvIdCombo()%>
                            </select></td>
                      </tr>
                      <tr nowrap class="bg_dialog body_txt">
                        <td class=nowrap>Showing differences since version</td>
                        <td>
                            <select id=showVersion1 class="form_item" onChange="setRefVersion(this)">
                                            <%Call DisplayComparePvIdCombo()%>
                            </select>
                            <button type="submit" name="btn" class="form_btn" value=Compare>Compare</button></td>
                      </tr>
                  </table>
                      <td align="right" nowrap class="bg_dialog body_txt" valign="top">
                            <%Call DisplayDiffSummary( rsTemp ) %>
              </td>
            </tr>
        </table>
                <table width="100%"  border="0" cellspacing="0" cellpadding="5">
            <tr>
              <td width="100%" valign="top" nowrap class="bg_bage body_txt">
                <%If parFileDiff <> "" Then%>
                    <button type="submit" name="filediff" class="form_btn" value="">Collapse Files and Folders...</button></td>
                                <%Else%>
                    <button type="submit" name="filediff" class="form_btn" value="true">Expand Files and Folders...</button></td>
                            <%End If%>
              </td>
                        
                        <td nowrap class='bg_bage'>
                    <%Call DisplayFileFilter%>
                                </td>
                        <td nowrap class='bg_bage'>
                                    <%Call displayDepFilter%>
                </td>
          </tr>
        </table>
                        
                    
                <%End If%>                                               
                <%
        %>                                      

                <table width="100%" border="0" cellspacing="1" cellpadding="3" class='etable stdGrey'>
            <thead>
                  <tr> 
                    <th nowrap width="1%">Change</th>
                    <th nowrap width="1%">Name&nbsp;&nbsp;</th>
                    <th nowrap width="1%">Current Version&nbsp;&nbsp;</th>
                    <th nowrap width="100%">Previous Version</th>
                  </tr>
            </thead>
          <%
                    Dim style, icon, sText
            icon  = Iif( Clng(DB_PV_ID) = cLng(parComparePvId),  "", LIMG_UPDATED)
            sText = Iif( Clng(DB_PV_ID) = cLng(parComparePvId),  "No Change", "Changed")
          %>
              <tr class="hdr csvData">
                    <td nowrap class="tcenter" data-csv="<%=sText%>"><%=icon%></td>
                    <td nowrap><%=pkgInfoHash.Item("pkg_name")%></td>
                    <td nowrap><%=pkgInfoHash.Item("pkg_version")%></td>
                    <td nowrap><%=preVerText%></td>
                  </tr>
          <%If (parFileDiff <> "") Then%>
          <tr> 
            <td>&nbsp;</td>
            <td>&nbsp;</td>
            <td colspan="2">
            <%Call DisplayComponentChanges( DB_PV_ID, parComparePvId )%>
            </td>
          </tr>
          <%End If%>    

                  
              <%If (rsTemp.RecordCount < 1) Then%>
          <tr>
                    <td nowrap>&nbsp;</td>
                    <td nowrap>&nbsp;</td>
                    <td nowrap>&nbsp;</td>
                    <td nowrap>&nbsp;</td>
                  </tr>
                  <%End If%>    
                  <%
                  While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))
                                Call RowStyle ( rsTemp("status"), icon, style, sText )
                  %>
                  
                          <%If NOT dDepFilter.Exists(CStr( rsTemp("status") )) Then%>
                                  <tr class="csvData">
                                    <td align="center" data-csv="<%=sText%>"><%=icon%></td>
                                    <td nowrap class="<%=style%>">
                                        <%If NOT IsNull(rsTemp("pkg_version")) Then%> 
                                                <a href="<%=ScriptName &"?pv_id="& rsTemp("pv_id") &"&rtag_id="& parRtag_id %>" class="<%=style%>"><%=rsTemp("pkg_name")%></a>
                                        <%Else%>
                                                <%=rsTemp("pkg_name")%>
                                        <%End If%>
                                        </td>
                                    <td nowrap class="<%=style%>"><%=rsTemp("pkg_version")%></td>
                                        <td nowrap class="<%=style%>"><%=rsTemp("previous_version")%></td>
                                  </tr>
                                  
                              <%If (parFileDiff <> "") AND ( rsTemp("status") <> enumDB_DIFF_NO_CHANGE ) Then%>
                                  <tr> 
                                    <td>&nbsp;</td>
                                    <td>&nbsp;</td>
                                    <td colspan="2">
                                        <%Call DisplayComponentChanges( rsTemp("pv_id"), rsTemp("old_pv_id") )%>
                                        </td>
                                  </tr>
                                  <%End If%>    
                          
                          <%End If%>
                  
                        
                        <%rsTemp.MoveNext
                  WEnd
                  rsTemp.Close
                  Set rsTemp = nothing
                  
                  %>
            
                </table>
                <input type="hidden" name="pv_id" value="<%=parPv_Id%>">
                <input type="hidden" name="rtag_id" value="<%=parRtag_Id%>">
                <input type="hidden" name="compare_pv_id" value="<%=parComparePvId%>">
        </form>