Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
Option explicit
Response.Expires = 0    ' always load the page, dont store
%>
<%
'=====================================================
'                                       Package Information
'=====================================================
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/common_dbedit.asp"-->
<!--#include file="common/_popup_window_common.asp"-->
<%
' Set rfile parameter. This is a return page after Login
Call objPMod.StoreParameter ( "rfile", "fixed_issues.asp" )
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_login.asp"-->
<!--#include file="_access_control_general.asp"-->
<!--#include file="_access_control_project.asp"-->
<%
'------------ Variable Definition -------------
Dim parPv_id
Dim query
Dim rsQry, rsTemp
Dim checked
Dim FRdeployableYES, FRdeployableNO
Dim objFormCollector
Dim pageIsEditable, criticalSectionIsEditable
Dim disableCriticalSectionEdit
Dim     Query_String
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
Set objFormCollector = CreateObject("Scripting.Dictionary")
parPv_id = QStrPar("pv_id")
'----------------------------------------------
%>
<%
Sub MessageBox()
%><script language="Javascript">
alert("You cannot select Generic with other BUILD MACHINE options!")
history.reload()


</script>
<%
End Sub
Sub Get_Form_Details( nPv_id, ByRef objDetails )
        Dim rsTemp, Query_String
        Query_String = _
        " SELECT pkg.pkg_name, pv.pkg_version, pv.pkg_label, pv.src_path, pv.pv_description, pv.pv_overview, pv.v_ext, is_deployable, is_build_env_required, pv.build_type, pv.bs_id, pv.dlocked "&_
        "  FROM package_versions pv, packages pkg"&_
        " WHERE pv.pkg_id = pkg.pkg_id"&_
        "   AND pv_id = "& nPv_id

        Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))
        If (NOT rsTemp.BOF ) AND (NOT rsTemp.EOF) Then
                objDetails.Item("pkg_name")             = rsTemp("pkg_name")
                objDetails.Item("pkg_version")          = rsTemp("pkg_version")
                objDetails.Item("pkg_label")            = rsTemp("pkg_label")
                objDetails.Item("src_path")             = rsTemp("src_path")
                objDetails.Item("pv_description")       = rsTemp("pv_description")
                objDetails.Item("pv_overview")          = rsTemp("pv_overview")
                objDetails.Item("v_ext")                        = rsTemp("v_ext")
                objDetails.Item("is_deployable")        = rsTemp("is_deployable")
                objDetails.Item("is_build_env_required")        = rsTemp("is_build_env_required")
                objDetails.Item("build_type")           = rsTemp("build_type")
                objDetails.Item("bs_id")                        = rsTemp("bs_id")
                objDetails.Item("dlocked")                      = rsTemp("dlocked")

        End If

        rsTemp.Close
        Set rsTemp = Nothing
End Sub

