Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
Option explicit
Response.Expires = 0   ' always load the page, dont store
%>
<%
'=====================================================
'               System Lock Package
'=====================================================
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/common_dbedit.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_general.asp"-->
<%
'------------ Variable Definition -------------
Dim parPv_id
Dim QueryString, rsQry
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
parPv_id = QStrPar("pv_id")
parRtag_id = QStrPar("rtag_id")
'----------------------------------------------
%>
<%
Sub LockPackage ()

   OraDatabase.Parameters.Add "PV_ID",   Request("pv_id"),        ORAPARM_INPUT, ORATYPE_NUMBER
   OraDatabase.Parameters.Add "USER_ID", objAccessControl.UserId, ORAPARM_INPUT, ORATYPE_NUMBER

   objEH.TryORA ( OraSession )
   On Error Resume Next

   OraDatabase.ExecuteSQL _
   "BEGIN  Lock_Package( :PV_ID, :USER_ID );  END;"

   objEH.CatchORA ( OraSession )

   OraDatabase.Parameters.Remove "PV_ID"
   OraDatabase.Parameters.Remove "USER_ID"
End Sub

%>
<%
'Process submition
'---------------------------------------
' THIS IS FOR SYSTEM ADMIN ONLY
'---------------------------------------
QueryString = "SELECT pv.DLOCKED, pv.IS_PATCH FROM PACKAGE_VERSIONS pv WHERE pv.PV_ID = "& parPv_id
Set rsQry = OraDatabase.DbCreateDynaset( QueryString, cint(0))
If IsNull(rsQry("is_patch")) Then
   Call RaiseMsg(enum_MSG_ERROR, "Only patches can be locked by this function." )
Else
   If objAccessControl.IsDataActive ("PROJECTS", DB_PROJ_ID, "EditProjects") AND (objAccessControl.IsActive("UnlockPatch"))  Then
      If rsQry("dlocked") = "N" Then
         Call LockPackage ()
         Response.Redirect ( "_generate_release_notes.asp?rfile=dependencies.asp&pv_id="& parPv_id &"&rtag_id="& parRtag_id )
      Else
         Call RaiseMsg(enum_MSG_ERROR, "Can only lock a patch that is currently unlocked." )
      End If
   Else
      Call RaiseMsg(enum_MSG_ERROR, "You do not have permissions to lock/unlock patches." )
   End If
End If
rsQry.Close
Set rsQry = nothing
%>

<!-- DESTRUCTOR ------->
<!--#include file="common/destructor.asp"-->