Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|                                wPasteItems                    |
'|                                                   |
'=====================================================
%>
<%
Option explicit
Response.Expires = 0
%>
<!--#include file="common/globals.asp"-->
<!--#include file="common/config.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/_popup_window_common.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_general.asp"-->
<%
'------------ VARIABLE DEFINITION -------------
Dim rsQry
Dim aProducts
Dim numOfRows
Dim rowNum
'------------ CONSTANTS DECLARATION -----------
'------------ VARIABLE INIT -------------------
parBom_id = Request("bom_id")
'------------ CONDITIONS ----------------------
'----------------------------------------------
%>
<%
'--------------------------------------------------------------------------------------------------------------------------------
Sub PasteItems ()
        
        If Request("item_id_list") = "" Then Exit Sub
        
        
        On Error Resume Next
        
        OraDatabase.Parameters.Add "ITEM_ID_LIST", Request("item_id_list"),             ORAPARM_INPUT, ORATYPE_VARCHAR2
        OraDatabase.Parameters.Add "FROM_ID",     Session( enumSESSION_COPY_FROM ),             ORAPARM_INPUT, ORATYPE_NUMBER
        
        
        
        objEH.TryORA ( OraSession )
        
        Select Case Session( enumSESSION_COPY_TYPE )
                Case "prod_id_list"
                        
                        If (Request("base_env_id") <> "") Then
                                OraDatabase.Parameters.Add "TO_ID", Request("base_env_id"),             ORAPARM_INPUT, ORATYPE_NUMBER
                                
                                OraDatabase.ExecuteSQL _
                                "BEGIN   pk_Utils.Paste_Products_To_Base_Env ( :ITEM_ID_LIST, :FROM_ID, :TO_ID );   END;"
                                
                        ElseIf (Request("os_id") <> "") Then
                                OraDatabase.Parameters.Add "TO_ID", Request("os_id"),           ORAPARM_INPUT, ORATYPE_NUMBER
                                
                                OraDatabase.ExecuteSQL _
                                "BEGIN   pk_Utils.Paste_Products ( :ITEM_ID_LIST, :FROM_ID, :TO_ID );   END;"
                                
                        End If
                        
                Case "os_id_list"
                        OraDatabase.Parameters.Add "TO_ID", Request("node_id"),                 ORAPARM_INPUT, ORATYPE_NUMBER
                        
                        OraDatabase.ExecuteSQL _
                        "BEGIN   pk_Utils.Paste_Os ( :ITEM_ID_LIST, :FROM_ID, :TO_ID );   END;"
                        
                Case "node_id_list"
                        OraDatabase.Parameters.Add "TO_ID", Request("bom_id"),          ORAPARM_INPUT, ORATYPE_NUMBER
                        
                        OraDatabase.ExecuteSQL _
                        "BEGIN   pk_Utils.Paste_Node ( :ITEM_ID_LIST, :FROM_ID, :TO_ID );   END;"
                
        End Select
        
        
        objEH.CatchORA ( OraSession )
        
        
        OraDatabase.Parameters.Remove "ITEM_ID_LIST"
        OraDatabase.Parameters.Remove "FROM_ID"
        OraDatabase.Parameters.Remove "TO_ID"
        
End Sub
'--------------------------------------------------------------------------------------------------------------------------
%>
<%
'------------ RUN BEFORE PAGE RENDER ----------
If Request("action") <> "" Then 
        ' --- Form is Valid ---
        Call PasteItems()
        
        If objEH.Finally Then
                Call OpenInParentWindow ( Request("rfile") &"?PASTE=OK"& objPMod.ComposeURLWithout("rfile") )
                Call CloseWindow()
        End If
End If
'----------------------------------------------
%>

<html>
<head>
<title>Deployment Manager</title>
<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link href="scripts/deployment_manager.css" rel="stylesheet" type="text/css">
<script language="JavaScript" src="scripts/common.js"></script>
</head>

