Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'   UsedByPackageSummary.asp
'   Show the body of the used by packages summary display
'   This is invoked via AJAX
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0    ' always load the page, dont store
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<%
'------------ Variable Definition -------------
Dim rsTemp
Dim pkgId
Dim parPv_id
Dim parMode
Dim divId
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
parPv_id = Request ("pv_id")
parMode = Request ("mode")
'----------------------------------------------
%>
<%
'------------------------------------------------------------------------------------------------------------------------
%>
<%
'------------------------ MAIN LINE ---------------------------------
'--------------------------------------------------------------------
%>
  <table width="100%"  border="0" cellspacing="1" cellpadding="4" class="stdGrey">
      <thead>
         <tr>
            <th width="1%"></th>
            <th width="100%" nowrap>Package</th>
         </tr>
      </thead>
     <%
     OraDatabase.Parameters.Add "PV_ID", parPv_id,    ORAPARM_INPUT, ORATYPE_NUMBER
     OraDatabase.Parameters.Add "MATCH", parMode,    ORAPARM_INPUT, ORATYPE_NUMBER
     Set rsTemp = OraDatabase.DbCreateDynaset( GetQuery("UsedByPackageSummary.sql"), cint(0) )
     OraDatabase.Parameters.Remove "PV_ID"
     OraDatabase.Parameters.Remove "MATCH"
     %>
     <%If rsTemp.RecordCount < 1 Then%>
        <tr>
           <td>&nbsp;</td>
           <td>None Found</td>
        </tr>
     <%End If%>
     <%While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))
        pkgId = rsTemp("pkg_id")
        divId = "PKGID_" & parMode & "_" & pkgId
        %>
        <tr>
           <td></td>
           <td>
              <span class="pointer txt_linked" onClick="ToggleLoadControl('<%=divId%>','UsedByPackageDetail.asp?pv_id=<%=parPv_id%>&pkg_id=<%=pkgId%>&mode=<%=parMode%>');">
                    <img id=IMG_<%=divId%> src="images/bt_plus.gif" border="0" align="absmiddle" hspace="3">
                    <%= rsTemp("pkg_name") &" ("& rsTemp("count") &")"%>
              </span>
              <DIV id="<%=divId%>" style="display:none;"><%=enumLOADING%></DIV>
           </td>
        </tr>

        <%rsTemp.MoveNext
     WEnd
     rsTemp.Close
     Set rsTemp = nothing%>

  </table><br>
<%
Call Destroy_All_Objects
%>