Subversion Repositories DevTools

Rev

Rev 5958 | Blame | Compare with Previous | Last modification | View Log | RSS feed 

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|                                      MESSAGE                                      |
'|                                                   |
'=====================================================
%>
<%
Option explicit
' Good idea to set when using redirect
Response.Expires = 0    ' always load the page, dont store
%>
<%
'------------ Variable Definition -------------
Dim parMsg, reqParam, ERRlog, ERRlogFULL, AdditionalParams
Dim MSG, msgFile, i, parArr, parJustemplate, parLinksON
'------------ Constants Declaration -----------
'------------ Variable Init -------------------
parMsg = QStrPar("msg")                                                 ' message template
reqParam = Session("reqParam")                                  ' parameters passed for processing
ERRlog = Session("ERRlog")                                              ' pkgs with errors + error type
ERRlogFULL = Session("ERRlogFULL")                              ' full list of submitted packages
AdditionalParams = Session("AdditionalParams")  ' additional parameters populating message template
parJustemplate = QStrPar("justemplate")
parLinksON = QStrPar("linksON")
'----------------------------------------------
%>
<!--#include file="common/config.asp"-->
<!--#include file="common/globals.asp"-->
<!--#include file="common/formating.asp"-->
<!--#include file="common/qstr.asp"-->
<!--#include file="common/common_subs.asp"-->
<%
Function Format_ERRlog( SSerrLog, SSerrFull )
        ' SSerrLog = "|pkgn,pkgv,errtype||pkgn,pkgv,errtype||pkgn,pkgv,errtype|"
        ' SSerrFull       = "|pkgn,pkgv||pkgn,pkgv|"   contains all submitted items
        
        
        Dim errDetSTR, errlistARR, fullARR, pkgpair, pkgdetailsARR, errDetARR, errItem, errTypesUsed
        Dim item, i, tempARR, tmpStr, errcolumnsARR, columnDrawn, mypkgname, mypkgversion
        
        Set errTypesUsed = CreateObject("Scripting.Dictionary")
        
        errlistARR = SplitPipes( SSerrLog )             'split  |pkgn,pkgv,errtype||pkgn,pkgv,errtype|
        fullARR = SplitPipes( SSerrFull )                       'split  |pkgpair1||pkgpair2|
        
        errDetSTR = ""
        errDetSTR =  errDetSTR & "<table width='100%' border='0' cellspacing='1' cellpadding='3' >"
        '==== Error Column Names ================
        For Each item In errlistARR
                tempARR = Split (item, ",")             'split  pkgn,pkgv,errtype
                If NOT errTypesUsed.Exists (tempARR(2)) Then errTypesUsed.ADD Cstr(tempARR(2)),""
        Next
        errcolumnsARR = errTypesUsed.Keys
        Set errTypesUsed = nothing
        
        ' draw error columns
        errDetSTR =  errDetSTR & "<tr><td><img src='images/h_trsp_dot.gif' width='40' height='1'></td><td></td>"
        For Each item In errcolumnsARR
                errDetSTR =  errDetSTR & "<td nowrap class='err_alert' background='images/bg_lght_gray.gif'>"& Error_Details ( item ) &" <a href='javascript:;' onMouseOver=""formTips.show('err"& item &"')"" onMouseOut=""formTips.hide()""><img src='images/i_help.gif' width='12' height='12' hspace='2' align='absmiddle' border='0' ></a></td>"
        Next
        errDetSTR =  errDetSTR & "</tr>"
        
        
        '==== Error Details =====================
        For Each pkgpair In fullARR
                pkgdetailsARR = Split(pkgpair, ",")             'split  pkg_name,pkg_version
                
                errItem = Filter(errlistARR, pkgdetailsARR(0) &",", True)
                errItem = Join(errItem, ",")
                
                mypkgname = pkgdetailsARR(0)
                mypkgversion = pkgdetailsARR(1)
                
                If errItem <> "" Then
                        'error FOUND for pkg_name
                        errDetARR = Split(errItem, ",")         'split  pkgn,pkgv,errtype
                        
                        errDetSTR = errDetSTR &_
                                        "<tr>"&_
                            "<td nowrap background='images/bg_lght_gray.gif' class='err_sol'>"& mypkgname &"</td>"&_
                            "<td nowrap background='images/bg_lght_gray.gif' class='err_sol'>"& mypkgversion &"</td>"
                        
                        'run through all error types if multiple pkgs found
                        columnDrawn = FALSE
                        For Each item In errcolumnsARR
                                
                                For i = 0 To UBound(errDetARR) Step 3
                                        If item = errDetARR(i+2) Then
                                                If (parLinksON <> "") AND (item = 4) Then
                                                        errDetSTR = errDetSTR & "<td background='images/bg_lght_gray.gif' align='center' class='err_sol'>"&_
                                                                                                        "<a href='#' onClick=""MM_openBrWindow('see_circular_dependencies.asp?pkgN="& mypkgname &"&pkgV="& mypkgversion & QSTR &"','ReleaseManager','scrollbars=yes,resizable=yes,width=500,height=300')"" class='txt_linked'><b>x</b></a></td>"
                                                Else
                                                        errDetSTR = errDetSTR & "<td background='images/bg_lght_gray.gif' align='center' class='err_sol'>x</td>"
                                                End If
                                                columnDrawn = TRUE
                                                Exit For
                                        End If
                                Next
                                
                                If NOT columnDrawn Then errDetSTR = errDetSTR & "<td background='images/bg_lght_gray.gif'>&nbsp;</td>"
                                columnDrawn = FALSE
                                
                        Next
                        errDetSTR = errDetSTR & "</tr>"
                        
                Else
                        'error NOT FOUND for pkg_name
                        errDetSTR = errDetSTR &_
                                                "<tr>"&_
                                    "<td nowrap background='images/bg_lght_gray.gif' class='err_sol'>"& mypkgname &"</td>"&_
                                    "<td nowrap background='images/bg_lght_gray.gif' class='err_sol'>"& mypkgversion &"</td>"
                                                For Each item In errcolumnsARR
                                                        errDetSTR = errDetSTR & "<td background='images/bg_lght_gray.gif'>&nbsp;</td>"
                                                Next
                                                errDetSTR = errDetSTR & "</tr>"
                End If
                
                errItem = ""    'clean errItem
        Next
        errDetSTR = errDetSTR & "</table>"
        
        Format_ERRlog = errDetSTR
