Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'                 ADD Packages
'               --- PROCESS FORM ---
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0   ' always load the page, dont store
%>

<!--#include file="common/conf.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/common_dbedit.asp"-->
<!--#include file="common/release_changed.asp"-->
<%
' Set rfile parameter. This is a return page after Login
Call objPMod.StoreParameter ( "rfile", "dependencies.asp" )
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_login.asp"-->
<!--#include file="_access_control_general.asp"-->
<!--#include file="_access_control_project.asp"-->
<%
'------------ Variable Definition -------------
Dim pkgArray()
Dim pv_id_list
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
'----------------------------------------------
%>
<%
'--------------------------------------------------------------------------------------------------------------------
Sub Populate_pkgArray ( NNpkg_list, ARRpkg )
   Dim depList, lastItem, i, recCnt, pkg_name, pkg_version, V_EXT
   Dim rsTemp, Query_String

   Query_String = _
   " SELECT pkg_id, pkg_name"&_
   "  FROM packages"&_
   " WHERE pkg_id IN ("& NNpkg_list &")"
   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

   recCnt = 0
   While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))
      ReDim Preserve ARRpkg( 2, recCnt )
      ARRpkg( 0, recCnt ) = rsTemp("pkg_name")
      ARRpkg( 1, recCnt ) = Request( "pkgn"& rsTemp("pkg_id") )

      recCnt = recCnt + 1
      rsTemp.MoveNext
   WEnd

   rsTemp.Close
   Set rsTemp = nothing
End Sub

'--------------------------------------------------------------------------------------------------------------------
Sub Seed_DB ( ARRpkg, retPV_ID_LIST )
   Dim i, lastRow

   On Error Resume Next

   OraDatabase.Parameters.Add "retPV_ID", 0, ORAPARM_OUTPUT, ORATYPE_NUMBER

   retPV_ID_LIST = ""
   lastRow = UBound( pkgArray, 2 )

   For i = 0 To lastRow
      If Err.Number = 0 Then
         OraDatabase.ExecuteSQL "BEGIN Seed_Package_Names_Versions ('"& ARRpkg(0,i) &"','"& ARRpkg(1,i) &"', :USER_ID, :retPV_ID); END;"
         retPV_ID_LIST = retPV_ID_LIST &","& OraDatabase.Parameters("retPV_ID").Value
      End If
   Next

   If Len(retPV_ID_LIST) > 0 Then retPV_ID_LIST = Replace ( retPV_ID_LIST, ",", "", 1, 1 )

   OraDatabase.Parameters.Remove "retPV_ID"
End Sub
'--------------------------------------------------------------------------------------------------------------------
Sub AddPackage ( sPvIdList )

   Dim rsQry, AssocMASS

   On Error Resume Next

   Set rsQry = OraDatabase.DbCreateDynaset( "SELECT * FROM RELEASE_TAGS RT, PACKAGE_VERSIONS PV WHERE RT.RTAG_ID ="&Request("rtag_id")&" AND PV.PV_ID IN ("&sPvIdList&")", cint(0))

   AssocMASS = rsQry("ASSOC_MASS_REF")

   If ( IsNull(AssocMASS) ) OR (AssocMASS <> "" AND (rsQry("v_ext") <> ".cr" AND rsQry("v_ext") <> ".mas" )) Then

      OraDatabase.Parameters.Add "PV_ID_LIST", sPvIdList, ORAPARM_OUTPUT, ORATYPE_VARCHAR2

      OraDatabase.ExecuteSQL "BEGIN PK_ENVIRONMENT.ADD_PACKAGE_BULK ( :PV_ID_LIST, :BASE_VIEW_ID, :RTAG_ID, :USER_ID ); END;"

      OraDatabase.Parameters.Remove "PV_ID_LIST"
   Else
      Err.Raise 8, "Cannot ADD a CORE/MASS package into a MASS_REF Reference Release!"
   End If

