Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'                                  REMOVE Build Dependency
'               --- PROCESS FORM ---
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0    ' always load the page, dont store
%>

<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/common_dbedit.asp"-->
<%
objPMod.PersistInQryString ( aPersistList(enumPAR_DPV_ID) )

' Set rfile parameter. This is a return page after Login
Call objPMod.StoreParameter ( "rfile", "dependencies.asp" )
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_login.asp"-->
<!--#include file="_access_control_general.asp"-->
<!--#include file="_access_control_project.asp"-->
<%
'------------ Variable Definition -------------
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
'----------------------------------------------
%>
<%
Sub Remove_Build_Dependency( NNpv_id, NNdpv_id )
        Dim description, Query_String, rsTemp

        Query_String = _
        " SELECT dpkg.pkg_name, dpv.pkg_version"&_
        "  FROM package_versions dpv,"&_
        "       packages dpkg"&_
        " WHERE dpv.pkg_id = dpkg.pkg_id"&_
        "   AND dpv.pv_id = "& NNdpv_id
        
        Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))
        description = rsTemp("pkg_name") &" "& rsTemp("pkg_version")
        
        OraDatabase.Parameters.Add "PV_ID",                     NNpv_id,        ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "DPV_ID",                    NNdpv_id,       ORAPARM_INPUT, ORATYPE_NUMBER
        OraDatabase.Parameters.Add "RTAG_ID",                   Request("rtag_id"),     ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "USER_ID",                   objAccessControl.UserId, ORAPARM_INPUT, ORATYPE_VARCHAR2
        OraDatabase.Parameters.Add "DESCRIPTION",               description, ORAPARM_INPUT, ORATYPE_VARCHAR2
        OraDatabase.Parameters.Add "ACTION_TYPE_NAME",  "depend_remove", ORAPARM_INPUT, ORATYPE_VARCHAR2
        
        
        
        OraSession.BeginTrans
        
        OraDatabase.ExecuteSQL _
        "DELETE FROM package_dependencies WHERE  pv_id = :PV_ID  AND  dpv_id = :DPV_ID"
        
        OraDatabase.ExecuteSQL _
        "BEGIN  Log_Action ( :PV_ID, :ACTION_TYPE_NAME, :USER_ID, :DESCRIPTION );  END;"                
        
        OraDatabase.ExecuteSQL _
        "BEGIN "&_
        " Touch_Release ( :RTAG_ID ); "&_
        "END; "
        
        OraSession.CommitTrans
        
        
        
        
        OraDatabase.Parameters.Remove "PV_ID"
        OraDatabase.Parameters.Remove "PATCH_ID"
        OraDatabase.Parameters.Remove "RTAG_ID"
        OraDatabase.Parameters.remove "USER_ID"
        OraDatabase.Parameters.remove "DESCRIPTION"
        OraDatabase.Parameters.remove "ACTION_TYPE_NAME"
End Sub
%>
<%
'-----------------------  MAIN LINE  ---------------------------

'--- Process submition ---
If (Request("pv_id") <> "") AND (Request("dpv_id") <> "") Then
        ' All mendatory parameters FOUND
        Call Remove_Build_Dependency( Request("pv_id"), Request("dpv_id") )
        
        Response.Redirect("dependencies.asp?pv_id="& QStrPar("pv_id") &"&rtag_id="& Request("rtag_id"))
Else
        Response.write "Some mendatory parameters are missing!" & "<br>" 'TODO
        Response.write QSTR_All 
End If
%>

<!-- DESTRUCTOR ------->
<!--#include file="common/destructor.asp"-->