End Function


Function Format_reqParam( SSreqParam )
        ' SSreqParam = "|parname=parvalue||parname=parvalue|"
        Dim errReqSTR, reqParamARR, tempARR, item
        
        '==== Required Parameters ===============
        errReqSTR = ""
        reqParamARR = SplitAmpasans( SSreqParam )       'split  &par=value&&par=value&
        
        For Each item In reqParamARR
                tempARR = Split(item, "=")                      'split par=value
                errReqSTR = errReqSTR & "<input type='hidden' name='"& tempARR(0) &"' value='"& URLEncode(tempARR(1)) &"'>" & VBNewLine
        Next
        
        Format_reqParam = errReqSTR
End Function


Private Function Error_Details ( NNerrnum )
        Dim errorType
        Set errorType = CreateObject("Scripting.Dictionary")
        '--- load error definition ------------------
        errorType.ADD           "1","VERSION NOT FOUND"
        errorType.ADD           "2","VERSION EXISTS"
        errorType.ADD           "3","DUPLICATE PACKAGE NAME"
        errorType.ADD           "4","CIRCULAR DEPENDENCY"
        errorType.ADD           "5","EXISTS IN THIS RELEASE"
        'this must match descriptions in images/_help_tips.js   e.g. errorType 1 has decsription err1
        '--------------------------------------------
        Error_Details = errorType.Item (Cstr( NNerrnum ))
