Subversion Repositories DevTools

<?xml version="1.0" ?>
<package>
        <comment>
        PrimalCode wizard generated file.
        </comment>
        <job id="onMakeUnofficial" args="/pkg_name:tp5000 /pkg_version:1.20.0.oso" prompt="no">
                <?job error="false" debug="false" ?>
                <runtime>
                        <named helpstring="Package Name" name="pkg_name" required="false" type="string"/>
                        <named helpstring="Package Version" name="pkg_version" required="false" type="string"/>
                        <named helpstring="Package primary key" name="pv_id" required="false" type="string"/>
                        <usage>
Usage: 
   Admin_Tools.wsf [/pkg_name:value] [/pkg_version:value]
OR
   Admin_Tools.wsf [/pv_id:value]

Options:

pkg_name     : Package Name
pkg_version  : Package Version
pv_id        : Package Version primary key
                        </usage>
                </runtime>
                <object id="Oracle_Objects_For_OLE" progid="OracleInProcServer.XOraSession" events="true"/>
                <script language="VBScript" src="common_subs.vbs"/>
                <script language="VBScript" src="config.vbs"/>
                <script language="VBScript" src="pkg_archive.vbs"/>
                <script id="Admin_Tools" language="VBScript">
<![CDATA[
Option Explicit
'=====================================================
'        Name:  onMakeUnofficial
' Description:  Run this job when making package
'               Unofficial again. This job should 
'               make version folder writable again.
'               INPUT:  pkg_name
'                               pkg_version
'               OR pv_id
'=====================================================

'================ Variable Definition ================
Dim parPv_id
Dim parPkg_name
Dim parPkg_Version
Dim objArgs
'=============== Constants Declaration ===============
'================== Variable Init ====================
'=====================================================
'-----------------------------------------------------------------------------------------------------------------
'-----------------------------------------------------------------------------------------------------------------
Sub onMakeUnofficial ( )
        Dim fileSys, rootPath, objPkgFileSys
        Dim pkgType
        
        Set objPkgFileSys = New PkgArchive
        
        objPkgFileSys.Map_Network_Drive  UNC_ARCHIVE, MappedDrive       ' Map Drive if required
        
        pkgType = Get_Package_Type ( parPv_id )
        
        ' Is this package ERG PRODUCT
        objPkgFileSys.Remote_Host = TELNET_MACHINE
        If pkgType = enumPKG_TYPE_ERG_PRODUCT Then
                rootPath = MappedDrive & DEPLOY_ARCHIVE &"\"& parPkg_name &"\"& parPkg_Version
                objPkgFileSys.Archive_Path = TELNET_DEPLOY_ARCHIVE
                
        Else
                rootPath = MappedDrive & DPKG_ARCHIVE &"\"& parPkg_name &"\"& parPkg_Version
                objPkgFileSys.Archive_Path = TELNET_DPKG_ARCHIVE
                
        End If
        
        Set fileSys = CreateObject("Scripting.FileSystemObject") 
    
    ' Do this only if folder exists     
        If fileSys.FolderExists( rootPath ) Then
            objPkgFileSys.Ensure_Read_Write parPkg_name, parPkg_version         ' Make sure all files and folders can be read
            
            Call Write_To_Release_Notes_Info ( parPv_id, NULL )             ' Clean release notes info
        End If
        
End Sub
'-----------------------------------------------------------------------------------------------------------------
'-------------------- MAIN LINE ----------------------
WScript.Echo "==================== job:onMakeUnofficial ===================="

Set objArgs = WScript.Arguments

If (objArgs.Unnamed.Count > 0) Then
        Wscript.Echo "ERROR: Unnamed parameters!"
        objArgs.ShowUsage
        WScript.Quit
        
Else
        parPkg_name = objArgs.Named.Item("pkg_name")
        parPkg_Version = objArgs.Named.Item("pkg_version")
        parPv_id = objArgs.Named.Item("pv_id")
                
        If ( parPkg_name <> "" AND parPkg_Version <> "") Then
                Call Get_PV_ID ( parPkg_name, parPkg_Version, parPv_id )
                
        ElseIf parPv_id <> ""  Then
                Call Get_Pkg_Name_Version ( parPv_id, parPkg_name, parPkg_Version )
                
        Else
                objArgs.ShowUsage
                WScript.Quit
                
        End If
        
End If

Call onMakeUnofficial ( )

WScript.Echo "onMakeUnofficial finished successfully!"
]]>
                </script>
        </job>
</package>