Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'   RequestUsedByThisProjectSummary.asp
'   Show the body of the used by packages summary display
'   This is invoked via AJAX
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0    ' always load the page, dont store
' Essential to get UTF through all the hoops. ie: VÄSTTRAFIK (VTK)
Response.ContentType = "text/html"
Response.AddHeader "Content-Type", "text/html;charset=UTF-8"
Response.CodePage = 65001
Response.CharSet = "UTF-8"
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<%
'------------ Variable Definition -------------
Dim rsTemp
Dim pkgId
Dim parPkg_id
Dim parVext
Dim parPvId
Dim projId, projName, projCount
Dim parExactMatch
Dim matchPVID
Dim divId
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
parPvId = Request("pv_id")
parPkg_id = Request ("pkg_id")
parVext = Request ("v_ext")
matchPVID = -1
parExactMatch = Request ("mode")
If (parExactMatch = 1 ) Then
    matchPVID = parPvId
End If
'----------------------------------------------
%>
<%
'------------------------------------------------------------------------------------------------------------------------
%>
<%
'------------------------ MAIN LINE ---------------------------------
'--------------------------------------------------------------------
%>

      <table width="100%"  border="0" cellspacing="1" cellpadding="4">
         <tr>
            <td width="1%" background="images/bg_form_lightbluedark.gif" nowrap class="body_col"></td>
            <td width="100%" background="images/bg_form_lightbluedark.gif" nowrap class="body_col">Project</td>
         </tr>
         <%
         OraDatabase.Parameters.Add "PKG_ID",  parPkg_id, ORAPARM_INPUT, ORATYPE_NUMBER
                 OraDatabase.Parameters.Add "V_EXT",   EmptyToNull(parVext), ORAPARM_INPUT, ORATYPE_VARCHAR2
         OraDatabase.Parameters.Add "PV_ID",   matchPVID, ORAPARM_INPUT, ORATYPE_NUMBER

         Set rsTemp = OraDatabase.DbCreateDynaset( GetQuery("UsedByProjects.sql"), cint(0) )

         OraDatabase.Parameters.Remove "PKG_ID"
         OraDatabase.Parameters.Remove "V_EXT"
         OraDatabase.Parameters.Remove "PV_ID"
         %>
         <%If rsTemp.RecordCount < 1 Then%>
            <tr>
               <td background="images/bg_form_lightgray.gif" nowrap class="form_item">&nbsp;</td>
               <td background="images/bg_form_lightgray.gif" nowrap class="form_item">&nbsp;</td>
            </tr>
         <%End If%>
         <%While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))
            projId = rsTemp("proj_id")
            projName = rsTemp("proj_name")
            projCount = rsTemp("used_count")
            divId = "PROJID_" & projId & parExactMatch
            %>
            <tr>
               <td background="images/bg_form_lightgray.gif" class="form_item"></td>
               <td nowrap background="images/bg_form_lightgray.gif" class="form_item">
                  <a href="javascript:;" class="txt_linked" onClick="ToggleUsedByControl('<%=divId%>','RequestUsedByThisProject.asp?pv_id=<%=parPvId%>&proj_id=<%=projId%>&mode=<%=parExactMatch%>');">
                        <img id=IMG_<%=divId%> src="images/bt_plus.gif" border="0" align="absmiddle" hspace="3">
                        <%= projName &" ("& projCount &")"%>
                   </a>
                  <DIV class="form_item" id="<%=divId%>" style="display:none;"><%=enumLOADING%></DIV>
               </td>
            </tr>

            <%rsTemp.MoveNext
         WEnd
         rsTemp.Close
         Set rsTemp = nothing%>

      </table><br>
<%
Call Destroy_All_Objects
%>