Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|                                wProdRejectNote                                |
'|                                                   |
'=====================================================
%>
<%
Option explicit
Response.Expires = 0
%>
<!--#include file="common/globals.asp"-->
<!--#include file="common/config.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/_popup_window_common.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_general.asp"-->
<%
'------------ VARIABLE DEFINITION -------------
Dim objFormCollector
Dim parReject_seq
'------------ CONSTANTS DECLARATION -----------
'------------ VARIABLE INIT -------------------
parProd_id = Request("prod_id")
parReject_seq = Request("reject_seq")
Set objFormCollector = CreateObject("Scripting.Dictionary")
'------------ CONDITIONS ----------------------
'----------------------------------------------
%>
<%
'--------------------------------------------------------------------------------------------------------------------------
Sub GetFormDetails ( nProd_id, nReject_seq, ByRef outobjDetails )
        Dim rsQry, query
        OraDatabase.Parameters.Add "ENTITY_ID",                 nProd_id,       ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "REJECT_SEQ",                nReject_seq,ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "ENUM_ENTITY_TYPE",  "enumENTITY_TYPE_PRODUCT",      ORAPARM_INPUT, ORATYPE_VARCHAR2
        
        query = _
        " SELECT rt.COMMENTS"&_
        "   FROM REJECTION_TRAIL rt "&_
        "  WHERE rt.ENUM_ENTITY_TYPE = GET_SYSTEM_VALUE( :ENUM_ENTITY_TYPE ) "&_
        "    AND rt.ENTITY_ID = :ENTITY_ID "&_
        "    AND rt.REJECT_SEQ = :REJECT_SEQ  "
        
        Set rsQry = OraDatabase.DbCreateDynaset( query , ORADYN_DEFAULT )
        
        
        outobjDetails.Item ("comments") = NULL
        If ((NOT rsQry.BOF) AND (NOT rsQry.EOF)) Then
                outobjDetails.Item ("comments")   = rsQry("comments")
                
        End If
        
        OraDatabase.Parameters.Remove "ENTITY_ID"
        OraDatabase.Parameters.Remove "REJECT_SEQ"
        OraDatabase.Parameters.Remove "ENUM_ENTITY_TYPE"
        
        rsQry.Close
        Set rsQry = Nothing
End Sub
'--------------------------------------------------------------------------------------------------------------------------
Sub ProdRejectNote ()
        On Error Resume Next
        
        OraDatabase.Parameters.Add "PROD_ID",           Request("prod_id"),     ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "REJECT_SEQ",        Request("reject_seq"),  ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "COMMENTS",          Request("reject_note"), ORAPARM_INPUT, ORATYPE_VARCHAR2
        OraDatabase.Parameters.Add "USER_ID",           objAccessControl.UserId,ORAPARM_INPUT, ORATYPE_NUMBER 
        
        
        objEH.TryORA ( OraSession )
        
        OraDatabase.ExecuteSQL _
        "BEGIN pk_Product.Accept_Reject_Comments ( :PROD_ID, :REJECT_SEQ, :COMMENTS, :USER_ID ); END;"  
        
        objEH.CatchORA ( OraSession )
        
        
        OraDatabase.Parameters.Remove "PROD_ID"
        OraDatabase.Parameters.Remove "REJECT_SEQ"
        OraDatabase.Parameters.Remove "COMMENTS"
        OraDatabase.Parameters.Remove "USER_ID"
        
End Sub
'--------------------------------------------------------------------------------------------------------------------------
%>
<%
'------------ RUN BEFORE PAGE RENDER ----------
' --- Get Form details from DB ---
Call GetFormDetails ( parProd_id, parReject_seq, objFormCollector )

' --- Load Validation Rules ---
Call objForm.LoadValidationRules ( Array("reject_note"), OraDatabase )          ' Load Validation Rules

' --- Enter Form Validation Rule Changes here... ----
'----------------------------------------------------

If CBool(Request("action")) Then
        If objForm.IsValidOnPostBack Then
                ' --- Form is Valid ---
                Call ProdRejectNote()
                
                If objEH.Finally Then
                        Call OpenInParentWindow ( Request("rfile") &"?"& objPMod.ComposeURL() )
                        Call CloseWindow()
                End If
                
        End If
End If

'----------------------------------------------
%>
<html>
<head>
<title>Deployment Manager</title>
<link rel="shortcut icon" href="<%=FavIcon%>"/>
<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link href="scripts/deployment_manager.css?ver=<%=VixVerNum%>" rel="stylesheet" type="text/css">
<script language="JavaScript" src="scripts/common.js?ver=<%=VixVerNum%>"></script>
</head>

<body background="images/bg_bage_0.gif" leftmargin="0" topmargin="0" onLoad="self.focus();FormName.reject_note.focus();">
<table width="100%"  border="0" cellspacing="0" cellpadding="10">
  <tr>
    <td bgcolor="#FFFFFF" class="body_txt"><span class="body_h1"><img src="icons/i_linkarrow_black.gif" width="11" height="11" align="absmiddle">&nbsp;Note</span> <br>
    Enter note details and click submit. 
    </td>
  </tr>
  <form name="FormName" method="post" action="<%=SCRIPT_NAME%>" onSubmit="ShowProgress();">
  <tr>
    <td background="images/bg_login.gif"><table width="100%"  border="0" cellspacing="0" cellpadding="0">
      <tr>
        <td><%=ProgressBar%></td>
        <td align="right"><input name="btn" type="submit" class="form_btn" value="Submit">
          <input name="btn" type="reset" class="form_btn" value="Cancel" onClick="self.close();"></td>
      </tr>
    </table></td>
  </tr>
  <tr>
    <td><table width="100%"  border="0" cellspacing="2" cellpadding="0">
          <!-- MESSAGE +++++++++++++++++++++++++++++++++++++++++++++++++++ -->  
          <%If NOT objEH.Finally Then%>
      <tr>
        <td class="form_iname">&nbsp;</td>
        <td>
                 <%objEH.DisplayMessage()%>
                </td>
        <td class="val_err"></td>
      </tr>
          <%End If%>
          <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
      <tr>
        <td valign="top" nowrap class="form_iname">Note</td>
        <td valign="top"><textarea name="reject_note" cols="80" rows="16" class="form_ivalue"><%=objForm.GetValue( "reject_note", objFormCollector.Item("comments")) %></textarea></td>
                <td valign="top">
                <%=objForm.Validate ("reject_note")%>
                </td>
      </tr>
      <tr>
        <td width="10%" class="form_iname">&nbsp;</td>
        <td width="1%">&nbsp;</td>
                <td width="90%" class="val_err"></td>
      </tr>
    </table></td>
  </tr>
  <%=objPMod.ComposeHiddenTags()%>
  <input type="hidden" name="reject_seq" value="<%=parReject_seq%>">
  <input type="hidden" name="action" value="true">
  </form>
</table>
</body>
</html>
<!--#include file="common/globals_destructor.asp"-->