Sub Update_Pkg_Info ( NNpv_id, NNdeployable, SSLabel, SSPath, SSdesc, SSoverview )
        Dim rsTemp, Query_String
        Query_String = _
        " SELECT pkg_label, src_path, pv_description, pv_overview, is_deployable "&_
        " FROM package_versions"&_
        " WHERE pv_id = "& NNpv_id

        If SSdesc = "" Then SSdesc = NULL
        Set rsTemp = OraDatabase.CreateDynaset( Query_String, cint(0))

        rsTemp.Edit

        ' Only update build critical sections (label, source path) if allowed
        If criticalSectionIsEditable Then
                If (Request("FRlabelNA") <> "") Then
                        rsTemp.Fields("pkg_label").Value = "N/A"
                Else
                        rsTemp.Fields("pkg_label").Value = SSLabel
                End If

                rsTemp.Fields("src_path").Value = SSPath
        End If

        ' Update non-build critical sections
        rsTemp.Fields("pv_description").Value = SSdesc
        rsTemp.Fields("pv_overview").Value = SSoverview

        If NNdeployable = "1" Then
                rsTemp.Fields("is_deployable").Value = "Y"
        Else
                rsTemp.Fields("is_deployable").Value = NULL
        End If


        rsTemp.Update

        rsTemp.Close
        Set rsTemp = nothing


        '--- Build Env Update

        ' Only update build critical sections (label, source path) if allowed
        If criticalSectionIsEditable Then
                OraDatabase.Parameters.Add "PV_ID",             Request("pv_id"),       ORAPARM_INPUT, ORATYPE_NUMBER
                OraDatabase.Parameters.Add "BS_ID",             objFormCollector.Item("bs_id"),         ORAPARM_INPUT, ORATYPE_NUMBER
                If Request("be_id_req") <> "" Then
                        OraDatabase.Parameters.Add "BE_ID_LIST",                NULL,           ORAPARM_INPUT, ORATYPE_VARCHAR2
                Else
                        OraDatabase.Parameters.Add "BE_ID_LIST",                Request("be_id_list"),          ORAPARM_INPUT, ORATYPE_VARCHAR2
                End If





                OraSession.BeginTrans

                OraDatabase.ExecuteSQL _
                "BEGIN   Set_Package_Build_Env_Temp ( :PV_ID, :BE_ID_LIST, :BS_ID  );   END;"

                OraSession.CommitTrans



                '--- Set Build Types ---
                Dim aBuildEnvList
                Dim OraParameter
                Dim nBuildMachine

                If Request("be_id_req") = "" Then

                        OraDatabase.Parameters.Add "BSA_ID",    0,      ORAPARM_INPUT, ORATYPE_NUMBER
                        OraDatabase.Parameters.Add "BM_ID",             0,      ORAPARM_INPUT, ORATYPE_NUMBER

                        Set OraParameter = OraDatabase.Parameters


                        OraSession.BeginTrans


                        aBuildEnvList = Split( Replace( Request("be_id_list"), " ", "" ) , ",")



                        For Each nBuildMachine In aBuildEnvList

                                'Response.write nBuildEnv &"-"& Request("build_type_comb_"& nBuildEnv) &"<br>"


                                OraParameter("BSA_ID").Value = Request("build_type_comb_"& nBuildMachine)
                                OraParameter("BM_ID").Value = nBuildMachine


                                OraDatabase.ExecuteSQL _
                                " UPDATE PACKAGE_BUILD_INFO pbinfo SET "&_
                                "       pbinfo.BSA_ID = :BSA_ID "&_
                                " WHERE pbinfo.PV_ID = :PV_ID "&_
                                "   AND pbinfo.BM_ID = :BM_ID "



                        Next


                        OraSession.CommitTrans



                        OraSession.BeginTrans


                        aBuildEnvList = Split( Replace( Request("be_id_list"), " ", "" ) , ",")



                        For Each nBuildMachine In aBuildEnvList

                                'Response.write nBuildEnv &"-"& Request("build_type_comb_"& nBuildEnv) &"<br>"


                                OraParameter("BSA_ID").Value = Request("build_type_comb_"& nBuildMachine)
                                OraParameter("BM_ID").Value = nBuildMachine

                                If objFormCollector.Item("bs_id") = 2 Then
                                        If nBuildMachine= 1 Then
                                                OraParameter("BM_ID").Value = 11
                                        Else
                                                OraParameter("BM_ID").Value = 12
                                        End If
                                End If

                                OraDatabase.ExecuteSQL _
                                " UPDATE PACKAGE_BUILD_ENV pbe SET "&_
                                "       pbe.BUILD_TYPE = :BSA_ID "&_
                                " WHERE pbe.PV_ID = :PV_ID "&_
                                "   AND pbe.BE_ID = :BM_ID "
                        Next


                        OraSession.CommitTrans

                End If


                OraDatabase.Parameters.Remove "PV_ID"
                OraDatabase.Parameters.Remove "BE_ID_LIST"
        End If
