Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'                                   Change release Mode
'               --- PROCESS FORM ---
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0    ' always load the page, dont store
%>
<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/common_dbedit.asp"-->
<%
' Set rfile parameter. This is a return page after Login
Call objPMod.StoreParameter ( "rfile", "dependencies.asp" )
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_login.asp"-->
<!--#include file="_access_control_general.asp"-->
<!--#include file="_access_control_project.asp"-->
<%
'------------ Variable Definition -------------
Dim rsQry
Dim     myMail
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
'----------------------------------------------
%>
<%
Sub CheckWIPS ()

        OraDatabase.Parameters.Add "RTAG_ID",                   Request("rtag_id"),     ORAPARM_INPUT, ORATYPE_NUMBER 
        
        Set rsQry = OraDatabase.DbCreateDynaset( GetQuery("CheckWIPS.sql"), cint(0))
        
        OraDatabase.Parameters.Remove "RTAG_ID"
        
        If      rsQry.RecordCount       > 0 Then
                Call OpenInWindow( "form_check_closed_mode.asp?rtag_id="& Request("rtag_id") )
        Else
                'COMPLETE THE REQUEST...
                Call ChangeReleaseMode ()
        End     If
        
        rsQry.Close()
        Set     rsQry   =       Nothing
        

End Sub
'----------------------------------------------------------------------------------------------------------
Sub ChangeReleaseMode ( )
        
        OraDatabase.Parameters.Add "RTAG_ID",                   Request("rtag_id"),     ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "MODECODE",                  Request("mode_code"),   ORAPARM_INPUT, ORATYPE_NUMBER
        OraDatabase.Parameters.Add "USER_ID",                   objAccessControl.UserId,        ORAPARM_INPUT, ORATYPE_NUMBER
        
        
        OraSession.BeginTrans
        
        OraDatabase.ExecuteSQL _
                " BEGIN   CHANGE_RELEASE_MODE ( :MODECODE, :RTAG_ID, :USER_ID );  END;"
                
        OraSession.CommitTrans
        
        
        OraDatabase.Parameters.Remove "RTAG_ID"
        OraDatabase.Parameters.Remove "MODECODE"
        OraDatabase.Parameters.Remove "USER_ID"
        
End Sub
'------------------------------------------------------------------------------------------------
Sub NotifyArchive

        OraDatabase.Parameters.Add "RTAG_ID",                   Request("rtag_id"),     ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "USER_ID",                   objAccessControl.UserId,        ORAPARM_INPUT, ORATYPE_NUMBER

        Set rsQry = OraDatabase.DbCreateDynaset( GetQuery("NotifyArchive.sql"), cint(0))
        
        
        Set myMail=Server.CreateObject("Persits.MailSender")
        myMail.Host = SMTP_HOST
        myMail.Subject="Project Release Archival Request"
        myMail.Body = "The Release Branch " & rsQry("rtag_name") &" in Project " & rsQry("proj_name") &" will be archived after 5 days. Please contact the Administrator for any change to the request."
        myMail.From=ADMIN_EMAIL
        myMail.AddAddress rsQry("user_email")&", releasem@erggroup.com"
                
        myMail.Send
        set myMail=nothing
        
        rsQry.Close()
        Set     rsQry   =       Nothing

        OraDatabase.Parameters.Remove "RTAG_ID"
        OraDatabase.Parameters.Remove "USER_ID"
        
End Sub
%>
<%
'-----------------------  MAIN LINE  ---------------------------
        On Error Resume Next
        
        objEH.Try()
'--- Process submission ---
If (Request("rtag_id") <> "")  AND  (Request("mode_code") <> "") Then
        
        If Request("mode_code") = 3 Then
                Call CheckWIPS ()
        ElseIf Request("mode_code") = 5 Then
                Call ChangeReleaseMode()
                Call NotifyArchive()
                OpenInWindow( "rtree.asp?proj_id="& Get_Proj_ID(Request("rtag_id")))
        Else
                'COMPLETE THE REQUEST...
                Call ChangeReleaseMode ()
        End If
        
        ' Display message
        'If Request("mode_code") = "1" Then
        '       
        '       Call RaiseMsg ( enum_MSG_RELEASE_IS_IN_OPEN_MODE, parRtag_id )
        '       
        'ElseIf Request("mode_code") = "2" Then
        '       Call RaiseMsg ( enum_MSG_RELEASE_IS_IN_RESTRICTIVE_MODE, parRtag_id )
        '       
        'ElseIf Request("mode_code") = "3" Then
        '       Call RaiseMsg ( enum_MSG_RELEASE_IS_IN_CLOSED_MODE, parRtag_id )        
        '       
        'End If
        
        Call OpenInWindow( "dependencies.asp?rtag_id="& Request("rtag_id") )
        
        
Else
        Err.Raise 8, "Request not accepted here."
        'Response.write "Some mandatory parameters are missing!" & "<br>" 'TODO
        'Response.write QSTR_All 
End If
        objEH.Catch()
%>

<!-- DESTRUCTOR ------->
<!--#include file="common/destructor.asp"-->