Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|                                _AddProd                                               |
'|                                                   |
'=====================================================
%>
<%
Option explicit
Response.Expires = 0
%>
<!--#include file="common/globals.asp"-->
<!--#include file="common/config.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/_code_behind_common.asp"-->
<!--#include file="common/_popup_window_common.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_general.asp"-->
<%
'------------ VARIABLE DEFINITION -------------
'------------ CONSTANTS DECLARATION -----------
'------------ VARIABLE INIT -------------------
'------------ CONDITIONS ----------------------
'----------------------------------------------
%>
<%
'--------------------------------------------------------------------------------------------------------------------------
Sub AddProdToOs ()
        Dim aPkgIdList, PkgId, OraParameter
        On Error Resume Next
        objEH.ErrorRedirect = TRUE
        
        OraDatabase.Parameters.Add "PKG_ID",            0,                                                      ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "PROD_VERSION",      NULL,                                           ORAPARM_INPUT, ORATYPE_VARCHAR2
        OraDatabase.Parameters.Add "COMMENTS",          NULL,                                           ORAPARM_INPUT, ORATYPE_VARCHAR2
        OraDatabase.Parameters.Add "OS_ID",             Request("os_id"),                       ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "USER_ID",           objAccessControl.UserId,        ORAPARM_INPUT, ORATYPE_NUMBER 
        
        Set OraParameter = OraDatabase.Parameters
        
        
        objEH.TryORA ( OraSession )
        
        aPkgIdList = Split ( Replace ( Request("pkg_id_list"), " ", ""  ), "," )
        
        For Each PkgId In aPkgIdList
                
                OraParameter("PKG_ID").Value = PkgId
                OraParameter("PROD_VERSION").Value = Request("pkgid"& PkgId )
                OraParameter("COMMENTS").Value     = Request("comments"& PkgId )
                
                OraDatabase.ExecuteSQL _
                "BEGIN   pk_Operating_System.Add_Product_Wrap ( :PKG_ID, :PROD_VERSION, :OS_ID, :USER_ID, :COMMENTS );   END;"
                
        Next
        
        '--- Log Action ---
        objEH.LogAction  _
        objAccessControl.UserId, _
        enumAT_EVENT_COMMENT, _
        "Sub AddProdToOs at os_id="& Request("os_id"), _
        SCRIPT_NAME, _
        "Added Products to OS.", _
        OraDatabase
                
        objEH.CatchORA ( OraSession )
        
        
        OraDatabase.Parameters.Remove "PKG_ID"
        OraDatabase.Parameters.Remove "PROD_VERSION"
        OraDatabase.Parameters.Remove "COMMENTS"
        OraDatabase.Parameters.Remove "OS_ID"
        OraDatabase.Parameters.Remove "USER_ID"
        
End Sub
'--------------------------------------------------------------------------------------------------------------------------
Sub AddProdToBaseEnv ()
        Dim aPkgIdList, PkgId, OraParameter
        
        On Error Resume Next
        objEH.ErrorRedirect = TRUE
        
        OraDatabase.Parameters.Add "PKG_ID",            0,                                                      ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "PROD_VERSION",      "",                                             ORAPARM_INPUT, ORATYPE_VARCHAR2
        OraDatabase.Parameters.Add "BASE_ENV_ID",       Request("base_env_id"),         ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "OS_ID",             Request("os_id"),                       ORAPARM_INPUT, ORATYPE_NUMBER   
        OraDatabase.Parameters.Add "USER_ID",           objAccessControl.UserId,        ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "COMMENTS",          NULL,                                           ORAPARM_INPUT, ORATYPE_VARCHAR2
        
        Set OraParameter = OraDatabase.Parameters
        
        objEH.TryORA ( OraSession )
        
        aPkgIdList = Split ( Replace ( Request("pkg_id_list"), " ", ""  ), "," )
        
        For Each PkgId In aPkgIdList
                
                OraParameter("PKG_ID").Value = PkgId
                OraParameter("PROD_VERSION").Value = Request("pkgid"& PkgId )
                OraParameter("COMMENTS").Value     = Request("comments"& PkgId )
                
                'Response.write OraParameter("PKG_ID").Value &"-"& OraParameter("PROD_VERSION").Value &"-"& OraParameter("BASE_ENV_ID").Value &"-"& OraParameter("USER_ID").Value &"|"& Request("pkgid"& PkgId ) &"<br>"
                
                OraDatabase.ExecuteSQL _
                "BEGIN   pk_Base_Env.Add_Product_Wrap ( :PKG_ID, :PROD_VERSION, :BASE_ENV_ID, :OS_ID , :USER_ID, :COMMENTS );   END;"
                
        Next
        
        '--- Log Action ---
        objEH.LogAction  _
        objAccessControl.UserId, _
        enumAT_EVENT_COMMENT, _
        "Sub AddProdToBaseEnv at BASE_ENV_ID="& Request("base_env_id"), _
        SCRIPT_NAME, _
        "Added Products to Base Configuration.", _
        OraDatabase
                
        objEH.CatchORA ( OraSession )
        
        
        OraDatabase.Parameters.Remove "PKG_ID"
        OraDatabase.Parameters.Remove "PROD_VERSION"
        OraDatabase.Parameters.Remove "BASE_ENV_ID"
        OraDatabase.Parameters.Remove "OS_ID"   
        OraDatabase.Parameters.Remove "USER_ID"
        OraDatabase.Parameters.Remove "COMMENTS"
        
End Sub
'--------------------------------------------------------------------------------------------------------------------------
%>
<%
'**************************** M  A  I  N ******************************

' --- Form is Valid ---
If Request("base_env_id") = "" Then
        Call AddProdToOs()
Else
        Call AddProdToBaseEnv()
End If


If objEH.Finally Then
        Call OpenInParentWindow ( Request("rfile") &"?ADDED=OK"& objPMod.ComposeURLWithout("rfile") )
        Call CloseWindow()
End If
'**********************************************************************
Call Destroy_All_Objects
%>