End Sub
'----------------------------------------------------------------------------------------------------------------------
Function IsBuildTypeSelected ( nBuildTypeValue, nComboItem )

        IsBuildTypeSelected = ""

        If IsNull(nBuildTypeValue) OR (nBuildTypeValue = "") Then  Exit Function

        If ( CInt(nComboItem) = CInt(nBuildTypeValue) ) Then
                IsBuildTypeSelected = "selected"
        End If

End Function
'----------------------------------------------------------------------------------------------------------------------
Function ShowHideBuildType( sBuildEnvChecked )

        ShowHideBuildType = "style='display:none;'"

        If (sBuildEnvChecked <> "") Then
                ShowHideBuildType = "style='display:block;'"
        End If

End Function
'----------------------------------------------------------------------------------------------------------------------
Sub RenderBuildTypeCombo( nBuildAddendum, nBuildMachine, nBuildStandard )

        If nBuildStandard = 1 Then
                Query_String = "SELECT * FROM build_standards_addendum WHERE bs_id = 1 ORDER BY bsa_id DESC"
        Else
                Query_String = "SELECT * FROM build_standards_addendum WHERE bs_id = 2 ORDER BY bsa_id DESC"
        End If

        Response.Write "<select name='build_type_comb_"& nBuildMachine &"' class='form_item'"& disableCriticalSectionEdit &">"

        Set rsTemp = OraDatabase.CreateDynaset( Query_String, cint(0))
        While (NOT rsTemp.BOF) AND (NOT rsTemp.EOF)

        If nBuildAddendum = rsTemp.Fields("bsa_id") Then
                Response.write "<option value='"& rsTemp.Fields("bsa_id") &"' selected>"& rsTemp.Fields("bsa_name") &"</option>"
        Else
                Response.write "<option value='"& rsTemp.Fields("bsa_id") &"'>"& rsTemp.Fields("bsa_name") &"</option>"
        End If
        rsTemp.MoveNext
        WEnd

        rsTemp.Close()
        Set rsTemp = nothing


        Response.Write "</select>"
End Sub
'----------------------------------------------------------------------------------------------------------------------
Function GetRowColor( sRowColor )
        If sRowColor = "#FFFFFF" Then
                GetRowColor = "#F5F5F5"
        Else
                GetRowColor = "#FFFFFF"
        End If
End Function
%>
<%
'------------------------------- RUN BEFORE PAGE RENDER ----------------------------
Call LoadFieldRules ( "'FRlabel','FRpath','pv_description','pv_overview','be_id_list'", objForm )               ' Load Validation Rules
Call Get_Form_Details( parPv_id, objFormCollector )

'--- From Validation Rule Changes ----
If objForm.IsPostBack Then
        If (Request("FRlabelNA") = "Y") Then
                objForm.UpdateRules ("id='FRlabel' IsRequired='N'")
        End If

        If (Request("be_id_req") = "N") Then
                objForm.UpdateRules ("id='be_id_list' IsRequired='N'")
        End If

Else
        If objFormCollector.Item("pkg_label") = "N/A" Then
                objForm.UpdateRules ("id='FRlabel' IsRequired='N'")
        End If

        If objFormCollector.Item("is_build_env_required") = "N" Then
                objForm.UpdateRules ("id='be_id_list' IsRequired='N'")
        End If

End If

If NOT criticalSectionIsEditable Then
        objForm.UpdateRules ("id='FRlabel' IsRequired='N'")
        objForm.UpdateRules ("id='FRpath' IsRequired='N'")
        objForm.UpdateRules ("id='be_id_list' IsRequired='N'")
End If


'--- Access Control Setup ------------
pageIsEditable = Is_Page_Editable ( objFormCollector.Item ("dlocked") )
criticalSectionIsEditable = Is_Critical_Section_Editable ( objFormCollector.Item("dlocked") )

If criticalSectionIsEditable then
        disableCriticalSectionEdit = ""
Else
        disableCriticalSectionEdit = "disabled"
End If


