Subversion Repositories DevTools

Rev

Rev 161 | Blame | Compare with Previous | Last modification | View Log | RSS feed 

<%@LANGUAGE="VBSCRIPT"%>
<%
Option explicit
Response.Expires = 0   ' always load the page, dont store
%>
<%
'=====================================================
'                Edit Code Review URL
'=====================================================
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/common_dbedit.asp"-->
<!--#include file="common/_popup_window_common.asp"-->
<%
' Set rfile parameter. This is a return page after Login
Call objPMod.StoreParameter ( "rfile", "fixed_issues.asp" )
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_login.asp"-->
<!--#include file="_access_control_general.asp"-->
<!--#include file="_access_control_project.asp"-->
<%
'------------ Variable Definition -------------
Dim parPv_id
Dim parCr_id
'Dim parProj_id
Dim rsQry
Dim rsCru
Dim pkgName
Dim pkgVersion
'Dim baseURL
'Dim tailURL
'Dim dateOfReview
Dim reason
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
parPv_id = Request("pv_id")
parRtag_id = Request("rtag_id")
parCr_id = Request("cr_id")
reason = Request("reason")
'parProj_id = Request("proj_id")
'dateOfReview = EuroDate( Date )
'----------------------------------------------

'------------ Escaping quotes and other special characted which  -------------------
'------------ might have special meaning to Oracle -------------------
'dim RegularExpressionObject
'dim expressionmatch
'dim expressionmatched

'Set RegularExpressionObject = New RegExp
'With RegularExpressionObject
        'Character \ will not be replaced, I need to do more searching about it :-(
'       .Pattern = "[(\n)(\b)(\t)'!@#$%^&*()<>?/\|{}~`:;[]]"
'       .IgnoreCase = False
'       .Global = True
'End With

'Set expressionmatch = RegularExpressionObject.Execute(reason)

'If expressionmatch.Count > 0 Then
'       For Each expressionmatched in expressionmatch
'               reason = RegularExpressionObject.Replace(reason, " ")
'       Next
'End If

'Set RegularExpressionObject = Nothing
'----------------------------------------------

%>
<%
'-----------------------------------------------------------------------------------------------------------------------------------
Sub GetFormDetails (nCr_id, rsTemp)
  Dim Query_String

  Query_String = "SELECT cru.*, proj.base_url FROM code_review_url cru, projects proj "&_
                 "WHERE cru.proj_id = proj.proj_id AND cru.cr_id = :CR_ID"

  OraDatabase.Parameters.Add "CR_ID",    nCr_id,    ORAPARM_INPUT,  ORATYPE_NUMBER

  Set rsTemp = OraDatabase.CreateDynaset( Query_String, cint(0))

  OraDatabase.Parameters.Remove "CR_ID"

End Sub
'-----------------------------------------------------------------------------------------------------------------------------------
Sub UpdateCodeReviewURL ( nCr_id, nProj_id, sURL, sReason )

   OraDatabase.Parameters.Add "CR_ID",    nCr_id,    ORAPARM_INPUT,  ORATYPE_NUMBER
   OraDatabase.Parameters.Add "PROJ_ID",  nProj_id,  ORAPARM_INPUT,  ORATYPE_NUMBER
   OraDatabase.Parameters.Add "URL",      sURL,      ORAPARM_INPUT,  ORATYPE_VARCHAR2
   OraDatabase.Parameters.Add "REASON",   sReason,   ORAPARM_INPUT,  ORATYPE_VARCHAR2

   objEH.TryORA ( OraSession )
   On Error Resume Next

   OraDatabase.ExecuteSQL "BEGIN PK_PACKAGE.UPDATE_CODE_REVIEW_URL ( :CR_ID, :PROJ_ID, :URL, :REASON );  END;"

   objEH.CatchORA ( OraSession )

   OraDatabase.Parameters.Remove "CR_ID"
   OraDatabase.Parameters.Remove "PROJ_ID"
   OraDatabase.Parameters.Remove "URL"
   OraDatabase.Parameters.Remove "REASON"