End Sub
'--------------------------------------------------------------------------------------------------------------------
Sub Add_Packages_To_View_Definition ( NNpkg_list )
   If OraDatabase.Parameters("PERSONAL_VIEW_ID").Value = "" Then Exit Sub
   OraDatabase.ExecuteSQL _
   " INSERT INTO view_def"&_
   "   SELECT TO_NUMBER( :PERSONAL_VIEW_ID ) AS view_id, pkg.pkg_id"&_
   "     FROM packages pkg"&_
   "    WHERE pkg.pkg_id IN ( "& NNpkg_list &" )"&_
   "   MINUS "&_
   "   SELECT vd.view_id, vd.pkg_id"&_
   "     FROM view_def vd"&_
   "    WHERE vd.view_id = :PERSONAL_VIEW_ID "
End Sub
'--------------------------------------------------------------------------------------------------------------------
%>
<%
'-----------------------  MAIN LINE  ---------------------------
On Error Resume Next
Dim rsQry
Dim bAdded: bAdded = False

Set rsQry = OraDatabase.DbCreateDynaset( "SELECT OFFICIAL FROM RELEASE_TAGS WHERE RTAG_ID ="&Request("rtag_id"), cint(0))
objEH.Try
If rsQry("official") = "N" OR rsQry("official") = "R" Then

   '--- Process submition ---
   If  ( Request("rtag_id") <> "" ) AND ( Request("pkg_list") <> "" ) Then

      ' All mandatory parameters FOUND

      Call Populate_pkgArray ( Request("pkg_list"), pkgArray )

      'On Error Resume Next
      OraSession.BeginTrans

      '---- SQL parameters ----
      OraDatabase.Parameters.Add "RTAG_ID", Request("rtag_id"), ORAPARM_INPUT, ORATYPE_NUMBER
      OraDatabase.Parameters.Add "USER_ID", objAccessControl.UserId, ORAPARM_INPUT, ORATYPE_NUMBER
      OraDatabase.Parameters.Add "BASE_VIEW_ID", Request("base_view_id"), ORAPARM_INPUT, ORATYPE_NUMBER
      OraDatabase.Parameters.Add "PERSONAL_VIEW_ID", Request("personal_view_id"), ORAPARM_INPUT, ORATYPE_NUMBER
      '------------------------

      Call Seed_DB ( pkgArray, pv_id_list )

      If Err.Number = 0 Then
         Call AddPackage ( pv_id_list )
         If Err.Number = 0 Then
            If NOT IsNull(Request("personal_view_id")) Then
               Call Add_Packages_To_View_Definition ( Request("pkg_list") )
            End If
         End If
      End If

      If Err.number <> 0 Then
         OraSession.RollBack
         Call RaiseMsg ( enum_MSG_ERROR, Err.description )
      Else
        OraSession.CommitTrans
        bAdded = True
      End If

      OraDatabase.Parameters.Remove "RTAG_ID"
      OraDatabase.Parameters.Remove "USER_ID"
      OraDatabase.Parameters.Remove "BASE_VIEW_ID"
      OraDatabase.Parameters.Remove "PERSONAL_VIEW_ID"

      If bAdded Then
        Dim objRC: Set objRC = New ReleaseChanged
        Call objRC.Run_ReleaseChanged_List(Request("rtag_id"),pv_id_list,enumRELEASE_CHANGE_MODE_PKG_ADDED)
        Set objRC = Nothing
      End If
      
      Response.Redirect("dependencies.asp?rtag_id="& Request("rtag_id"))
   Else
      Response.write "Some mandatory parameters are missing!" & "<br>" 'TODO
      Response.write QSTR_All
   End If

Else
   Err.Raise 8, "Cannot ADD a package in a CLOSED or CCB Release Mode"
End If
   rsQry.Close
   Set rsQry = nothing
objEH.Catch
%>

<!-- DESTRUCTOR ------->
<!--#include file="common/destructor.asp"-->