Subversion Repositories DevTools

<%
'===================================================================
'                                               State Options
'===================================================================
%>
<%
'------------ VARIABLE DEFINITION -------------
Dim rsMenuOptions
Dim moQuery
Dim objPopupMenuStateOptions
Dim ItemName
Dim aStateOptionList
Dim AM_StaticObjName
'------------ CONSTANTS DECLARATION -----------
'------------ VARIABLE INIT -------------------
Set objPopupMenuStateOptions = New PopupMenuControl
objPopupMenuStateOptions.PopupMenuStyle ReadFile( Server.MapPath("scripts/popup_menu_styles.html") ), "StyleWinXP"
'----------------------------------------------
%>
<%
'------------ RUN BEFORE CONTROL RENDER -------
'----------------------------------------------
%>
<%
Select Case CInt( StateTypeEnum )
        Case enumDB_STATE_TYPE_BOM_CREATOR
                aStateOptionList = Array( "pmiNewBom", _
                                                                  "pmiDestroyBom", _
                                                                  enumSEPARATOR_LABEL, _
                                                                  "pmiLockBom", _
                                                                  "pmiUnlockBom", _
                                                                  enumSEPARATOR_LABEL, _
                                                                  "pmiVersionTree", _
                                                                  "pmiImportExportBom", _
                                                                  enumSEPARATOR_LABEL, _
                                                                  "pmiReleaseTo", _
                                                                  enumSEPARATOR_LABEL, _
                                                                  "pmiToProduction" )
                
                AM_StaticObjName = "pmoCreator"
                
        Case enumDB_STATE_TYPE_BOM_LOCAL_TESTER
                aStateOptionList = Array( "pmiAcceptBom", _
                                                                  "pmiRejectBom", _
                                                                  enumSEPARATOR_LABEL, _
                                                                  "pmiVersionTree", _
                                                                  enumSEPARATOR_LABEL, _
                                                                  "pmiReleaseTo" )
                
                AM_StaticObjName = "pmoTester"
                
        Case enumDB_STATE_TYPE_BOM_EXTERNAL_TESTER
                                aStateOptionList = Array( _
                                                                  "pmiAcceptBom", _
                                                                  "pmiRejectBom", _
                                                                  enumSEPARATOR_LABEL, _
                                                                  "pmiVersionTree", _
                                                                  enumSEPARATOR_LABEL, _
                                                                  "pmiReleaseTo" )
                
                AM_StaticObjName = "pmoExternalTester"
        
End Select


If objAccessControl.IsVisible ( AM_StaticObjName ) Then
        
        moQuery = GetQuery ("PopupMenuItemsList.sql")
        moQuery = Replace ( moQuery, "%ITEM_LIST%", Join( aStateOptionList, "','") )
        Set rsMenuOptions = OraDatabase.DbCreateDynaset( moQuery , ORADYN_DEFAULT )
        
        If ((NOT rsMenuOptions.BOF) AND (NOT rsMenuOptions.EOF)) Then
                
                With objPopupMenuStateOptions
                        .LoadRows rsMenuOptions.GetRows()
                        
                        Response.write "<td width='100%' valign='top'><a href='javascript:;' onClick=""ToggleDisplay('divStateOption_"& StateId &"');""><img src='icons/b_options.gif' alt='Options...' width='12' height='10' border='0'></a>"
                        
                        '.AllActive = objAccessControl.UserStaticPermissionValue ( AM_StaticObjName, enumDB_PERMISSION_TYPE_ACTIVE )            ' ACCESS CONTROL
                        .RenderInOrder "divStateOption_"& StateId, aStateOptionList, objAccessControl, AM_StaticObjName
                End With
                
        End If
        rsMenuOptions.Close
        
End If


%>
<%
'------------ RUN AFTER CONTROL RENDER --------
Set objPopupMenuStateOptions = Nothing
Set rsMenuOptions = Nothing
'----------------------------------------------
%>