End Sub
'-----------------------------------------------------------------------------------------------------------------------------------
Sub AddCodeReviewURL ( nPv_id, nProj_id, sURL, sReason, dDateOfReview )

   OraDatabase.Parameters.Add "PV_ID",           nPv_id,         ORAPARM_INPUT,  ORATYPE_NUMBER
   OraDatabase.Parameters.Add "PROJ_ID",         nProj_id,       ORAPARM_INPUT,  ORATYPE_NUMBER
   OraDatabase.Parameters.Add "URL",             sURL,           ORAPARM_INPUT,  ORATYPE_VARCHAR2
   OraDatabase.Parameters.Add "REASON",          sReason,        ORAPARM_INPUT,  ORATYPE_VARCHAR2
   OraDatabase.Parameters.Add "DATE_OF_REVIEW",  dDateOfReview,  ORAPARM_INPUT,  ORATYPE_DATE

   objEH.TryORA ( OraSession )
   On Error Resume Next

   OraDatabase.ExecuteSQL "BEGIN PK_PACKAGE.ADD_CODE_REVIEW_URL ( :PV_ID, :PROJ_ID, :URL, :REASON, :DATE_OF_REVIEW );  END;"

   objEH.CatchORA ( OraSession )

   OraDatabase.Parameters.Remove "PV_ID"
   OraDatabase.Parameters.Remove "PROJ_ID"
   OraDatabase.Parameters.Remove "URL"
   OraDatabase.Parameters.Remove "REASON"
   OraDatabase.Parameters.Remove "DATE_OF_REVIEW"

End Sub
'------------ Action Requirements -------------------
'Process submission
If CBool(Request("action")) AND objAccessControl.UserLogedIn Then
  If (Not IsNull(parCr_id)) AND (parCr_id <> "") Then
      Call UpdateCodeReviewURL ( parCr_id, Request("proj_id"), Request("code_review_url_tail"), reason )
   Else
      Call AddCodeReviewURL ( parPv_id, Request("proj_id"), Request("code_review_url_tail"), reason, Request("date_of_review") )
   End If

   Call OpenInParentWindow ("fixed_issues.asp?pv_id="& parPv_id &"&rtag_id="& parRtag_id)
   Call CloseWindow
End If

