Subversion Repositories DevTools

Rev

Blame | Last modification | View Log | RSS feed 

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|                ADMIN Page                         |
'|               Display Session Details             |
'|                                                   |
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0   ' always load the page, dont store
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_general.asp"-->
<%
'------------ Variable Definition -------------
Dim name, datatype, data
Dim active
Dim parServerReq

'------------ Constants Declaration -----------
'------------ Variable Init -------------------
active = objAccessControl.IsActive("MSMaintainer")
parServerReq = Request("detail")
'----------------------------------------------
%>
<html>
<head>
<title>Admin Session Variables</title>
<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link rel="stylesheet" href="images/release_manager_style.css" type="text/css">
<link rel="stylesheet" href="images/navigation.css" type="text/css">
<script language="JavaScript" src="images/common.js"></script>
<!-- DROPDOWN MENUS -->
<!--#include file="_menu_def.asp"-->
<script language="JavaScript1.2" src="images/popup_menu.js"></script>
<!-- StyleSheet Extensions -->
<style>
.pagebody {margin-left:auto; margin-right:auto; width:50%;border-width: 0px;border-spacing: 2px; background-color: rgb(255, 204, 0)}
.pagebody td{vertical-align: top;text-align: left;padding-left: 3px;padding-right: 3px; background: #f2f0e4}
.tablehdr td{background-color: rgb(255, 204, 0)}
</style>
</head>

<body bgcolor="#FFFFFF" text="#000000" leftmargin="0" topmargin="0" >
<!-- MENU LAYERS -------------------------------------->
<div id="popmenu" class="menuskin" onMouseover="clearhidemenu();highlightmenu(event,'on')" onMouseout="highlightmenu(event,'off');dynamichide(event)">
</div>
<!-- TIPS LAYERS -------------------------------------->
<div id="formTipsLayer" style="position: absolute; z-index: 1000; visibility: hidden; left:0; top: 0; width: 10">&nbsp;</div>
<!-- HEADER -->
<!--#include file="_header.asp"-->
<p>
<!-- Body of the page -->
<table class="pagebody">
   <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
      <tr class="body_col tablehdr">
      <td>Server Request Variables</td>
      <td>Value</td>
   </tr>
   <%If active Then %>
   <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->

   <%If parServerReq <> "" Then %>
   <%for each name in request.servervariables%>
   <tr class="body_row">
     <td> <%= name %></td>
     <td> <%= request.servervariables(name) %></td>
   </tr>
   <%Next%>
   <%Else%>
   <tr class="body_row">
     <td></td>
     <td>
       <a class="form_btn" href="admin_session_details.asp?detail=1" title="More Detail">Show</a>
     </td>
   </tr>
   <%End If%>
   <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
      <tr class="body_col tablehdr">
      <td>Session Variables</td>
      <td>Value</td>
   </tr>
   <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
   <%for each name in Session.Contents
       datatype = TypeName(Session(name)) & ":" & VarType(Session(name))
       If VarType(Session(name)) < 100 Then
           data  = Session(name)
       Else
           data = "Cannot be displayed"
       End If
    %>
   <tr class="body_row">
     <td> <%= name %></td>
     <td> [<%=datatype%>] : <%=data%></td>
   </tr>
   <%Next%>

   <tr class="body_row">
     <td>Timeout</td>
     <td><%=Session.Timeout%></td>
   </tr>
   <tr class="body_row">
     <td>SessionId</td>
     <td><%=Session.SessionId%></td>
   </tr>
   <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
   <tr class="body_col tablehdr">
      <td>Application Variables</td>
      <td>Value</td>
   </tr>
   <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->

   <%for each name in Application.Contents%>
   <tr class="body_row">
     <td><%= name %></td>
     <td><%= Application(name) %></td>
   </tr>
   <%Next%>
   <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
   <tr class="body_col tablehdr">
      <td colspan="2">
       <a class="form_btn" href="admin_session_details.asp" title="Refresh Page">Refresh</a>
       <a class="form_btn" href="admin_session_details.asp?detail=1" title="More Detail">More</a>
      </td>
   </tr>
   <%End If%>
</table>
 <p>
</body>
</html>
<!-- FOOTER -->
<!--#include file="_footer.asp"-->
<%
Call Destroy_All_Objects
%>