Subversion Repositories DevTools

Rev

Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | RSS feed 

<%
'===================================================================
'                                               Bom Browser Control
'===================================================================
%>
<%
'------------ VARIABLE DEFINITION -------------
Dim rsBomTree
'------------ CONSTANTS DECLARATION -----------
Const IMG_INDENT1 = "<img src='images/spacer.gif' width='15' height='5' align='absmiddle' border='0'>"
Const IMG_INDENT2 = "<img src='images/spacer.gif' width='40' height='5' align='absmiddle' border='0'>"
'------------ VARIABLE INIT -------------------
'----------------------------------------------
%>
<%
'----------------------------------------------------------------------------------------------------------------------------------------------
Function BBSelectorStyle ( nRowID, nParID, nLevel )
        
        BBSelectorStyle = "menu_link"
        
        If dbPARprod_id <> enumDB_DEFAULT_EMPTY Then
                If ( CStr(nRowID) =  CStr(nParID) ) AND ( nLevel = 2 ) Then BBSelectorStyle = "menu_linkselect"
                
        ElseIf dbPARos_id <> enumDB_DEFAULT_EMPTY Then
                If ( CStr(nRowID) =  CStr(nParID) ) AND ( nLevel = 1 ) Then BBSelectorStyle = "menu_linkselect"
                
        ElseIf dbPARnode_id <> enumDB_DEFAULT_EMPTY Then
                If ( CStr(nRowID) =  CStr(nParID) ) AND ( nLevel = 0 ) Then BBSelectorStyle = "menu_linkselect"
                
        ElseIf dbPARbom_id <> enumDB_DEFAULT_EMPTY Then
                If ( nLevel = -1 ) Then BBSelectorStyle = "menu_linkselect"
                
        End If
        
        
End Function
'----------------------------------------------------------------------------------------------------------------------------------------------
Function ChangeLogDecoder ( cFlag )
        Select Case cFlag
                Case "U"
                        ChangeLogDecoder = "<SPAN class='body_txtr'>&nbsp;(updated)</SPAN>"
                Case enumDB_NO
                        ChangeLogDecoder = "<SPAN class='body_txtr'>&nbsp;(added)</SPAN>"
                Case Else
                        ChangeLogDecoder = NULL
        End Select
End Function
'----------------------------------------------------------------------------------------------------------------------------------------------
Sub BrowserActionButtons ()
        Dim objAbtnControl, abdQuery, rsAbtnDef, AbtnName, aAbtnList
        
        Set objAbtnControl = New ActionButtonControl
        
        
        If dbPARprod_id <> enumDB_DEFAULT_EMPTY Then
                ' Product Level
                aAbtnList = Array( "abtnNew", "abtnProdProperties", "width=5", "abtnProdRemove", "width=5", "abtnAcceptRejectProd", "width=5", "abtnRMlink" )

                
        ElseIf dbPARbom_id <> enumDB_DEFAULT_EMPTY Then
                ' Bom Level
                aAbtnList = Array( "abtnNew", "abtnBomProperties" )
                
        Else
                aAbtnList = Array ( enumDB_DEFAULT_EMPTY )              ' This will return no results
                
        End If
        
        
        ' -- Load Action Buttons
        Call objAbtnControl.LoadActionButtons ( aAbtnList, OraDatabase )
        
        ' -- Set ButtonText Space
        objAbtnControl.ButtonTextSpacer = 2
        
        ' -- Tell control if buttons need to be readonly actions 
        objAbtnControl.IsReadonlyAction = objBomCollector.Item("is_readonly")
        
        ' -- Render Buttons
        Call objAbtnControl.Render  ( aAbtnList )
        
        Set objAbtnControl = Nothing
End Sub
'----------------------------------------------------------------------------------------------------------------------------------------------
%>
<%
'------------ RUN BEFORE CONTROL RENDER -------
'----------------------------------------------
%>

<!-- BOM BROWSER ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->

<%If Request.Cookies( enumCOOKIE_NAME )( "bom_browser" ) = "hide" Then%>
        <a href="<%=SCRIPT_NAME%>?bom_browser=<%=enumDEFAULT%>&<%=objPMod.ComposeURL()%>"><img src="icons/b_right.gif" width="13" height="13" border="0" hspace="2" vspace="3" title="Maximize BOM Browser"></a>
        
<%Else%>

<table width="100%"  border="0" cellspacing="0" cellpadding="5">
  <form name="Find" method="get" action="FindInBom.asp">
  <tr>
    <td width="100%" background="images/bg_bage_1.gif" nowrap><span class="body_smltxt">Find in BOM:</span><br>
      <input name="keyword" type="text" class="form_iname" size="25" value="<%=Request("keyword")%>">
      <input name="btn" type="submit" class="form_iname" value="Go"></td>
        <td width="1" valign="top" background="images/bg_bage_1.gif"><a href="<%=SCRIPT_NAME%>?bom_browser=hide&<%=objPMod.ComposeURL()%>"><img src="icons/b_left.gif" width="13" height="13" border="0" title="Minimize BOM Browser"></a></td>
  </tr>
  <input type="hidden" name="bom_id" value="<%=dbPARbom_id%>">
  </form>
