Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'
'   RequestBomDiffProductLocation.asp
'       This page is used by an AJAX call
'       It will return an html fragment
'=====================================================
%>
<%
Option explicit
Response.Expires = 0
%>
<!--#include file="common/globals.asp"-->
<!--#include file="common/config.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/_form_window_common.asp"-->
<%
'------------ VARIABLE DEFINITION -------------
Dim rsQry
Dim IsProductInNewBom
Dim bgColor
Dim QueryName
Dim parBomId
Dim rsPkg, pkgName, pkgVersion, pkgId
Dim rsProj, projName, branchName, projId
Dim rsOS, OSName
Dim objZIPObject
Dim mode
Dim pageOs
'------------ CONSTANTS DECLARATION -----------
'------------ VARIABLE INIT -------------------
parBomId = Request("bom_id")
pageOs = "OsDefault.asp"
mode = ""
If Request("Mode") <> "" Then
    mode = Request("Mode")
    mode="Base"
    pageOs = "Os_BaseConf.asp"
End If

'------------ RUN BEFORE PAGE RENDER ----------
If (Request("change_type") = "R") Then
    QueryName = "BomRemoved"+mode+"ProductLocation.sql"
    IsProductInNewBom = FALSE
    
ElseIf (Request("change_type") = "U") Then
    QueryName = "BomUpdated"+mode+"ProductLocation.sql"
    IsProductInNewBom = TRUE

Else
    QueryName = "BomAdded"+mode+"ProductLocation.sql"
    IsProductInNewBom = TRUE
    
End If

Call GetProjDetails ( parBomId, objFormCollector )
'----------------------------------------------
%>
        <table width="100%"  border="0" cellspacing="3" cellpadding="0">
          <%
          OraDatabase.Parameters.Add "BOM_ID",          Request("bom_id"),          ORAPARM_INPUT, ORATYPE_NUMBER 
          OraDatabase.Parameters.Add "COMPARE_BOM_ID",  Request("compare_bom_id"),  ORAPARM_INPUT, ORATYPE_NUMBER 
          OraDatabase.Parameters.Add "PROD_ID",         Request("prod_id"),         ORAPARM_INPUT, ORATYPE_NUMBER 
          OraDatabase.Parameters.Add "PKG_NAME",        Request("pkg_name"),        ORAPARM_INPUT, ORATYPE_VARCHAR2
          
          Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ( QueryName ), ORADYN_DEFAULT )
          
          bgColor = NULL
          
          If rsQry.RecordCount < 1 Then
          %>
          <tr>
            <td <%=bgColor%> nowrap valign="top" class="body_row" colspan="2">Product not found.
            </td>
          </tr>
          <%
          End If
          
          While (NOT rsQry.BOF) AND (NOT rsQry.EOF)
            
            If IsNull( bgColor ) Then
                bgColor = "bgcolor='#F5F5F5'"
            Else
                bgColor = NULL
            End If

            If Request("bom_id") <> "" AND Request("prod_id") <> "" Then

                Set rsPkg = OraDatabase.DbCreateDynaset( "select * from package_versions pv, packages pkg where pv.pv_id = "&Request("prod_id")&" and pkg.pkg_id = pv.pkg_id", cint(0))
    
                pkgName = rsPkg("pkg_name")
                pkgVersion = rsPkg("pkg_version")
                pkgId = rsPkg("pkg_id")
                
                rsPkg.Close()
                Set rsPkg = nothing
                
                Set rsProj = OraDatabase.DbCreateDynaset( "select br.branch_name, prj.proj_name, prj.proj_id from boms bm, branches br, dm_projects prj where bm.bom_id = "&Request("bom_id")&" and br.BRANCH_ID = bm.BRANCH_ID and prj.PROJ_ID = br.PROJ_ID", cint(0))
                
                projName = rsProj("proj_name")  
                branchName = rsProj("branch_name")
                projId = rsProj("proj_id")
                
                rsProj.Close()
                Set rsProj = nothing
                
                If rsQry("os_id") <> "" Then
                    Set rsOS = OraDatabase.DbCreateDynaset( "select bt.bos_type from os_base_env obe, base_env be, bos_types bt where obe.OS_ID = "&rsQry("os_id")&" and be.BASE_ENV_ID = obe.BASE_ENV_ID and bt.BOS_ID = be.BOS_ID", cint(0))
                    
                    OSName = rsOS("bos_type")
                    
                    If OSName = "Windows" OR OSName = "MOS" Then
                        OSName = "win32"
                    Else
                        OSName = "sparc"
                    End If  
                    
                    rsOS.Close()
                    Set rsOS = nothing
                Else
                    OSName = "Undefined"     
                End If     
                
            End If
          %>            
          
          <tr>
            <td <%=bgColor%> nowrap valign="top" class="body_row" colspan="2">&nbsp;&nbsp;&nbsp;&nbsp;
                <img hspace="4" src="icons/<%=rsQry("node_icon")%>" align="absmiddle" border="0">
                <%If rsQry("nodeExists") <> "" Then%>
                    <a href="NodeDefault.asp?node_id=<%=rsQry("node_id")%>&bom_id=<%=parBomId%>" class="body_link"><%=rsQry("node_name")%></a>
                <%Else%>
                    <span class="body_strike"><%=rsQry("node_name")%></span>
                <%End If%>
                &nbsp;/&nbsp;
                <%If rsQry("osExists") <> "" Then%>
                    <a href="<%=pageOs%>?os_id=<%=rsQry("os_id")%>&bom_id=<%=parBomId%>" class="body_link"><%=rsQry("os_name") %></a>
                <%Else%>
                    <span class="body_strike"><%=rsQry("os_name")%></span>
                <%End If%>
                &nbsp;/&nbsp;
            <%If IsProductInNewBom Then%>
                <a href="ProdDefault.asp?os_id=<%=rsQry("os_id")%>&prod_id=<%=rsQry("prod_id")%>&bom_id=<%=parBomId%>" class="body_link"><%=rsQry("pkg_name") &" "& rsQry("pkg_version")%></a>
            <%End If%>
            <%If NOT IsNull(objFormCollector.Item("is_download")) Then%>
                &nbsp;&nbsp;<a href="javascript:;" onClick="popup = window.open('LogDownload.asp?url=<%=release_archiveURL%><%=projName%>/<%=branchName%>/<%=pkgName%>/<%=OSName%>/<%=pkgName%>-<%=pkgVersion%>-<%=OSName%>.zip&pkg_id=<%=pkgId%>&pkg_version=<%=pkgVersion%>', 'Download       Version',       'height=440,width=600,scrollbars=yes,resizable=yes');   return  false"  target="_blank" class="body_link">Download      Version:        <%=Request("new_version")       %></a>&nbsp;&nbsp;
            <%End If%>
            </td>
          </tr>
          <%
            rsQry.MoveNext
          WEnd
          
          OraDatabase.Parameters.Remove "BOM_ID"
          OraDatabase.Parameters.Remove "PROD_ID"
          OraDatabase.Parameters.Remove "COMPARE_BOM_ID"
          OraDatabase.Parameters.Remove "PKG_NAME"
          
          rsQry.Close
          Set rsQry = Nothing
          %>
        </table>    
<!--#include file="common/globals_destructor.asp"-->