Subversion Repositories DevTools

<%
'===================================================================
'                                                       Node Common
'===================================================================
%>
<!--#include file="../class/classTemplateManager.asp"-->
<!--#include file="../class/classCrumbs.asp"-->
<!--#include file="../class/classTabControl.asp"-->
<!--#include file="../class/classActionButtonControl.asp"-->
<!--#include file="../class/classPopupMenuControl.asp"-->
<!--#include file="../class/classFormater.asp"-->
<%
'------------ VARIABLE DEFINITION -------------
Dim objTabControl
Dim objTemplateManager
Dim objNodeCollector
Dim objBomCollector
Dim objBtnControl
Dim objFormater
Dim aTabBtnsDef
'------------ CONSTANTS DECLARATION -----------
Const LIMG_EDIT = "<img src='icons/i_edit.gif' width='16' height='16' border='0' hspace='2'>"
Const LIMG_REMOVE = "<img src='icons/i_remove.gif' width='16' height='16' border='0' hspace='2'>"
'------------ VARIABLE INIT -------------------
Set objCrumbs = New Crumbs
Set objPMod = New PersistanceModule
Set objNodeCollector = CreateObject("Scripting.Dictionary")
Set objBomCollector = CreateObject("Scripting.Dictionary")
Set objBtnControl = New ActionButtonControl
Set objFormater = New Formater
'------------ CONDITIONS ----------------------
'----------------------------------------------
%>
<%
'------------ RUN BEFORE PAGE RENDER ----------
Call GetMainDBParameters ( dbPARproj_id, dbPARbranch_id, dbPARbom_id, dbPARnode_id, dbPARos_id, dbPARprod_id )
Call InitialiseCrumbs ( objCrumbs )
objPMod.PersistInCookie ("bom_browser")
objPMod.PersistInCookie ("user_bar")
objPMod.PersistInQryString ( aPersistList(enumPAR_BOM_ID) )
objPMod.PersistInQryString ( aPersistList(enumPAR_NODE_ID) )
Call GetBomDetails ( dbPARbom_id, objBomCollector )
Call GetNodeDetails ( dbPARnode_id, objNodeCollector )
'----------------------------------------------
%>
<%
'-----------------------------------------------------------------------------------------------------------------
Sub GetNodeDetails ( nNode_id, ByRef outobjDetails )
        Dim rsQry, query
        OraDatabase.Parameters.Add "NODE_ID", nNode_id, ORAPARM_INPUT, ORATYPE_NUMBER 
        
        query = "SELECT nn.*  FROM NETWORK_NODES nn  WHERE nn.NODE_ID = :NODE_ID"
        
        Set rsQry = OraDatabase.DbCreateDynaset( query , ORADYN_DEFAULT )
        
        If ((NOT rsQry.BOF) AND (NOT rsQry.EOF)) Then
                outobjDetails.Item ("node_id")   = rsQry("node_id")
                outobjDetails.Item ("node_name") = rsQry("node_name")
                
        Else
                Err.Raise 8, "Sub GetNodeDetails", "Empty record set returned. nNode_id="& nNode_id
                
        End If
        
        OraDatabase.Parameters.Remove "NODE_ID"
        rsQry.Close
        Set rsQry = Nothing
End Sub
'-----------------------------------------------------------------------------------------------------------------
Sub RenderTitle ( objCollector )
        Response.write "<b>"& objCollector.Item("node_name") &"</b>"
End Sub
'-----------------------------------------------------------------------------------------------------------------
%>