Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'                                  NEW Unit Test
'               --- PROCESSING FORM ---
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0    ' always load the page, dont store
%>

<!--#include file="common/config.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/common_dbedit.asp"-->
<!--#include file="upload/clsUpload.asp"-->
<%
' Set rfile parameter. This is a return page after Login
Call objPMod.StoreParameter ( "rfile", "default.asp" )
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_general.asp"-->
<%
'------------ Variable Definition -------------
Dim parPv_id
Dim objUpload
Dim sFileName
Dim sPath
Dim newID
Dim retErrCode
Dim sPkgName
Dim sPkgVersion
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
Set objUpload = New clsUpload
'parPv_id = objUpload.Fields("pv_id").Value
'----------------------------------------------
%>
<%
Sub New_Unit_Test ( nPv_id, _
                                        nTestTypeId, _
                    sTest_summary, _
                    sResults_attachment, _
                    sCompletion_date, _
                                        nFileSize, _
                                        outFileName )
                                        
        ' IN PARAMETERS
        
        OraDatabase.Parameters.Add "PV_ID",                     nPv_id,                         ORAPARM_INPUT,  ORATYPE_NUMBER
        OraDatabase.Parameters.Add "TEST_TYPE_ID",              nTestTypeId,            ORAPARM_INPUT,  ORATYPE_NUMBER
        OraDatabase.Parameters.Add "TEST_SUMMARY",              sTest_summary,          ORAPARM_INPUT,  ORATYPE_VARCHAR2
        OraDatabase.Parameters.Add "DPKG_PATH",                 DOC_FOLDER,             ORAPARM_INPUT,  ORATYPE_VARCHAR2
        

        If nFileSize > 0 Then
                OraDatabase.Parameters.Add "RESULTS",   sResults_attachment,ORAPARM_INPUT,      ORATYPE_VARCHAR2
        Else
                OraDatabase.Parameters.Add "RESULTS",   NULL,                           ORAPARM_INPUT,  ORATYPE_VARCHAR2
        End If
        
        OraDatabase.Parameters.Add "COMPLETION_DATE",   sCompletion_date,                               ORAPARM_INPUT,  ORATYPE_VARCHAR2
        OraDatabase.Parameters.Add "COMPLETED_BY",              objAccessControl.UserId,                ORAPARM_INPUT,  ORATYPE_NUMBER
        OraDatabase.Parameters.Add "enumTEST_TYPE_SANITY",      enumTEST_TYPE_SANITY,   ORAPARM_INPUT,  ORATYPE_NUMBER
        OraDatabase.Parameters.Add "enumTEST_TYPE_NOT_DONE",    enumTEST_TYPE_NOT_DONE, ORAPARM_INPUT,  ORATYPE_NUMBER
        
        
        ' OUT PARAMETERS
        OraDatabase.Parameters.Add "FILENAME",                  "",                                     ORAPARM_OUTPUT, ORATYPE_VARCHAR2
        
        
        
        OraSession.BeginTrans
        
        
        OraDatabase.ExecuteSQL _
        "BEGIN  New_Unit_Test  ( :PV_ID,"&_
    "                        :TEST_TYPE_ID,"&_
    "                        :TEST_SUMMARY,"&_
    "                        :DPKG_PATH,"&_
        "                        :RESULTS,"&_
        "                        :COMPLETION_DATE,"&_
    "                        :COMPLETED_BY,"&_
        "                        :enumTEST_TYPE_SANITY, "&_
        "                        :enumTEST_TYPE_NOT_DONE, "&_
        "                        :FILENAME "&_
        "                                                 );  END;"
        
        
        OraSession.CommitTrans
        
        
        
        outFileName = OraDatabase.Parameters("FILENAME").Value 
        
        
        
        OraDatabase.Parameters.Remove "PV_ID"
        OraDatabase.Parameters.Remove "TEST_TYPE_ID"
        OraDatabase.Parameters.Remove "TEST_SUMMARY"
        OraDatabase.Parameters.Remove "DPKG_PATH"
        OraDatabase.Parameters.Remove "RESULTS"
        OraDatabase.Parameters.Remove "COMPLETION_DATE"
        OraDatabase.Parameters.Remove "COMPLETED_BY"
        OraDatabase.Parameters.Remove "enumTEST_TYPE_SANITY"
        OraDatabase.Parameters.Remove "enumTEST_TYPE_NOT_DONE"
        OraDatabase.Parameters.Remove "FILENAME"
        
End Sub
%>
<%
'-----------------------  MAIN LINE  ---------------------------

'--- Process submission ---

If (objUpload.Fields("pv_id").Value <> "") Then
        
        ' Insert Unit Test Record
        Call Get_Pkg_Short_Info(  objUpload.Fields("pv_id").Value, NULL, sPkgName, sPkgVersion, NULL, NULL, NULL )
        
        Call New_Unit_Test ( objUpload.Fields("pv_id").Value, _
                                                 objUpload.Fields("test_type_id").Value, _
                                                 objUpload.Fields("test_summary").Value, _
                                                 objUpload.Fields("results_file").FileName, _
                                                 objUpload.Fields("completion_date").Value, _
                                                 objUpload.Fields("results_file").Length, _
                                                 sFileName )
        
        
        'If retErrCode <> 0 Then
        '       OraSession.RollBack
        '       Call RaiseMsg ( enum_MSG_DUPLICATE_UT, objUpload.Fields("test_name").Value )
        'End If
        
        ' Upload File
        On Error Resume Next
        If objUpload.Fields("results_file").FileName <> "" Then
                
                If objUpload.Fields("results_file").Length > 0 Then
                        ' Compile path to save file to
                        sPath = Server.MapPath( TEMP_FOLDER )
                        Call Create_Folder ( sPath, sPkgName )
                        
                        sPath = sPath & "\" & sPkgName
                        Call Create_Folder ( sPath, sPkgVersion )
                        
                        sPath = sPath &"\"& sPkgVersion
                        Call Create_Folder ( sPath, DOC_FOLDER )
                        
                        sPath = sPath &"\"& DOC_FOLDER &"\"& sFileName
                        Call DeleteFile( sPath )                ' Delete the file if already exists
                        
                        
                        ' Save the binary data to the file system
                        objUpload("results_file").SaveAs sPath
                End If
                
        End If
        
        If Err.number <> 0 Then
                Call RaiseMsgInParent ( enum_MSG_ERROR, "Upload is not completed.<br>"& Err.description )
        Else%>
        
        <script language="JavaScript" type="text/javascript">
        <!--
        window.opener.location.reload();
        //-->   
        </script>
        <%
                
        End If
        
        'Response.write "PLEASE TRY USING THIS LATER! (Debuging)<br>"& objUpload.Fields("pv_id").Value
        
        
        Set objUpload = Nothing
        Call CloseWindow
        
Else
        Response.write "Some mandatory parameters are missing!" & "<br>" 'TODO
        Response.write QSTR_All 
        
End If
%>


<!-- DESTRUCTOR ------->
<!--#include file="common/globals_destructor.asp"-->