End Function
%>
<%
'-----------------------  MAIN LINE  ---------------------------
'Read the message template
MSG = ReadFile( rootPath &"messages\"& parMsg &".html" )

'== $TABLE$ parameter ================
If ERRlog <> "" Then
        MSG = Replace( MSG, "$TABLE$", Format_ERRlog( ERRlog, ERRlogFULL) )
End If

'== $HIDDEN$ =========================
If reqParam <> "" Then
        MSG = Replace( MSG, "$HIDDEN$", Format_reqParam( reqParam ) )
End If

'== AdditionalParams =================
If AdditionalParams <> "" Then
        parArr = Split(AdditionalParams, ",")
        For i = 0 To UBound(parArr) Step 2
                MSG = Replace( MSG, parArr(i), parArr(i+1) )
        Next
End If

'== Query String parameter ===========
MSG = Replace( MSG, "$QSTR$", QSTR_All )

'== Clean the session variables ======
Session("reqParam") = ""
Session("ERRlog") = ""
Session("ERRlogFULL") = ""
Session("AdditionalParams") = ""
%>
<%If parJustemplate <> "" Then%>
        <%Response.write MSG%>
<%Else%>
<html>
<head>
<title>Deployment Manager</title>
<link rel="shortcut icon" href="<%=FavIcon%>"/>
<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link href="scripts/deployment_manager.css?ver=<%=VixVerNum%>" rel="stylesheet" type="text/css">
<link rel="stylesheet" href="images/release_manager_style.css?ver=<%=VixVerNum%>" type="text/css">
<link rel="stylesheet" href="images/navigation.css?ver=<%=VixVerNum%>" type="text/css">
<script language="JavaScript" src="scripts/common.js?ver=<%=VixVerNum%>"></script>
<!-- TIPS -->
<script language="JavaScript" src="images/tipster.js?ver=<%=VixVerNum%>"></script>
<script language="JavaScript" src="images/_help_tips.js"></script>
</head>
<body bgcolor="#FFFFFF" text="#000000" leftmargin="0" topmargin="0" >
<!-- MENU LAYERS -------------------------------------->
<div id="popmenu" class="menuskin" onMouseover="clearhidemenu();highlightmenu(event,'on')" onMouseout="highlightmenu(event,'off');dynamichide(event)"> 
</div>
<!-- TIPS LAYERS -------------------------------------->
<div id="formTipsLayer" style="position: absolute; z-index: 1000; visibility: hidden; left:0; top: 0; width: 10">&nbsp;</div>
<!----------------------------------------------------->
<!-- HEADER -->
<!--#include file="_header.asp"-->
<!-- BODY ---->
<table width="100%" border="0" cellspacing="0" cellpadding="0">
  <tr>
    <td background="images/bg_lght_gray.gif" align="left" valign="top"> 
      <table width="100%" border="0" cellspacing="0" cellpadding="0">
        <tr> 
          <td valign="top" width="1%"><img src="images/h_trsp_dot.gif" width="10" height="10"></td>
          <td valign="top" width="1%">
                  <!-- LEFT -->
                  </td>
          <td valign="top" width="1%"><img src="images/h_trsp_dot.gif" width="30" height="550"></td>
          <td valign="top" width="100%">
                  <!-- MIDDLE -->
                        <table width="650" border="0" cellspacing="0" cellpadding="0">
                          <tr> 
                            <td> 
                              <table width="100%" border="0" cellspacing="0" cellpadding="0">
                                <tr> 
                                  <td width="1%">&nbsp;</td>
                                  <td align="right"><img src="images/h_trsp_dot.gif" width="30" height="30"></td>
                                  <td width="1%">&nbsp;</td>
                                </tr>
                                <tr> 
                                  <td width="1%">&nbsp;</td>
                                  <td> 
                                    <table width="100%" border="0" cellspacing="0" cellpadding="0">
                                      <tr> 
                                        <td nowrap class="form_ttl"></td>
                                        <td align="right" valign="bottom">
                                          <!-- TABS -->
                                                          &nbsp;
                                        </td>
                                      </tr>
                                    </table>
                                  </td>
                                  <td width="1%">&nbsp;</td>
                                </tr>
                                <tr> 
                                  <td align="left" valign="top" width="1%" background="images/lbox_bg_blue.gif"><img src="images/lbox_tl_cnr_b.gif" width="13" height="13"></td>
                                  <td background="images/lbox_bg_blue.gif"></td>
                                  <td align="right" valign="top" width="1%" background="images/lbox_bg_blue.gif"><img src="images/lbox_tr_cnr_b.gif" width="13" height="13"></td>
                                </tr>
                                <tr> 
                                  <td width="1%" bgcolor="#FFFFFF"><img src="images/h_trsp_dot.gif" width="10" height="100"></td>
                                  <td bgcolor="#FFFFFF" valign="top"> 
                                    <!-- Body -->
                                                <%Response.Write MSG%>
                                    <!-- END Body-->
                                  </td>
                                  <td width="1%" background="images/lbox_bgside_white.gif">&nbsp;</td>
                                </tr>
                                <tr> 
                                  <td width="1%" background="images/lbox_bg_blue.gif" valign="bottom"><img src="images/lbox_bl_cnr_b.gif" width="13" height="13"></td>
                                  <td background="images/lbox_bg_blue.gif"></td>
                                  <td width="1%" background="images/lbox_bg_blue.gif" valign="bottom" align="right"><img src="images/lbox_br_cnr_b.gif" width="13" height="13"></td>
                                </tr>
                              </table>
                            </td>
                          </tr>
                        </table>                  
                  </td>
        </tr>
      </table>
    </td>
  </tr>
</table>
<!-- FOOTER -->
<!--#include file="_footer.asp"-->
</body>
</html>
<%End If%>