Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|                 RequestUsedByThisProject.asp          |
'|                                                   |
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0    ' always load the page, dont store
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<%
'------------ Variable Definition -------------
Dim rsTemp
Dim parPvId
Dim parMode
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
parPvId = Request("pv_id")
parMode = Request ("mode")
'----------------------------------------------
%>
<table width="100%" border="0" cellspacing="1" cellpadding="3" class="stdGrey">
    <thead>
      <tr>
        <th width="33%" nowrap>Release</th>
        <th width="33%" nowrap>Location</th>
        <th width="33%" nowrap>Version&nbsp;Used</th>
        <th width="1"   nowrap>Last&nbsp;Modified</th>
      </tr>
    </thead>

<%
  OraDatabase.Parameters.Add "PROJ_ID", Request("proj_id"),     ORAPARM_INPUT, ORATYPE_NUMBER 
  OraDatabase.Parameters.Add "PV_ID",   parPvId, ORAPARM_INPUT, ORATYPE_NUMBER 
  OraDatabase.Parameters.Add "MATCH",   parMode, ORAPARM_INPUT, ORATYPE_VARCHAR2
  
  Set rsTemp = OraDatabase.DbCreateDynaset( GetQuery("UsedByThisProject.sql"), cint(0))
  
  OraDatabase.Parameters.Remove "PROJ_ID"
  OraDatabase.Parameters.Remove "PV_ID"
  OraDatabase.Parameters.Remove "MATCH"
  %>
  <%If rsTemp.RecordCount < 1 Then%>
  <tr> 
    <td nowrap>&nbsp;</td>
    <td nowrap>&nbsp;</td>
    <td nowrap>&nbsp;</td>
    <td nowrap>&nbsp;</td>
  </tr>
  <%End If%>
  <%While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))%>
  <tr> 
    <td nowrap><a href="dependencies.asp?pv_id=<%=rsTemp("pv_id")%>&rtag_id=<%=rsTemp("rtag_id")%>" class="txt_linked"><%=ReleaseIcon( rsTemp("official") )%>&nbsp;<%=rsTemp("rtag_name")%></a></td>
    <td nowrap><%=GetEnvName(rsTemp("env_area")) %></td>
    <td nowrap <%If rsTemp("pv_id") <> Request("pv_id") Then%>class="err_alert"<%Else%>class="form_item"<%End If%>><%=rsTemp.Item ("pkg_name") &" "& rsTemp("pkg_version")%></td>
    <td nowrap><%=emailField(enum_imgUser & rsTemp("full_name"), rsTemp("user_email"))%>&nbsp;<%=DisplayDate ( rsTemp("modified_stamp") )%></td>
  </tr>
  <%rsTemp.MoveNext
  WEnd
  rsTemp.Close
  Set rsTemp = nothing%>
</table>
<%
Call Destroy_All_Objects
%>