Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|                      REPORT                       |
'|                      Escrow                       |
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0   ' always load the page, dont store
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_dbedit.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_general.asp"-->
<%
'------------ Variable Definition -------------
Dim rsQry
Dim rsTemp
Dim parPv_id, parExt
Dim objReleaseContent
Dim aReleaseContent
Dim objPackageDetails
Dim BldStd
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
parRtag_id = Request("rtag_id")
parExt = Request("ext")
Set objReleaseContent = CreateObject("Scripting.Dictionary")
Set objPackageDetails = CreateObject("Scripting.Dictionary")
'----------------------------------------------
%>
<%
'----------------------------------------------------------------------------------------------------------------------------------------
Sub GetPackageInformation ( nPv_id, ByRef oPackageDetails )
   Dim rsQry, query
   query = _
   " SELECT pkg.pkg_name, pv.* "&_
   "   FROM PACKAGES pkg,"&_
   "        PACKAGE_VERSIONS pv"&_
   "  WHERE pv.pv_id = "& nPv_id &_
   "    AND pv.pkg_id = pkg.pkg_id   "

   Set rsQry = OraDatabase.DbCreateDynaset( query, 0)

   oPackageDetails.RemoveAll

   If (NOT rsQry.BOF) AND (NOT rsQry.EOF) Then
      oPackageDetails("pkg_name") = rsQry("pkg_name")
      oPackageDetails("pkg_version") = rsQry("pkg_version")
      oPackageDetails("v_ext") = rsQry("v_ext")
      oPackageDetails("pv_description") = rsQry("pv_description")
      oPackageDetails("pv_overview") = rsQry("pv_overview")
      oPackageDetails("src_path") = rsQry("src_path")
      oPackageDetails("pkg_label") = rsQry("pkg_label")
      oPackageDetails("is_build_env_required") = rsQry("is_build_env_required")

   End If

   rsQry.Close()
   Set rsQry = Nothing
End Sub
'----------------------------------------------------------------------------------------------------------------------------------------
Function SQL_Build_Std ( nPv_id )
   SQL_Build_Std = _
   " SELECT bs.bs_name"&_
   "   FROM RELEASE_MANAGER.PACKAGE_VERSIONS pv,"&_
   "        RELEASE_MANAGER.BUILD_STANDARDS bs"&_
   "  WHERE pv.PV_ID = "& nPv_id &_
   "    AND pv.BS_ID = bs.BS_ID "
End Function
'----------------------------------------------------------------------------------------------------------------------------------------
Function SQL_Build_Env ( nPv_id )
   SQL_Build_Env = _
   " SELECT bm.bm_name"&_
   "  FROM  RELEASE_MANAGER.PACKAGE_BUILD_INFO pbi,"&_
   "        RELEASE_MANAGER.BUILD_MACHINES bm"&_
   "  WHERE pbi.PV_ID = "& nPv_id &_
   "    AND pbi.BM_ID = bm.BM_ID "&_
   "  ORDER BY UPPER(bm.BM_NAME) "
End Function
'----------------------------------------------------------------------------------------------------------------------------------------
Function SQL_Build_Dependencies ( nPv_id )
   SQL_Build_Dependencies = _
   " SELECT dpkg.pkg_name, dpv.pkg_version"&_
   "   FROM PACKAGE_DEPENDENCIES dep,"&_
   "        PACKAGES dpkg,"&_
   "        PACKAGE_VERSIONS dpv"&_
   "  WHERE dep.pv_id = "& nPv_id &_
   "    AND dep.DPV_ID = dpv.pv_id"&_
   "    AND dpv.pkg_id = dpkg.pkg_id   "&_
   " ORDER BY UPPER(dpkg.pkg_name) "
End Function
'----------------------------------------------------------------------------------------------------------------------------------------
Sub GetReleaseContent ( nRtag_id, ByRef oReleaseContent )
   Dim rsQry, query
   query = _
   " SELECT qry.pv_id"&_
   "  FROM ("&_
   "      SELECT pv.pv_id, pkg.pkg_name, pv.pkg_version, 1 AS seq_num"&_
   "        FROM RELEASE_CONTENT rc,"&_
   "             PACKAGES pkg,"&_
   "             PACKAGE_VERSIONS pv"&_
   "       WHERE rc.rtag_id = "& nRtag_id  &_
   "         AND pv.pkg_id = pkg.pkg_id"&_
   "         AND rc.pv_id = pv.pv_id"&_
   "         AND rc.BASE_VIEW_ID = 5  "&_
   "      UNION   "&_
   "      SELECT pv.pv_id, pkg.pkg_name, pv.pkg_version, 2 AS seq_num"&_
   "        FROM RELEASE_CONTENT rc,"&_
   "             PACKAGES pkg,"&_
   "             PACKAGE_VERSIONS pv"&_
   "       WHERE rc.rtag_id = "& nRtag_id &_
   "         AND pv.pkg_id = pkg.pkg_id"&_
   "         AND rc.pv_id = pv.pv_id"&_
   "         AND rc.BASE_VIEW_ID != 5"&_
   "      ) qry  "&_
   " ORDER BY qry.seq_num, UPPER(qry.pkg_name)"

   Set rsQry = OraDatabase.DbCreateDynaset( query, 0)

   While (NOT rsQry.BOF) AND (NOT rsQry.EOF)
      oReleaseContent( CStr( rsQry("pv_id")) ) = ""
      rsQry.MoveNext()
   WEnd

   rsQry.Close()
   Set rsQry = Nothing
End Sub
'----------------------------------------------------------------------------------------------------------------------------------------