</table>

<%
'-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-
'objAccessControl.BeginRegion ( "oProjectList" )
'If objAccessControl.IsVisible ( "oProjectList" ) Then
%>
<!-- ACTION BUTTONS +++++++++++++ -->
<table width="100%"  border="0" cellspacing="0" cellpadding="5">
  <tr>
    <td width="100%" nowrap background="images/bg_bage_0a.gif"><%Call BrowserActionButtons ()%></td>
  </tr>
</table>
        <!-- MENU OPTIONS NEW ... -->
        <!--#include file="_menu_option_abtn_new.asp"-->
        <!-- MENU OPTIONS NEW ... -->
<!-- ACTION BUTTONS END +++++++++ -->
<%
'End If
'objAccessControl.EndRegion ( "oProjectList" )
'-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-
%>

<!-- BOM BROWSER ++++++++++++++++ -->
<table width="100%"  border="0" cellspacing="5" cellpadding="0">
  <tr>
    <td><table width="100%"  border="0" cellspacing="2" cellpadding="0">
          <tr>
        <td nowrap><img src="images/spacer.gif" width="15" height="19" hspace="2" vspace="1" align="absmiddle"><a href="Bom_Home.asp?bom_id=<%=dbPARbom_id%>" class="<%=BBSelectorStyle ( 0, 0, -1 )%>">BOM Home</a></td>
      </tr>
      <tr>
        <td nowrap background="images/bg_bage_1.gif"><img src="images/spacer.gif" width="1" height="1"></td>
      </tr>
      
          <%
          OraDatabase.Parameters.Add "BOM_ID",  dbPARbom_id,    ORAPARM_INPUT, ORATYPE_NUMBER 
          OraDatabase.Parameters.Add "NODE_ID", dbPARnode_id,   ORAPARM_INPUT, ORATYPE_NUMBER 
          
          
          
          ' Keep OS_ID at 0 if you do not want to expand packages on tree view. Else replace 0 with dbPARos_id
          OraDatabase.Parameters.Add "OS_ID",   0,      ORAPARM_INPUT, ORATYPE_NUMBER 
          
          
          
          Set rsBomTree = OraDatabase.DbCreateDynaset( GetQuery ("BomBrowser.sql") , ORADYN_DEFAULT )
          
          While ((NOT rsBomTree.BOF) AND (NOT rsBomTree.EOF))
          %>
      <%If rsBomTree("prod_id") <> 0 Then%>
                <tr>
                <td nowrap><%=IMG_INDENT2%><a href="ProdDefault.asp?bom_id=<%=dbPARbom_id%>&os_id=<%=rsBomTree("os_id")%>&prod_id=<%=rsBomTree("prod_id")%>" class="menu_link"><%=GetProductIcon( rsBomTree )%><SPAN class="<%=BBSelectorStyle( rsBomTree("prod_id"), dbPARprod_id, 2 )%>"><%=rsBomTree("prod_name")%></SPAN></a><%=ChangeLogDecoder( rsBomTree("change_log_flag") )%></td>
        </tr>
          <%ElseIf rsBomTree("os_id") <> 0 Then%>
                <tr>
                <td nowrap><a href="OsDefault.asp?bom_id=<%=dbPARbom_id%>&os_id=<%=rsBomTree("os_id")%>" class="menu_link"><%=IMG_INDENT1%><%=Expander ( rsBomTree("expand") )%><img src="icons/<%=rsBomTree("bos_icon")%>" width="19" height="19" hspace="2" border="0" align="absmiddle"><SPAN class="<%=BBSelectorStyle( rsBomTree("os_id"), dbPARos_id, 1 )%>"><%=rsBomTree("os_name")%></SPAN></a></td>
        </tr>
          <%Else%>
                <tr>
                <td nowrap><a href="NodeDefault.asp?bom_id=<%=dbPARbom_id%>&node_id=<%=rsBomTree("node_id")%>" class="menu_link" title="<%=rsBomTree("node_version") &"."& rsBomTree("node_life_cycle") %>"><%=Expander ( rsBomTree("expand") )%><img src="icons/<%=rsBomTree("node_icon")%>" width="19" height="19" hspace="4" border="0" align="absmiddle"><SPAN class="<%=BBSelectorStyle( rsBomTree("node_id"), dbPARnode_id, 0 )%>"><%=rsBomTree("node_name")%></SPAN></a></td>
        </tr>
          <%End If%>
          <% 
                rsBomTree.MoveNext
          WEnd
          
          rsBomTree.Close
          Set rsBomTree = Nothing
          OraDatabase.Parameters.Remove "BOM_ID"
          OraDatabase.Parameters.Remove "NODE_ID"
          OraDatabase.Parameters.Remove "OS_ID"
          %>
    </table></td>
  </tr>
</table>
<img src="images/spacer.gif" width="200" height="1">


<%End If%>
<!-- BOM BROWSER END ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
<%
'------------ RUN AFTER CONTROL RENDER --------
'----------------------------------------------
%>