Subversion Repositories DevTools

<?xml version="1.0" ?>
<package>
        <comment>
        PrimalCode wizard generated file.
        </comment>
        <job id="GenerateXMLNodeDefinitons" args="/bom_id:2864" prompt="no">
                <?job error="false" debug="false" ?>
                <runtime>
                        <named helpstring="Bom ID" name="bom_id" required="false" type="string"/>
                </runtime>
                <object id="Oracle_Objects_For_OLE" progid="OracleInProcServer.XOraServer" events="true"/>
                <script language="VBScript" src="common_subs.vbs"/>
                <script language="VBScript" src="config.vbs"/>
                <script id="GenerateXMLNodeDefnitions" language="VBScript">
<![CDATA[
Option Explicit
'=====================================================
'        Name:  GetComponents
' Description:  Connects to dpkg_archive and gets the
'                               content of folders and files of certain
'                               package. It then stores this info into 
'                               Release Manager database. This info can
'                               later be included in release notes Or
'                               searched with search engine.
'               INPUT:  pkg_name
'                               pkg_version
'=====================================================

'== Variable Definition ==============================
Dim BomId
Dim objArgs
'== Constants Declaration ============================
'== Variable Init ====================================
'=====================================================


'-----------------------------------------------------------------------------------------------------------------
Sub GenerateXMLNodeDefinitions ( nBomId )
        Dim rsQry, aNetworkNodes, XMLNode, DateString
        Dim lastRow, row
        
        ' Remove existing stuff
        Call DeleteFile( APP_ROOT &"downloads\*" )
        
        
        OraDatabase.Parameters.Add "BOM_ID", nBomId, ORAPARM_INPUT, ORATYPE_NUMBER 
                          
        Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("NetworkNodes.sql"), ORADYN_DEFAULT )
        
        OraDatabase.Parameters.Remove "BOM_ID"
        
        If rsQry.RecordCount > 0 Then
                aNetworkNodes = rsQry.GetRows()
                
        End If
        
        lastRow = UBound( aNetworkNodes, 2 )
        DateString = DateReversed( Date )
        
        For row = 0 To lastRow
                
                XMLNode = Null
        
                XMLNode = XMLNode &_
                "       <BomHeader>"& vbNewLine &_
                "               <release_ident></release_ident>"& vbNewLine &_
               "               <bom_name>"& aNetworkNodes( 1, row ) &"</bom_name>"& vbNewLine &_
               "               <bom_type>system</bom_type>"& vbNewLine &_
               "               <bom_version>"& aNetworkNodes( 2, row ) &"."& aNetworkNodes( 3, row ) &"</bom_version>"& vbNewLine &_
               "               <bom_date>"& DateString &"</bom_date>"& vbNewLine &_
               "               <bom_status>REG</bom_status>"& vbNewLine &_
               "               <bom_status_date>"& DateString &"</bom_status_date>"& vbNewLine &_
                "       </BomHeader>"& vbNewLine 
                
                
                '-- Get Node Details --
                XMLNode = XMLNode & GetNodeDetails ( nBomId, aNetworkNodes( 0, row ) ) & vbNewLine 
                
                
                ' Close xml node tag before saving
                XMLNode = _
                "<BomDistribution>"& vbNewLine &_
                XMLNode &"</BomDistribution>"& vbNewLine
                
                'WScript.Echo XMLNode
                
                
                ' Save to a file
                Call SaveFile( DateString, rsQry("version"), rsQry("branch_name"), APP_ROOT &"downloads",  FormatFileName( aNetworkNodes( 1, row ) ) &".xml", XMLNode )
                
                
        Next
        
        
        
                  
                        
End Sub
'-----------------------------------------------------------------------------------------------------------------
Function FormatFileName ( sFileName )
        Dim sReturn
        
        sReturn = Replace ( sFileName, "/", "" )        
        sReturn = Replace ( sReturn, "\", "" )  
        sReturn = Replace ( sReturn, "&", "And" )       
        sReturn = Replace ( sReturn, " ", "_" )         
        
        FormatFileName = sReturn
        
End Function
'-----------------------------------------------------------------------------------------------------------------
Function GetNodeDetails ( nBomId, nNodeId )
        Dim rsQry, XMLPackageString
        
        OraDatabase.Parameters.Add "BOM_ID", nBomId, ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "NODE_ID", nNodeId, ORAPARM_INPUT, ORATYPE_NUMBER 
                  
        Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("NodeProducts.sql"), ORADYN_DEFAULT )
        
        OraDatabase.Parameters.Remove "BOM_ID"
        OraDatabase.Parameters.Remove "NODE_ID"
        
        
        While (NOT rsQry.BOF) AND (NOT rsQry.EOF)
                
                XMLPackageString = XMLPackageString &_
                "       <PackageRecord>"& vbNewLine &_
                "               <pkg_name>"& rsQry("pkg_name") &"</pkg_name>"& vbNewLine &_
               "               <pkg_version>"& rsQry("pkg_version") &"</pkg_version>"& vbNewLine &_
               "               <pkg_date>2003-03-01</pkg_date>"& vbNewLine &_
               "               <pkg_status>REG</pkg_status>"& vbNewLine &_
               "               <pkg_status_date>"& DateReversed( CDate( rsQry("modified_stamp") ) ) &"</pkg_status_date>"& vbNewLine &_
               "               <pkg_target></pkg_target>"& vbNewLine &_
        "               <pkg_platform_list>"& vbNewLine &_
        "                       <platform_record>"& rsQry("bos_type") &"</platform_record>"& vbNewLine &_
        "               </pkg_platform_list>"& vbNewLine &_ 
               "               <pkg_release_type>IR</pkg_release_type>"& vbNewLine &_
                "       </PackageRecord>"& vbNewLine
                
                
                rsQry.MoveNext()
        Wend    
        
        rsQry.Close()
        Set rsQry = Nothing
        
        ' Return string
        GetNodeDetails = XMLPackageString       
        
End Function
'-----------------------------------------------------------------------------------------------------------------



'=================================== MAIN LINE ======================================
WScript.Echo "==================== job:GenerateXMLNodeDefenitions ===================="

Set objArgs = WScript.Arguments

If (objArgs.Unnamed.Count > 0) Then
        Wscript.Echo "ERROR: Unnamed parameters!"
        objArgs.ShowUsage
        WScript.Quit
        
Else
        BomId = objArgs.Named.Item("bom_id")
                
        If ( BomId <> "" ) Then
                Call GenerateXMLNodeDefinitions( BomId )
                        
        Else
                objArgs.ShowUsage
                WScript.Quit
                
        End If
        
End If


WScript.Echo "Job completed successfully!"

'====================================================================================


]]>
                </script>
        </job>
</package>