Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'                                   MAKE PENDING
'               --- PROCESS FORM ---
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0    ' always load the page, dont store
%>

<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/common_dbedit.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_login.asp"-->
<!--#include file="_access_control_general.asp"-->
<!--#include file="_access_control_project.asp"-->
<%
'------------ Variable Definition -------------
Dim parPv_id
Dim parRfile
Dim retERRmsg
Dim retALRTmsg
Dim retParameters
Dim pkgType
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
parPv_id = Request("pv_id")
parRfile = Request("rfile")
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
'----------------------------------------------
%>
<%
Sub MakePending ()
        Dim objWSH
        Set objWSH = Server.CreateObject("WScript.Shell")
        
        
        OraDatabase.Parameters.Add "PV_ID",             Request("pv_id"),       ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "RTAG_ID",           Request("rtag_id"),     ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "USER_ID",           objAccessControl.UserId,        ORAPARM_INPUT, ORATYPE_NUMBER 
        
        
        OraSession.BeginTrans
        
        OraDatabase.ExecuteSQL " UPDATE package_versions "&_
                                                   " SET owner_id = :USER_ID"&_
                                                   " WHERE pv_id = :PV_ID"

        OraDatabase.ExecuteSQL _
        "BEGIN "&_
        " PK_ENVIRONMENT.MAKE_PENDING ( :PV_ID, :RTAG_ID, :USER_ID ); "&_
        "END; "
        
        OraSession.CommitTrans
        
        
        OraDatabase.Parameters.Remove "PV_ID"
        OraDatabase.Parameters.Remove "RTAG_ID"
        OraDatabase.Parameters.Remove "USER_ID"
        
        objWSH.Run   "cmd.exe /c cscript.exe //B //NoLogo "& rootPath & SCRIPTS_FOLDER &"\on_Make_Official.wsf //job:GetComponents //job:PostRun "&_
                 "/pv_id:"& Request("pv_id") , _
                 0, False 
                                 
        
End Sub
%>
<%
'-----------------------  MAIN LINE  ---------------------------

'--- Process submition ---
If ( Request("rtag_id") <> "") AND (Request("pv_id") <> "") Then
        
        Call CheckRequirementsForMakePending ( parPv_id, parRtag_id, pkgType, retERRmsg, retALRTmsg, retParameters )
        
        If IsNull(retERRmsg) Then
                ' All Requirements OK
                'COMPLETE THE REQUEST...
                Call MakePending ( )
                
                If Request("rfile") <> "" Then
                        Response.Redirect ( Request("rfile") &"?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id") )
                Else
                        Response.Redirect ( "dependencies?pv_id="& Request("pv_id") &"&rtag_id="& Request("rtag_id") )
                End If
                
        Else
                Call RaiseMsg ( Eval(retERRmsg), parRtag_id &"|"& parPv_id      &"|"& retParameters &"|"& "N" )
                
        End If
        
Else
        Response.write "Some mendatory parameters are missing!" & "<br>" 'TODO
        Response.write QSTR_All 
End If
%>

<!-- DESTRUCTOR ------->
<!--#include file="common/destructor.asp"-->