Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'   sdk_remove_release.asp
'   Remove zero or more SDKs from a Release
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0   ' always load the page, dont store
%>

<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/common_dbedit.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_login.asp"-->
<!--#include file="_access_control_general.asp"-->
<!--#include file="_access_control_project.asp"-->
<%
'------------ Variable Definition -------------
Dim ProblemsString
Dim OverideWarnings
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
ProblemsString = NULL

OverideWarnings = "N"
If InStr( 1, Request("btn"), "YES", 1 ) > 0 Then OverideWarnings = "Y"

'----------------------------------------------
%>
<%
Sub RemoveReleaseSdk   ( nRtagId, nSdktagId, outProblemsString )

   OraDatabase.Parameters.Add "RTAG_ID",     nRtagId,   ORAPARM_INPUT, ORATYPE_NUMBER
   OraDatabase.Parameters.Add "SDKTAG_ID",   nSdktagId, ORAPARM_INPUT, ORATYPE_NUMBER

   objEH.TryORA ( OraSession )
   On Error Resume Next

   OraDatabase.ExecuteSQL _
   " BEGIN "&_
   "    PK_RELEASE.REMOVE_RELEASE_SDK ( :RTAG_ID, :SDKTAG_ID ); "&_
   " END; "

   objEH.CatchORA ( OraSession )

   OraDatabase.Parameters.Remove "RTAG_ID"
   OraDatabase.Parameters.Remove "SDKTAG_ID"
End Sub
%>
<%
'-----------------------  MAIN LINE  ---------------------------

'------ ACCESS CONTROL ----------
'If NOT canShowControlInProject("RemoveReleaseSdk") Then
'   Call OpenInWindow ( "Login.asp?message=4&rfile="& scriptName & objPMod.ComposeURLWithout("rfile") )
'End If
'--------------------------------

If (Request("rtag_id") <> "") Then

   '    May have zero or more SDKs to delete
   '    Ignore attempts to delete zero SDks
   Dim sdktagArray, ii
   sdktagArray = Split(Request("sdktag_id"), ",")

    For ii = 0 To UBound(sdktagArray)
        Call RemoveReleaseSdk ( Request("rtag_id"), sdktagArray(ii), ProblemsString )
    Next

   Response.Redirect( "dependencies.asp?rtag_id="& Request("rtag_id") )

Else

   Err.Raise 8, "This page requires more paramaters to run.<br>"& objPMod.ComposeURL()

End If

'----------------------------------------------------------------
%>

<!-- DESTRUCTOR ------->
<!--#include file="common/destructor.asp"-->