Call GetFormDetails(parCr_id, rsCru)
Call Get_Pkg_Short_Info( parPv_id, NULL, pkgName, pkgVersion, NULL, NULL, NULL )
'----------------------------------------------
%>
<html>
  <head>
    <title>Release Manager</title>
    <meta http-equiv="Pragma" content="no-cache">
    <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
    <link rel="stylesheet" href="images/release_manager_style.css" type="text/css">
    <link rel="stylesheet" href="images/navigation.css" type="text/css">
    <script language="JavaScript" src="images/common.js"></script>
  </head>
  <body bgcolor="#FFFFFF" text="#000000" leftmargin="0" topmargin="0" onload="self.focus();">
    <form action="_wform_edit_code_review_url.asp" method="post" name="codereview" onsubmit="MM_validateForm('date_of_review','Date of Review','RisDate','code_review_url_tail','Code Review URL','RmaxLength:4000','reason','Reason for Review','maxLength:4000');return document.MM_returnValue;">
      <table width="100%" border="0" cellspacing="0" cellpadding="2" height="100%">
        <tr>
          <td width="1%" background="images/lbox_bg_orange.gif"><img src="images/s_code_review_off.gif" width="21" height="23" hspace="5" border="0"></td>
          <td width="50%" background="images/lbox_bg_blue.gif" nowrap class="wform_ttl">&nbsp;Code Review URL for <%=pkgName%>&nbsp;<%=pkgVersion%>
          </td>
          <td width="50%" background="images/lbox_bg_blue.gif" align="right" nowrap class="wform_ttl">
            <input type="submit" name="btn" value="Save" class="form_btn"> <input type="reset" name="btn" value="Close" class="form_btn" onclick="self.close()">
          </td>
          <td background="images/lbox_bg_blue.gif" align="right" width="1%" nowrap><img src="images/h_trsp_dot.gif" width="5" height="22"></td>
        </tr>
        <tr>
          <td height="100%" width="1%">&nbsp;</td>
          <td valign="top" nowrap colspan="3" class="wform_ttl" background="images/bg_form_lightgray.gif">
            <br>
            <br>
            <table width="100%" border="0" cellspacing="0" cellpadding="0">
              <tr>
                <td width="1%"><img src="images/h_trsp_dot.gif" width="10" height="30"></td>
                <td width="100%">
                  <table width="100%" border="0" cellspacing="1" cellpadding="4">
                    <tr>
                      <td nowrap background="images/bg_form_lightbluedark.gif" class="form_field">Date of Review</td>
                      <td nowrap background="images/bg_form_lightbluedark.gif" class="form_item"  width="100%">
                        <input name="date_of_review" type="text" size="20" maxlength="20" class="form_item" value='<%If IsNull(rsCru("date_of_review")) Then%><%=EuroDate ( Date )%><%Else%><%=EuroDate ( rsCru("date_of_review") )%><%End If%>'>
                      </td>
                    </tr>
                    <tr>
                      <td nowrap background="images/bg_form_lightbluedark.gif" class="form_field">Code Review URL</td>
                      <td nowrap background="images/bg_form_lightbluedark.gif" class="form_item" width="100%">
                      <select name="proj_id" class="form_item">
                        <% Set rsQry = OraDatabase.DbCreateDynaset( "SELECT * FROM projects WHERE base_url IS NOT NULL", cint(0))

                        If rsQry.RecordCount > 0 Then
                          While ((NOT rsQry.BOF) AND (NOT rsQry.EOF))
                          %>
                          <option value="<%=rsQry("proj_id")%>" <%If rsQry("proj_id") = rsCru("proj_id") Then%>selected<%End If%>><%=rsQry("proj_name")%> - <%=rsQry("base_url")%></option>
                          <%
                          rsQry.MoveNext
                          Wend
                        End If
                        rsQry.Close()
                        %>
                      </select>&nbsp;<input name="code_review_url_tail" type="text" size="80" maxlength="150" class="form_item" id="code_review_url_tail" value="<%=rsCru("url")%>" >
                      </td>
                    </tr>
                    <tr>
                      <td valign="top" nowrap background="images/bg_form_lightbluedark.gif" class="form_field">Reason for Review</td>
                      <td nowrap background="images/bg_form_lightbluedark.gif" class="form_item" width="100%">
                        <input name="reason" id="reason" type="text" size="146" maxlength="200" class="form_item" value="<%=rsCru("reason")%>">
                       <!--<textarea name="reason" id="reason" rows="5" style="width:100%" class="form_item"><%=rsCru("reason")%></textarea>-->

                      </td>
                    </tr>
                  </table>
                </td>
              </tr>
            </table>
            <input type="hidden" name="action" value="true">
            <input type="hidden" name="pv_id" value="<%=parPv_id%>">
            <input type="hidden" name="rtag_id" value="<%=parRtag_id%>">
            <input type="hidden" name="cr_id" value="<%=parCr_id%>">
            <br>
            <br>
          </td>
        </tr>
        <tr>
          <td height="1%" width="1%"><img src="images/h_trsp_dot.gif" width="5" height="5"></td>
          <td valign="top" nowrap colspan="3" class="wform_ttl" background="images/lbox_bg_blue.gif"></td>
        </tr>
      </table>
    </form>
  </body>
</html>
<!-- DESTRUCTOR ------->
<!--#include file="common/destructor.asp"-->