Subversion Repositories DevTools

Rev

Rev 129 | Blame | Compare with Previous | Last modification | View Log | RSS feed 

<%@LANGUAGE="VBSCRIPT"%>
<%
Option explicit
Response.Expires = 0    ' always load the page, dont store
%>
<%
'=====================================================
'                                       Edit Personal View
'=====================================================
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/common_dbedit.asp"-->
<!--#include file="common/_popup_window_common.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_login.asp"-->
<!--#include file="_access_control_general.asp"-->
<%
'------------ Variable Definition -------------
Dim rsTemp
Dim parView_id
Dim viewdefHash                 ' Hash of view settings
Dim viewinfoHash                ' Hash of view details
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
Set viewdefHash = CreateObject("Scripting.Dictionary")
Set viewinfoHash = CreateObject("Scripting.Dictionary")
parView_id = QStrPar("FRview_id")
'----------------------------------------------
%>
<%
Function Get_All_Pkg_Names
        Get_All_Pkg_Names = " SELECT pkg_id, pkg_name, UPPER(pkg_name) AS name_order FROM packages WHERE pkg_id > 0 ORDER BY name_order ASC"
End Function

Sub Populate_viewdefHash ( NNview_id,  HHviewdefHash )
        Dim rsTemp, Query_String
        Query_String = _
        " SELECT pkg_id FROM view_def WHERE view_id = "& NNview_id
        Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))
        While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))
                HHviewdefHash.Add CStr(rsTemp.Fields("pkg_id")), ""
                rsTemp.MoveNext
        WEnd
        rsTemp.Close
        Set rsTemp = nothing
End Sub

Sub Populate_viewinfoHash ( NNview_id,  HHviewinfoHash )
        Dim rsTemp, Query_String
        Query_String = _
        " SELECT * FROM views WHERE view_id = "& NNview_id
        Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))
        If ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF)) Then
                HHviewinfoHash.Add "view_name", CStr(rsTemp.Fields("view_name"))
                HHviewinfoHash.Add "public_read", CStr(rsTemp.Fields("public_read"))
        End If
        rsTemp.Close
        Set rsTemp = nothing
End Sub
%>
<%
'------------------------- MAIN LINE ------------------------
'Process submition
If CBool(QStrPar("action"))  Then
        Call OpenInParentWindow ("_edit_personal_view.asp?FRview_id="& parView_id &"&FRviewname="& QStrPar("FRviewname") &"&FRpkginc="& Request("FRpkginc") &"&FRpubread="& QStrPar("FRpubread") )
        Call CloseWindow
End If

Call Populate_viewdefHash ( parView_id, viewdefHash )
Call Populate_viewinfoHash ( parView_id, viewinfoHash )
%>
<html>
<head>
<title>Release Manager</title>
<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link rel="stylesheet" href="images/release_manager_style.css" type="text/css">
<link rel="stylesheet" href="images/navigation.css" type="text/css">
<script language="JavaScript" src="images/common.js"></script>
<!-- TIPS -->
<script language="JavaScript" src="images/tipster.js"></script>
<script language="JavaScript" src="images/_help_tips.js"></script>