'--- Process Submission ---------------
If CBool(QStrPar("action"))  AND  objAccessControl.UserLogedIn Then
        If objForm.IsValidOnPostBack Then
                Dim aBuildEnvList, nBuildEnv, display
                display = false
                aBuildEnvList = Split( Replace( Request("be_id_list"), " ", "" ) , ",")

                If UBound(aBuildEnvList) > 0 Then
                        If aBuildEnvList(0) = "4" Then
                                display = true
                        End If
                End If


                For Each nBuildEnv In aBuildEnvList
                        If Request("build_type_comb_"& nBuildEnv) = 0 Then
                                display = true
                        End If
                Next

                If display then
                        Call MessageBox()
                Else
                        Call Update_Pkg_Info ( parPv_id, QStrPar("FRdeployable"), QStrPar("FRlabel"), QStrPar("FRpath"), QStrPar("pv_description"), QStrPar("pv_overview") )
                        Call OpenInParentWindow ( "fixed_issues.asp?pv_id="& parPv_id &"&rtag_id="& parRtag_id &"&hidenv=true" )
                        Call CloseWindow
                End If
        End If



End If
'--------------------------------------------------------------------------------------------
%>
<html>
<head>
<title>Release Manager</title>
<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link rel="stylesheet" href="images/release_manager_style.css" type="text/css">
<link rel="stylesheet" href="images/navigation.css" type="text/css">
<script language="JavaScript" src="images/common.js"></script>
<!-- TIPS -->
<script language="JavaScript" src="images/tipster.js"></script>
<script language="JavaScript" src="images/_help_tips.js"></script>
<script language="JavaScript" type="text/javascript">
<!--
function SetLabel(slabel) {
        if ( MM_findObj('FRlabelNA').checked ) {

                MM_findObj('FRlabel').value = 'N/A';
                MM_findObj('FRlabel').disabled = true;
        } else {
                MM_findObj('FRlabel').value = slabel;
                MM_findObj('FRlabel').disabled = false;
        }

}
//-->
</script>
</head>
<body bgcolor="#FFFFFF" text="#000000" leftmargin="0" topmargin="0" onload="self.focus();">
<!-- TIPS LAYERS -------------------------------------->
<div id="formTipsLayer" style="position: absolute; z-index: 1000; visibility: hidden; left:0; top: 0; width: 10">&nbsp;</div>
<!----------------------------------------------------->
<form name="pkginfo" method="post" action="<%=scriptName%>">
  <table width="100%" border="0" cellspacing="0" cellpadding="2" height="100%">
    <tr>
      <td background="images/lbox_bg_orange.gif" width="1%" height="1%"><img src="images/s_info_off.gif" width="21" height="21" hspace="5" border="0"></td>
      <td background="images/lbox_bg_blue.gif" nowrap width="50%" class="wform_ttl">&nbsp;Package Information </td>
      <td background="images/lbox_bg_blue.gif" align="right" width="50%">
        <input type="submit" name="btn" value="Submit" <%If pageIsEditable Then%>class="form_btn_comp"<%Else%>disabled class="form_btn_comp_disabled"<%End If%>>
        <input type="reset" name="btn" value="Cancel" class="form_btn_comp" onclick="self.close()">
      </td>
      <td background="images/lbox_bg_blue.gif" align="right" width="1%" nowrap>
        <img src="images/h_trsp_dot.gif" width="5" height="22"> </td>
    </tr>
    <tr>
      <td height="100%" width="1%">&nbsp;</td>
      <td valign="top" nowrap colspan="3" class="wform_ttl" background="images/bg_form_lightgray.gif">
        <table width="100%" border="0" cellspacing="1" cellpadding="2">
          <tr>
            <td width="1%"><img src="images/h_trsp_dot.gif" width="10" height="30"></td>
            <td width="1%" nowrap class="form_group" valign="bottom"></td>
            <td nowrap width="1%">&nbsp; </td>
            <td nowrap width="100%">&nbsp;</td>
          </tr>
          <tr>
            <td>&nbsp;</td>
            <td nowrap class="form_field" background="images/bg_form_lightbluedark.gif">Package</td>
            <td nowrap background="images/bg_form_lightbluedark.gif" class="form_txt"><%=objFormCollector.Item("pkg_name") &" "& objFormCollector.Item("pkg_version")%></td>
            <td valign="top" nowrap background="images/bg_form_lightbluedark.gif" class="form_txt">&nbsp;</td>
          </tr>
          <tr>
            <td>&nbsp;</td>
            <td nowrap class="form_field" background="images/bg_form_lightbluedark.gif">Deployable?<%=Quick_Help ( "deployable" )%></td>
                        <%
                        FRdeployableYES = ""
                        FRdeployableNO = ""

                        If objForm.IsPostBack Then
                                If Request("FRdeployable") = "1" Then
                                        FRdeployableYES = "checked"
                                Else
                                        FRdeployableNO = "checked"
                                End If

                        Else
                                If objFormCollector.Item("is_deployable") = enumDB_YES Then
                                        FRdeployableYES = "checked"
                                Else
                                        FRdeployableNO = "checked"
                                End If

                        End If
                        %>
            <td nowrap background="images/bg_form_lightbluedark.gif" class="form_txt">Yes<input name="FRdeployable" type="radio" value="1" <%=FRdeployableYES%>>
              &nbsp;&nbsp;No<input name="FRdeployable" type="radio" value="0" <%=FRdeployableNO%>></td>
            <td valign="top" nowrap background="images/bg_form_lightbluedark.gif" class="form_txt">&nbsp;</td>
          </tr>
          <tr>
            <td>&nbsp;</td>
            <td nowrap background="images/bg_form_lightbluedark.gif" class="form_field">Label<%=Quick_Help ( "pkg_label" )%></td>
            <td nowrap background="images/bg_form_lightbluedark.gif" class="form_txt">
                        <%
                        Dim sDefaultLabel, sLabel, sLabelDisabled, sLabelChecked, sLabelReadOnly
                        sLabelDisabled = ""
                        sLabelChecked = ""
                        sLabelReadOnly = ""
                        sDefaultLabel = Default_Label( objFormCollector.Item("pkg_name"), objFormCollector.Item("pkg_version"), objFormCollector.Item("v_ext"))

                        If objFormCollector.Item("build_type") = "A" AND NOT criticalSectionIsEditable Then
                                sLabelReadOnly = "readonly"
                        End If

                        If objForm.IsPostBack Then
                                If (Request("FRlabelNA") <> "") Then
                                        sLabelDisabled = "disabled"
                                        sLabelChecked = "checked"
                                        sLabel = "N/A"
                                Else
                                        sLabel = Request("FRlabel")
                                End If

                        Else
                                If (objFormCollector.Item("pkg_label") = "N/A") Then
                                        sLabelDisabled = "disabled"
                                        sLabelChecked = "checked"
                                        sLabel = "N/A"
                                Else
                                        If objFormCollector.Item("pkg_label") = "" OR IsNull(objFormCollector.Item("pkg_label"))  Then
                                                sLabel = sDefaultLabel
                                        Else
                                                sLabel = objFormCollector.Item("pkg_label")
                                        End If
                                        objForm.SetValue "FRlabel", sLabel

                                End If

                        End If


                        %>
                        <%If objFormCollector.Item("build_type") = "M" AND criticalSectionIsEditable Then%>
                        <input name="FRlabelNA" type="checkbox" id="FRlabelNA" value="Y" <%=disableCriticalSectionEdit%> onClick="SetLabel('<%=sDefaultLabel%>');" <%=sLabelChecked%>> Label not applicable<br>
                        <%End If%>
                        <input type="text" name="FRlabel" id="FRlabel" maxlength="50" size="60" class="form_item" <%=disableCriticalSectionEdit%> value="<%=sLabel%>" <%=sLabelDisabled%> <%=sLabelReadOnly%>>
            </td>
            <td valign="top" nowrap background="images/bg_form_lightbluedark.gif" class="form_txt"><%=objForm.Validate ("FRlabel")%></td>
          </tr>
          <tr>
            <td>&nbsp;</td>
            <td valign="top" nowrap background="images/bg_form_lightbluedark.gif" class="form_field">Source Path<%=Quick_Help ( "src_path" )%></td>
            <td nowrap background="images/bg_form_lightbluedark.gif" class="form_txt">
              <input name="FRpath" type="text" class="form_item" <%=disableCriticalSectionEdit%> id="FRpath" value="<%=objForm.GetValue( "FRpath", objFormCollector.Item("src_path") )%>" size="60" maxlength="2000">
              <br>
              Example:<br>
              \MASS_Dev\Infra\core_cs <br>
               </td>
            <td valign="top" nowrap background="images/bg_form_lightbluedark.gif" class="form_txt"><%=objForm.Validate ("FRpath")%>
                        </td>
          </tr>
          <tr>
            <td>&nbsp;</td>
            <td valign="top" background="images/bg_form_lightbluedark.gif" class="form_field">Short
              Package Description<%=Quick_Help ( "pkg_info_short_desc" )%></td>
            <td valign="top" nowrap background="images/bg_form_lightbluedark.gif" class="form_txt"><textarea name="pv_description" cols="57" rows="5" class="form_item" id="pv_description"><%=objForm.GetValue( "pv_description", objFormCollector.Item("pv_description") )%></textarea>
            </td>
            <td valign="top" nowrap background="images/bg_form_lightbluedark.gif" class="form_txt"><%=objForm.Validate ("pv_description")%></td>
          </tr>
          <tr>
            <td>&nbsp;</td>
            <td valign="top" background="images/bg_form_lightbluedark.gif" class="form_field">Package Overview<%=Quick_Help ( "pkg_info_overview" )%></td>
            <td valign="top" nowrap background="images/bg_form_lightbluedark.gif" class="form_txt"><textarea name="pv_overview" cols="57" rows="10" class="form_item" id="pv_overview"><%=objForm.GetValue( "pv_overview", objFormCollector.Item("pv_overview") )%></textarea>
            </td>
            <td valign="top" nowrap background="images/bg_form_lightbluedark.gif" class="form_txt"><%=objForm.Validate ("pv_overview")%></td>
          </tr>

          <tr>
            <td>&nbsp;</td>
            <td valign="top" nowrap background="images/bg_form_lightbluedark.gif" class="form_field">Build Environment<%=Quick_Help ( "build_environment" )%></td>
            <td nowrap background="images/bg_form_lightbluedark.gif" class="form_txt">
                        <%
                        checked = ""
                        If objForm.IsPostBack Then
                                If (Request("be_id_req") = "N") Then checked = "checked"
                        Else
                                If objFormCollector.Item("is_build_env_required") = "N" Then checked = "checked"
                        End If
                        %>
                        <%If objFormCollector.Item("is_build_env_required") = "N" Then%>
                                <input type="checkbox" name="be_id_req" value="N" <%=disableCriticalSectionEdit%> onClick="ToggleDisplay('divBuildEnv');" <%=checked%>>&nbsp;Build Environment not applicable
                        <%End If%>
                        <div id="divBuildEnv" name="divBuildEnv" style="width:320px; height:150px; overflow: auto; <%If (Request("be_id_req") = "N") OR (objFormCollector.Item("is_build_env_required") = "N") Then%>display:none;<%Else%>display:block;<%End If%>">
                          <table width="100%" border="0" cellspacing="0" cellpadding="0">
                                <tr>
                                  <td bgcolor="#FFFFFF">
                                   <table width="100%" border="0" cellspacing="0" cellpadding="3">
                                   <%
                                   OraDatabase.Parameters.Add "PV_ID",  parPv_id,       ORAPARM_INPUT, ORATYPE_NUMBER

                                   query = _
                                    " SELECT DECODE ( pkgbinfo.BM_ID,"&_
                                    "                                   bm.BM_ID, 'checked',"&_
                                        "                               NULL ) AS checked,"&_
                                        "          bm.BM_ID,"&_
                                        "          bm.BM_NAME, "&_
                                        "          pkgbinfo.BSA_ID"&_
                                        "  FROM BUILD_MACHINES bm,"&_
                                        "          PACKAGE_BUILD_INFO pkgbinfo"&_
                                        " WHERE pkgbinfo.BM_ID (+)= bm.BM_ID"&_
                                        "   AND pkgbinfo.PV_ID (+)= :PV_ID"&_
                                        " ORDER BY UPPER(bm.bm_name) "


                                   Set rsQry = OraDatabase.DbCreateDynaset( query, cint(0))
                                   Dim rowColor

                                   rowColor = "#F5F5F5"

                                   While (NOT rsQry.BOF) AND (NOT rsQry.EOF)
                                          checked = ""
                                      If objForm.IsTicked( "be_id_list", rsQry("bm_id"), rsQry("checked") ) Then
                                                  checked = "checked"
                                              objForm.SetValue "be_id_list", checked
                                          End If

                                          rowColor = GetRowColor( rowColor )
                                   %>
                                        <tr>
                                          <td nowrap class="form_txt" bgcolor="<%=rowColor%>"><input type="checkbox" name="be_id_list" onClick="ToggleDisplay('build_type_<%=rsQry("bm_id")%>');" <%=disableCriticalSectionEdit%> value="<%=rsQry("bm_id")%>" <%=checked%>></td>
                                          <td nowrap class="form_txt" bgcolor="<%=rowColor%>"><%=rsQry("bm_name")%></td>
                                          <td nowrap class="form_txt" bgcolor="<%=rowColor%>"><div id="build_type_<%=rsQry("bm_id")%>" <%=ShowHideBuildType( checked )%>><% Call RenderBuildTypeCombo( rsQry("bsa_id"), rsQry("bm_id"), objFormCollector.Item("bs_id") )%></div></td>
                                          <%If checked = "checked" AND rsQry("bsa_id") = 0 Then%>
                                          <td valign="top" nowrap background="images/bg_form_lightbluedark.gif" class="form_txt"><td background='images/red_dot.gif'><img src='images/spacer.gif' width='1' height='1'></td><td valign='top'><img src='icons/i_bulet_red.gif' width='4' height='4' hspace='3' vspace='4' border='0' align='absmiddle'></td><td class='val_err'>Required</td></td>
                                          <%End If%>
                                        </tr>
                                   <%rsQry.MoveNext
                                   WEnd

                                   rsQry.Close
                                   Set rsQry = Nothing

                                   OraDatabase.Parameters.Remove "PV_ID"
                                   %>
                                   <tr>
                                          <td width="1"></td>
                                          <td width="1"></td>
                                          <td width="100%"></td>
                                        </tr>
                                  </table></td>
                                </tr>
                          </table>
                        </div>
                        </td>
            <td valign="top" nowrap background="images/bg_form_lightbluedark.gif" class="form_txt"><%=objForm.Validate("be_id_list")%></td>
          </tr>
          <tr>
            <td>&nbsp;</td>
            <td nowrap class="form_field"><img src="images/h_trsp_dot.gif" width="100" height="10"></td>
            <td nowrap> <p>&nbsp;</p></td>
            <td nowrap>&nbsp;</td>
          </tr>
        </table>
      </td>
    </tr>
    <tr>
      <td height="1%" width="1%"><img src="images/h_trsp_dot.gif" width="5" height="5"></td>
      <td valign="top" nowrap colspan="3" class="wform_ttl" background="images/lbox_bg_blue.gif"></td>
    </tr>
  </table>
<input type="hidden" name="pv_id" value="<%=parPv_id%>">
<input type="hidden" name="rtag_id" value="<%=parRtag_id%>">
<input type="hidden" name="action" value="true">
</form>
</body>
</html>
<%
'------------- RUN AFTER PAGE RENDER ---------------
Set objFormCollector = Nothing
'---------------------------------------------------
%>

<!-- DESTRUCTOR ------->
<!--#include file="common/destructor.asp"-->