%>
<%
'---------------------- Run Before Page ---------------------------
Call GetReleaseContent ( parRtag_id, objReleaseContent )
'------------------------------------------------------------------
%>
<html>
<head>
<title>Release Manager</title>
<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
</head>
<body>

<%
aReleaseContent = objReleaseContent.Keys
For Each parPv_id In aReleaseContent
   Response.Flush
   Call GetPackageInformation ( parPv_id, objPackageDetails )
   %>
   <a name="<%=objPackageDetails.Item("pkg_name")%>"></a>
   <table width="100%" border="0" cellspacing="0" cellpadding="0">
      <tr>
         <td class="body_colb"><h3><%=objPackageDetails.Item("pkg_name")%></h3></td>
      </tr>
   </table>
   <table width="100%" border="0" cellspacing="0" cellpadding="0">
      <tr>
         <td nowrap bgcolor="#FFFFFF" class="sublbox_txt" valign="top"><strong>Version:</strong></td>
         <td bgcolor="#FFFFFF" class="sublbox_txt"><%=objPackageDetails.Item("pkg_version")%></td>
      </tr>
      <tr>
         <td nowrap bgcolor="#FFFFFF" class="sublbox_txt" valign="top"><strong>Source Path:</strong> </td>
         <td bgcolor="#FFFFFF" class="sublbox_txt"><%=objPackageDetails.Item("src_path")%></td>
      </tr>
      <tr>
         <td nowrap bgcolor="#FFFFFF" class="sublbox_txt" valign="top"><strong>Source Label:</strong></td>
         <td bgcolor="#FFFFFF" class="sublbox_txt"><%=objPackageDetails.Item("pkg_label")%></td>
      </tr>
      <tr>
         <td width="1%" nowrap bgcolor="#FFFFFF" class="sublbox_txt" valign="top"><strong>Short Description:</strong></td>
         <td witdh="100%" bgcolor="#FFFFFF" class="sublbox_txt"><%=NewLine_To_BR ( To_HTML( objPackageDetails.Item("pv_description") ) )%></td>
      </tr>
      <tr>
         <td nowrap bgcolor="#FFFFFF" class="sublbox_txt" valign="top"><strong>Package Overview:</strong> </td>
         <td bgcolor="#FFFFFF" class="sublbox_txt"><%=NewLine_To_BR ( To_HTML( objPackageDetails.Item("pv_overview") ) )%></td>
      </tr>
      <tr>
         <td nowrap bgcolor="#FFFFFF" class="sublbox_txt" valign="top"><strong>General Sublicense Material:</strong> </td>
         <td bgcolor="#FFFFFF" class="sublbox_txt"><%If objPackageDetails.Item("v_ext") = parExt Then%>Yes<%Else%>No<%End If%></td>
      </tr>
      <tr>
         <td nowrap bgcolor="#FFFFFF" class="sublbox_txt" valign="top"><strong>Build Environment:</strong> </td>
         <td bgcolor="#FFFFFF" class="sublbox_txt"><%If objPackageDetails.Item("is_build_env_required") = enumDB_NO Then%>Not Required.<%End If%>
            <%
            '--- Get Build Env Details

            Set rsQry = OraDatabase.DbCreateDynaset( SQL_Build_Std ( parPv_id ), cint(0))
            If ((NOT rsQry.BOF) AND (NOT rsQry.EOF)) Then
               BldStd = rsQry("bs_name")
               rsQry.Close

               Set rsQry = OraDatabase.DbCreateDynaset( SQL_Build_Env ( parPv_id ), cint(0))
               %>
               <ul>
                  <%
                  While (NOT rsQry.BOF) AND (NOT rsQry.EOF)
                     %>
                     <li><%=BldStd%>, <%=rsQry("bm_name")%></li>
                     <%rsQry.MoveNext
                  WEnd
                  %>
               </ul>
            <%End If%>
         </td>
      </tr>
      <tr>
         <td nowrap bgcolor="#FFFFFF" class="sublbox_txt" valign="top"><strong>Build Dependencies:</strong> </td>
         <td bgcolor="#FFFFFF" class="sublbox_txt">
            <%
            '--- Get Build Dependencies Details

            Set rsQry = OraDatabase.DbCreateDynaset( SQL_Build_Dependencies ( parPv_id ), cint(0))
            %>
            <table width="100%"  cellspacing="0" cellpadding="2" border="1">
               <tr>
                  <td nowrap class="sublbox_txt" bgcolor="#FFFFFF" width="1%"><strong>Software Component</strong></td>
                  <td nowrap class="sublbox_txt" bgcolor="#FFFFFF" width="100%"><strong>Version</strong></td>
               </tr>
               <%If rsQry.RecordCount < 1 Then%>
                  <tr>
                     <td nowrap class="sublbox_txt">No Dependencies</td>
                     <td nowrap class="sublbox_txt"></td>
                  </tr>
               <%End If%>
               <%
               While (NOT rsQry.BOF) AND (NOT rsQry.EOF)
                  %>
                  <tr>
                     <td nowrap class="sublbox_txt"><a href="#<%=rsQry("pkg_name")%>"><%=rsQry("pkg_name")%></a></td>
                     <td nowrap class="sublbox_txt"><%=rsQry("pkg_version")%></td>
                  </tr>
                  <%rsQry.MoveNext
               WEnd
               %>
            </table>
         </td>
      </tr>
   </table>
   <br><br>
   <%
'Exit For
Next
%>
</body>
</html>
<%
Call Destroy_All_Objects
%>