</head>
<body bgcolor="#FFFFFF" text="#000000" leftmargin="0" topmargin="0" onload="document.newview.FRviewname.focus()">
<!-- TIPS LAYERS -------------------------------------->
<div id="formTipsLayer" style="position: absolute; z-index: 1000; visibility: hidden; left:0; top: 0; width: 10">&nbsp;</div>
<!----------------------------------------------------->
<form name="newview" method="post" action="<%=scriptName%>?done=done<%=QSTR_All%>" onSubmit="return check();">
  <table width="100%" border="0" cellspacing="0" cellpadding="2" height="100%">
    <tr>
      <td background="images/bg_member_dark.gif" width="1%" height="1%"><img src="images/bt_view.gif" width="31" height="18" hspace="5"></td>
      <td background="images/bg_member_dark.gif" nowrap width="50%" class="wform_ttl">&nbsp;Edit Personal View</td>
      <td background="images/bg_member_dark.gif" align="right" width="50%">
                <input type="hidden" name="action" value="true">
                <input type="hidden" name="FRview_id" value="<%=parView_id%>">
        <input type="submit" name="btn" value="Update" class="form_btn_comp" onClick="clickedButton=true;MM_validateForm('FRviewname','View Name','R');return document.MM_returnValue">
        <input type="reset" name="btn" value="Cancel" class="form_btn_comp" onclick="self.close()">
      </td>
      <td background="images/bg_member_dark.gif" align="right" width="1%%" nowrap>
        <img src="images/h_trsp_dot.gif" width="5" height="22"> </td>
    </tr>
    <tr>
      <td height="100%" width="1%">&nbsp;</td>
      <td valign="top" nowrap colspan="3" class="wform_ttl">
        <table width="100%" border="0" cellspacing="1" cellpadding="2">
          <tr>
            <td width="1%"><img src="images/h_trsp_dot.gif" width="1" height="1"></td>
            <td width="1%" nowrap class="form_group" valign="bottom"></td>
            <td nowrap width="100%" align="right" class="form_step">&nbsp;</td>
          </tr>
          <tr>
            <td width="1%">&nbsp;</td>
            <td colspan="2" width="1%" nowrap class="form_field" background="images/bg_form_lightbluedark.gif">
              View Name</td>
          </tr>
          <tr>
            <td width="1%">&nbsp;</td>
            <td colspan="2" width="1%" nowrap background="images/bg_form_lightgray.gif">
              <input type="text" name="FRviewname" maxlength="30" class="form_item" value="<%=viewinfoHash.Item("view_name")%>">&nbsp;
              <input type="checkbox" name="FRpubread" value="Y" <%If CStr(viewinfoHash.Item("public_read")) = "Y" Then Response.write "checked"%>><span class="form_item">public read</span><%=Quick_Help("pubread")%></td>
          </tr>
          <tr>
            <td width="1%"><img src="images/h_trsp_dot.gif" width="1" height="10"></td>
            <td width="1%" nowrap class="form_group" valign="bottom"></td>
            <td nowrap width="100%" align="right" class="form_step"></td>
          </tr>
          <tr>
            <td width="1%">&nbsp;</td>
            <td colspan="2" width="1%" nowrap class="form_field">
              <table width="100%" border="0" cellspacing="1" cellpadding="2">
                <tr>
                  <td background="images/bg_form_lightbluedark.gif" nowrap width="1%" class="form_field">&nbsp;</td>
                  <td background="images/bg_form_lightbluedark.gif" nowrap width="100%" class="form_field">Package Name</td>
                </tr>
                <%Set rsTemp = OraDatabase.DbCreateDynaset( Get_All_Pkg_Names, cint(0))
                                While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))%>
                <tr>
                  <td background="images/bg_form_lightgray.gif" nowrap class="form_item">
                    <input type="checkbox" name="FRpkginc" value="<%=rsTemp.Fields("pkg_id")%>" <%If viewdefHash.Exists (Cstr(rsTemp.Fields("pkg_id"))) Then Response.write "checked"%>>
                  </td>
                  <td background="images/bg_form_lightgray.gif" class="form_item"><%=rsTemp.Fields("pkg_name")%></td>
                </tr>
                <%rsTemp.MoveNext
                                WEnd%>
                                <%If rsTemp.RecordCount < 1 Then%>
                                <tr>
                  <td background="images/bg_form_lightgray.gif" nowrap class="form_item"></td>
                  <td background="images/bg_form_lightgray.gif" class="err_alert">NO PACKAGES FOUND!</td>
                </tr>
                                <%End If%>
              </table>
            </td>
          </tr>
        </table>
      </td>
    </tr>
    <tr>
      <td height="1%" width="1%"><img src="images/h_trsp_dot.gif" width="5" height="5"></td>
      <td valign="top" nowrap colspan="3" class="wform_ttl" background="images/bg_member_dark.gif"></td>
    </tr>
  </table>
</form>
</body>
</html>
<%
Call Destroy_All_Objects
%>