Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'   RequestUsedByThisProjectSummary.asp
'   Show the body of the used by packages summary display
'   This is invoked via AJAX
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0    ' always load the page, dont store
' Essential to get UTF through all the hoops. ie: VÄSTTRAFIK (VTK)
Response.ContentType = "text/html"
Response.AddHeader "Content-Type", "text/html;charset=UTF-8"
Response.CodePage = 65001
Response.CharSet = "UTF-8"
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<%
'------------ Variable Definition -------------
Dim rsTemp
Dim pkgId
Dim parPkg_id
Dim parVext
Dim parPvId
Dim projId, projName, projCount
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
parPvId = Request("pv_id")
parPkg_id = Request ("pkg_id")
parVext = Request ("v_ext")
'----------------------------------------------
%>
<%
'------------------------------------------------------------------------------------------------------------------------
%>
<%
'------------------------ MAIN LINE ---------------------------------
'--------------------------------------------------------------------
%>

      <table width="100%"  border="0" cellspacing="1" cellpadding="4">
         <tr>
            <td width="1%" background="images/bg_form_lightbluedark.gif" nowrap class="body_col"></td>
            <td width="100%" background="images/bg_form_lightbluedark.gif" nowrap class="body_col">Project</td>
         </tr>
         <%
         OraDatabase.Parameters.Add "PKG_ID",  parPkg_id,     ORAPARM_INPUT, ORATYPE_NUMBER
         If parVext <> "" Then
            OraDatabase.Parameters.Add "V_EXT",   parVext,    ORAPARM_INPUT, ORATYPE_VARCHAR2
         Else
            OraDatabase.Parameters.Add "V_EXT",   NULL,       ORAPARM_INPUT, ORATYPE_VARCHAR2
         End If

         Set rsTemp = OraDatabase.DbCreateDynaset( GetQuery("UsedByProjects.sql"), cint(0) )

         OraDatabase.Parameters.Remove "PKG_ID"
         OraDatabase.Parameters.Remove "V_EXT"
         %>
         <%If rsTemp.RecordCount < 1 Then%>
            <tr>
               <td background="images/bg_form_lightgray.gif" nowrap class="form_item">&nbsp;</td>
               <td background="images/bg_form_lightgray.gif" nowrap class="form_item">&nbsp;</td>
            </tr>
         <%End If%>
         <%While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))
            projId = rsTemp("proj_id")
            projName = rsTemp("proj_name")
            projCount = rsTemp("used_count")
            %>
            <tr>
               <td background="images/bg_form_lightgray.gif" class="form_item"></td>
               <td nowrap background="images/bg_form_lightgray.gif" class="form_item">
                  <a href="javascript:;" class="txt_linked" onClick="ToggleUsedByControl('PROJID_<%=projId%>','RequestUsedByThisProject.asp?pv_id=<%=parPvId%>&proj_id=<%=projId%>');">
                        <img id=IMG_PROJID_<%=projId%> src="images/bt_plus.gif" border="0" align="absmiddle" hspace="3">
                        <%= projName &" ("& projCount &")"%>
                   </a>
                  <DIV class="form_item" id="PROJID_<%=projId%>" style="display:none;"><%=enumLOADING%></DIV>
               </td>
            </tr>

            <%rsTemp.MoveNext
         WEnd
         rsTemp.Close
         Set rsTemp = nothing%>

      </table><br>
<%
Call Destroy_All_Objects
%>