Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'                 EDIT Personal View
'               --- PROCESS FORM ---
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0   ' always load the page, dont store
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/common_dbedit.asp"-->
<%
' Set rfile parameter. This is a return page after Login
Call objPMod.StoreParameter ( "rfile", "members_personal_view.asp" )
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_login.asp"-->
<!--#include file="_access_control_general.asp"-->
<%
'------------ Variable Definition -------------
Dim parView_id
Dim parViewName
Dim parPkgInc
Dim parPubread
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
parView_id = QStrPar("FRview_id")
parViewName = QStrPar("FRviewname")
parPkgInc = QStrPar("FRpkginc")
parPubread = QStrPar("FRpubread")
'----------------------------------------------
%>
<%
Sub Update_View ( NNview_id, SSViewName, SSPubread )
   Dim rsTemp, Query_String
   If SSPubread = "" Then SSPubread = "N"
   Query_String = _
   " SELECT *"&_
   " FROM views"&_
   " WHERE view_id = "& NNview_id

   Set rsTemp = OraDatabase.CreateDynaset( Query_String, cint(0))

   'update fields
   rsTemp.Edit
   rsTemp.Fields("view_name").Value = SSViewName
   rsTemp.Fields("public_read").Value = SSPubread
   rsTemp.Update

   rsTemp.Close
   Set rsTemp = nothing
End Sub

Sub Update_View_Definition ( NNview_id, SSPkgInc )
   ' Remove current view definition
   On Error Resume Next
   objEH.TryORA ( OraSession )
   OraDatabase.ExecuteSQL "DELETE FROM view_def WHERE view_id = "& NNview_id
   objEH.CatchORA ( OraSession )
   If objEH.LastOraFailed = FALSE Then
      ' Set view definition
      If SSPkgInc <> "" Then
         objEH.TryORA ( OraSession )
         OraDatabase.ExecuteSQL _
            " INSERT INTO view_def"&_
            " SELECT TO_NUMBER('"& NNview_id &"') AS view_id, pkg_id FROM packages WHERE pkg_id IN ("& SSPkgInc &")"
         objEH.CatchORA ( OraSession )
      End If
   End If
End Sub
%>
<%
'-----------------------  MAIN LINE  ---------------------------

'--- Process submition ---
If (parView_id <> "") AND (parViewName <> "") Then
   ' All mandatory parameters FOUND

   ' report errors if found
   If NOT This_View_Owner( parView_id, objAccessControl.UserId ) Then
      Session("reqParam") = ""
      Session("ERRlog") = ""
      Session("ERRlogFULL") = ""
      Response.Redirect("message.asp?msg=401-4")
   End If

   'COMPLETE THE REQUEST...
   Call Update_View ( parView_id, parViewName, parPubread )
   Call Update_View_Definition ( parView_id, parPkgInc )

   Response.Redirect("members_personal_view.asp")
Else
   Response.write "Some mandatory parameters are missing!" & "<br>" 'TODO
   Response.write QSTR_All
End If
%>

<!-- DESTRUCTOR ------->
<!--#include file="common/destructor.asp"-->