Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'       sdk_content_json.asp
'       Ajax support for table of SDK Content
'       Designed to be driven by the jquery tablescroller
'       Uses DataTables 1.10 format data
'=====================================================
%>
<%
Option explicit
' Essential to get UTF through all the hoops. ie: VÄSTTRAFIK (VTK)
Response.ContentType = "text/html"
Response.AddHeader "Content-Type", "text/html;charset=UTF-8"
Response.CodePage = 65001
Response.CharSet = "UTF-8"
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<SCRIPT LANGUAGE="VBScript" RUNAT=SERVER SRC="class/classaspJSON.vbs"></SCRIPT> 
<%
'------------ Variable Definition -------------
Dim result : result = -1
Dim SqlQry
Dim rsQry
Dim sdktag_id : sdktag_id = Request("sdktag_id")
Dim sdk_statefilter : sdk_statefilter = Request("sdk_statefilter")

' Init the output JSON class
'   Operations can add data
'   Default data will be added at the end
Dim oJSON :Set oJSON = New aspJSON
Dim newitem

'
' Determine the size of the record set
'   Gives bad results when searching
Dim MaxCount : MaxCount = 0

SqlQry = "select count(*) as count from SDK_CONTENT skc where SDKTAG_ID = '" & sdktag_id &"'"
If sdk_statefilter Then
    SqlQry = SqlQry & " AND skc.sdkpkg_state in ('E')"
End If

On Error Resume Next
objEH.ErrorRedirect = FALSE
objEH.TryORA ( OraSession )
Set rsQry = OraDatabase.DbCreateDynaset( SqlQry, ORADYN_DEFAULT )
objEH.CatchORA ( OraSession )
    If ((NOT rsQry.BOF) AND (NOT rsQry.EOF)) Then
        MaxCount = rsQry("COUNT")
    End If
rsQry.Close
Set rsQry = Nothing

' Basic Header
'   iTotalRecords = total records without any filtering/limits
'   iTotalDisplayRecords = filtered result count

oJSON.data("draw") = CInt(Request.QueryString("draw"))
oJSON.data("recordsTotal") = MaxCount
oJSON.data("recordsFiltered") = MaxCount

Dim vName
for each vName in Request.QueryString
    oJSON.data("sReq_" & vName) = Request.QueryString(vName)
next

' Extract selected range
result = 0
dim firstRow,lastRow
firstRow = CInt(Request.QueryString("start"))
lastRow = firstRow + CInt(Request.QueryString("length"))

' Define the data items to extract from the database
' An array of items to extract
'
Dim dataCols: dataCols = Array ( _ 
        "sc.pv_id", _
        "p.pkg_name", _
        "pv.pkg_version", _
        "sc.sdkpkg_state" )

'   Define array of colums to sort by
'       Must match user sort column request
Dim sortCols: sortCols = Array ( _
        "sc.pv_id", _
        "UPPER(p.pkg_name)", _
        "UPPER(pv.pkg_version)", _
        "UPPER(sc.sdkpkg_state)" )

' Dim determine sorting options
'On Error goto 0
'Response.Write "<pre>"
Dim sortString
If Request.QueryString("order[0][column]") <> "" Then
    sortString = " ORDER BY " & sortCols(CInt(Request.QueryString("order[0][column]")))
    sortString = sortString & " " & Request.QueryString("order[0][dir]")
    sortString = sortString & "," & sortCols(CInt(1)) & " asc"
Else
    sortString = " ORDER BY " & sortCols(CInt(1)) & " asc"
End If

' Filter (search )
Dim searchString : searchString = ""
If Request.QueryString("search[value]") <> "" Then
    searchString = " AND upper(pkg_name) || '_' || UPPER(pv.pkg_version) LIKE upper('%" & Request.QueryString("search[value]") & "%')" 
End If

If sdk_statefilter Then
    searchString = searchString & " AND sc.sdkpkg_state in ('E')"
End If

' Create a list of cols that we need. Avoids ambiguity in selections
Dim x,colList,colListJoin
For x = Lbound(dataCols) to Ubound(dataCols)
    colList = colList & colListJoin & dataCols(x)
    colListJoin = ","
Next

Dim whereString
Dim BasicSql
BasicSql = "select " & colList &_
            " FROM SDK_CONTENT SC , PACKAGE_VERSIONS pv, PACKAGES p " &_
            " where sc.sdktag_id = "&sdktag_id&" AND pv.pv_id = sc.pv_id AND p.pkg_id = pv.pkg_id " &_
            whereString &_
            searchString &_
            sortString

SqlQry = "select * from ( "&_
            "select a.*, ROWNUM rnum from (" & BasicSql &_
                ") a where ROWNUM <= " & lastRow &_
            ") where rnum >= " & firstRow

' Assist in debug
oJSON.data("BasicSql") = BasicSql
'oJSON.data("SqlQry") = SqlQry

' Perform the database query
Set oJSON.data("aaData") = oJSON.Collection()
On Error Resume Next
objEH.ErrorRedirect = FALSE
objEH.TryORA ( OraSession )
Set rsQry = OraDatabase.DbCreateDynaset( SqlQry, ORADYN_DEFAULT )
objEH.CatchORA ( OraSession )
' Process each row and return required fields to the user
If objEH.Finally Then
On Error goto 0
   
    While (NOT rsQry.BOF) AND (NOT rsQry.EOF)
        Set newitem = oJSON.AddToCollection(oJSON.data("aaData"))
        Dim ii
        for ii = 0 to rsQry.Fields.Count - 2
            newitem (rsQry.FieldName(ii)) = rsQry.Fields(ii)
            'newitem (ii) = rsQry.Fields(ii)
        Next
       rsQry.MoveNext
    Wend
End IF

rsQry.Close
Set rsQry = Nothing

'
' SQL error detection and reporting
'   The content of 'error' will be dsplayed to the user.
If objEH.LastOraFailed Then
    oJSON.data("error") = objEH.MessageSummary
    oJSON.data("emsgDetails") = objEH.MessageDetails
    oJSON.data("SqlQry") = SqlQry
End If

'Return the object
Response.Write oJSON.JSONoutput()
'OraSession.Dispose()
%>