<body background="images/bg_bage_0.gif" leftmargin="0" topmargin="0" onLoad="self.focus();">
<table width="100%"  border="0" cellspacing="0" cellpadding="10">
  <tr>
    <td bgcolor="#FFFFFF" class="body_txt"><span class="body_h1"><img src="icons/btn_paste.gif" align="absmiddle">&nbsp;Clipboard </span> <br>
    Select items from the list and click Paste.
    </td>
  </tr> 
  <form name="FormName" method="post" action="<%=SCRIPT_NAME%>">
  <tr>
    <td background="images/bg_login.gif"><table width="100%"  border="0" cellspacing="0" cellpadding="0">
      <tr>
        <td>&nbsp;</td>
                
        <td align="right">        
        <input name="btn" type="submit" class="form_btn" value="Paste">
        <input name="btn" type="reset" class="form_btn" value="Cancel" onClick="self.close();"></td>
      </tr>
    </table></td>
  </tr>
  <tr>
    <td>
<!-- PASTE RESULTS ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->           
        <table width="100%"  border="0" cellspacing="10" cellpadding="0">
      <tr>
        <td width="100%" valign="top" nowrap class="body_txt">
                  <!-- MESSAGE +++++++++++++++++++++++++++++++++++++++++++++++++++ -->  
                  <!--#include file="messages/_msg_inline.asp"-->
                  <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
          <table width="100%"  border="0" cellspacing="3" cellpadding="0">
            <tr>
                          <td width="1%" nowrap background="images/bg_bage_0h.gif" class="body_col">Paste</td>
              <td width="100%" align="right" nowrap background="images/bg_bage_0h.gif" class="body_col">Item</td>
                          <td><img src="images/spacer.gif" width="1" height="20"></td>
            </tr>
                <%
                '-- Exit if mixing apples with pairs
                If Session( enumSESSION_COPY_TYPE ) = Request("copy_type") Then
                %>
                        <%
                        OraDatabase.Parameters.Add "ITEM_ID_LIST", Session( enumSESSION_COPY_ITEMS ),           ORAPARM_INPUT, ORATYPE_VARCHAR2
                        OraDatabase.Parameters.Add "FROM_ID",      Session( enumSESSION_COPY_FROM ),            ORAPARM_INPUT, ORATYPE_NUMBER
                        
                        Select Case Session( enumSESSION_COPY_TYPE )
                                Case "prod_id_list"
                                        Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("PasteProductList.sql"), ORADYN_DEFAULT )
                                Case "os_id_list"
                                        Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("PasteOsList.sql"), ORADYN_DEFAULT )
                                Case "node_id_list"
                                        Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("PasteNodeList.sql"), ORADYN_DEFAULT )
                                        
                        End Select
                        
                        
                        While (NOT rsQry.BOF) AND (NOT rsQry.EOF)
                        %>
            <tr>
              <td align="center" nowrap><input type="checkbox" name="item_id_list" value="<%=rsQry("item_id")%>" checked> </td>
              <td nowrap class="body_row"><img hspace="4" src="icons/<%=rsQry("item_icon")%>" align="absmiddle" border="0"><%=rsQry("item_name")%></td>
                          <td><img src="images/spacer.gif" width="1" height="1"></td>
            </tr>
                        <tr>
              <td colspan="3" background="images/bg_table_border.gif"><img src="images/spacer.gif" width="1" height="1"></td>
            </tr>
            <%rsQry.MoveNext
                        Wend
                        
                        OraDatabase.Parameters.Remove "ITEM_ID_LIST"
                        OraDatabase.Parameters.Remove "FROM_ID"
                        
                        rsQry.Close
                        Set rsQry = Nothing
                        %>
                <%
                End If
                %>
                        <tr>
              <td colspan="3" background="images/bg_table_border.gif"><img src="images/spacer.gif" width="1" height="3"></td>
            </tr>
          </table></td>
        </tr>
                
    </table>
        <!-- ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
    </td>
  </tr>
  <%=objPMod.ComposeHiddenTags()%>
  <input type="hidden" name="copy_type" value="<%=Request("copy_type")%>">
  <input type="hidden" name="base_env_id" value="<%=Request("base_env_id")%>">
  <input type="hidden" name="action" value="true">
  </form>
</table>
</body>
</html>
<%
'------------ RUN AFTER PAGE RENDER -----------
'----------------------------------------------
%><!--#include file="common/globals_destructor.asp"-->