WebSVN – DevTools – /ManagerSuite/Deployment_Manager/trunk/web/BomStates.asp

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|                                BomStates                                      |
'|                                                   |
'=====================================================
%>
<%
Option explicit
Response.Expires = 0
%>
<!--#include file="common/globals.asp"-->
<!--#include file="common/config.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/_explorer_common.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_general.asp"-->
<%
'------------ VARIABLE DEFINITION -------------
Dim rsQry
Dim StateId, StateTypeEnum
Dim objFormCollector
'------------ CONSTANTS DECLARATION -----------
'------------ VARIABLE INIT -------------------
parBranch_id = Request("branch_id")
Set objFormCollector = CreateObject("Scripting.Dictionary")
'------------ CONDITIONS ----------------------
'----------------------------------------------
%>
<%
'--------------------------------------------------------------------------------------------------------------------------
Sub GetFormDetails ( nBranch_id, ByRef outobjDetails )
        Dim rsQry, query
        OraDatabase.Parameters.Add "BRANCH_ID", nBranch_id, ORAPARM_INPUT, ORATYPE_NUMBER 
        
        Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("BranchDetails.sql"), ORADYN_DEFAULT )
        
        If rsQry.RecordCount > 0 Then
                outobjDetails.Item ("branch_id")  = rsQry("branch_id")
                outobjDetails.Item ("branch_name")  = rsQry("branch_name").Value
                outobjDetails.Item ("proj_name")  = rsQry("proj_name").Value
                
        End If
        
        OraDatabase.Parameters.Remove "BRANCH_ID"
        
        rsQry.Close
        Set rsQry = Nothing
End Sub
'----------------------------------------------------------------------------------------------------------------------------------------------
Sub NewBOMList ( rsQry )
%>
        <table width="100%"  border="0" cellspacing="2" cellpadding="0">
          <tr>
            <td width="1"><img src="images/spacer.gif" width="20" height="1"></td>
            <td width="100%" nowrap class="body_scol">BOM Version</td>
            <td width="1" align="right" nowrap class="body_scol">Arrived</td>
          </tr>
          <tr>
            <td background="images/bg_bage_1.gif"><img src="images/spacer.gif" width="1" height="1"></td>
                <td background="images/bg_bage_1.gif"><img src="images/spacer.gif" width="165" height="1"></td>
                <td background="images/bg_bage_1.gif"><img src="images/spacer.gif" width="1" height="1"></td>
          </tr>
          <%rsQry.MoveNext%>
          <%If ((NOT rsQry.BOF) AND (NOT rsQry.EOF)) Then%>
                  <%
                  If (NOT IsNull(rsQry("bom_id"))) Then
                          Dim RowColor
                          RowColor = NULL
                          
                          While ((NOT rsQry.BOF) AND (NOT rsQry.EOF) AND (NOT IsNull(rsQry("bom_id"))))
                                
                                If IsNull( RowColor ) Then
                                        RowColor = "bgcolor='#F5F5F5'"
                                Else
                                        RowColor = NULL
                                End If
                  %>
                  <tr>
                    <td <%=RowColor%>><input type="checkbox" name="bom_id_list" value="<%=rsQry("bom_id")%>"></td>
                    <td <%=RowColor%> nowrap><a href="Bom_Home.asp?bom_id=<%=rsQry("bom_id")%>" class="menu_link"><%=BomIcon( rsQry("is_readonly"), rsQry("is_rejected") )%><%=rsQry("bom_name").Value &" "& rsQry("bom_version") &"."& rsQry("bom_lifecycle")%></a></td>
                    <td <%=RowColor%> align="left" nowrap class="body_txt">&nbsp;<%=objFormater.FormatDate ( rsQry("date_stamp"), 1 ) %></td>
                  </tr>

                  <%
                                rsQry.MoveNext
                          WEnd
                          
                  End If
                  
                  rsQry.MovePrevious
                  %>
          <%Else
                        rsQry.MovePrevious
          %>
          <%End If%>
          <tr>
            <td background="images/bg_bage_1.gif"><img src="images/spacer.gif" width="1" height="1"></td>
                <td background="images/bg_bage_1.gif"><img src="images/spacer.gif" width="1" height="1"></td>
                <td background="images/bg_bage_1.gif"><img src="images/spacer.gif" width="1" height="1"></td>
          </tr>
        </table>
<%
End Sub
'----------------------------------------------------------------------------------------------------------------------------------------------
Sub NewState ( rsQry )
%>
        <td valign="top">
                <table width="100%"  border="0" cellspacing="0" cellpadding="2">
                  <tr>
                    <td class="body_txt"><b><%=rsQry("state_name").Value%></b></td>
                  </tr>
                </table>
                <table width="100%"  border="0" cellspacing="0" cellpadding="0">
                  <form name="FormState<%=StateId%>" method="post" action="<%=SCRIPT_NAME%>">
                  <tr>
                    <td width="1"><img src="images/spacer.gif" width="10" height="1"></td>
                    <td width="1" background="images/bg_bage_2.gif"><img src="images/spacer.gif" width="1" height="1"></td>
                    <td width="100%" valign="top">
                        <%
                        '-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-
                        'objAccessControl.BeginRegion ( "SomeName" )
                        %>
                      <table width="100%"  border="0" cellspacing="0" cellpadding="0">
                        <tr>
                          <td width="1" valign="top"><img src="<%=GetStateImage( StateTypeEnum )%>"></td>
                          <!-- OPTIONS ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
                                  <!--#include file="_state_menu_options.asp"-->
                          <!-- OPTIONS END ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
                          </td>
                        </tr>
              </table>
                        <%
                        'objAccessControl.EndRegion ( "SomeName" )
                        '-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-ACCESSMANAGER-
                        %>
                    <%Call NewBOMList( rsQry )%>
                        &nbsp;<a href="StateExplorer.asp?state_id=<%=StateId%>&<%=objPMod.ComposeURL()%>" class="body_linkdb">More...</a>
                    </td>
                  </tr>
                  <%=objPMod.ComposeHiddenTags()%>
                  <input type="hidden" name="state_id" value="<%=StateId%>">
                  <input type="hidden" name="action" value="true">
                  </form>
                </table>
        </td>
<%
End Sub
'----------------------------------------------------------------------------------------------------------------------------------------------
%>
<%
'------------ RUN BEFORE PAGE RENDER ----------
Call GetFormDetails ( parBranch_id, objFormCollector )

If (Request("action") <> "") Then
        '-- Select Action
        Call ActionRedirection ( Request("action") )
        
End If
'----------------------------------------------
%>
<html>
<head>
<title>Deployment Manager</title>
<link rel="shortcut icon" href="<%=FavIcon%>"/>
<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link href="scripts/deployment_manager.css?ver=<%=VixVerNum%>" rel="stylesheet" type="text/css">
<script language="JavaScript" src="scripts/common.js?ver=<%=VixVerNum%>"></script>
</head>

<body leftmargin="0" topmargin="0">
<!-- HEADER ++++++++++++++++ -->
<!--#include file="_header.asp"-->
<!-- +++++++++++++++++++++++ -->
<!-- MAIN MENU  +  CRUMBS ++++++++++++++++ -->
<!--#include file="_main_menu.asp"-->
<!-- +++++++++++++++++++++++++++++++++++++ -->
<table width="100%"  border="0" cellspacing="0" cellpadding="0">
  <tr>
    <td width="1%" background="images/bg_bage_1.gif"><img src="images/spacer.gif" width="1" height="1"></td>
    <td width="100%" background="images/bg_bage_1.gif"><img src="images/spacer.gif" width="1" height="1"></td>
  </tr>
  <tr>
    <td background="images/bg_bage_0.gif"><img src="images/spacer.gif" width="17" height="30"></td>
    <td background="images/bg_bage_0.gif">
        <!-- BUTTONS CONTROL +++++++++++++++++++ -->
        <!-- +++++++++++++++++++++++++++++++++++ -->
        </td>
  </tr>
  <tr>
    <td background="images/bg_bage_1.gif"><img src="images/spacer.gif" width="1" height="1"></td>
    <td background="images/bg_bage_1.gif"><img src="images/spacer.gif" width="1" height="1"></td>
  </tr>
  <tr>
    <td><img src="images/spacer.gif" width="1" height="1"></td>
    <td><img src="images/spacer.gif" width="1" height="8"></td>
  </tr>
  <tr>
    <td>&nbsp;</td>
    <td class="body_ttl1">Release Explorer</td>
  </tr>
  <tr>
    <td><img src="images/spacer.gif" width="1" height="1"></td>
    <td><img src="images/spacer.gif" width="1" height="30"><a href="Default.asp?BACK=OK<%=objPMod.ComposeURLWithout("branch_id")%>" class="body_link"><img src="icons/i_caretone.gif" width="11" height="7" hspace="2" border="0"><%=objFormCollector.Item("proj_name")%></a></td>
  </tr>
</table>
<table width="100%"  border="0" cellspacing="0" cellpadding="0">
  <tr>
    <td width="1%">&nbsp;</td>
    <td width="100%" rowspan="2" valign="top">
        <!-- PAGE DETAILS ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
        
        <!-- STATES ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
         <%If (dbPARproj_id <> enumDB_DEFAULT_EMPTY) AND (dbPARbranch_id <> enumDB_DEFAULT_EMPTY) Then%>
         <table width="10"  border="0" cellspacing="0" cellpadding="0">
      <tr>
                <%
                OraDatabase.Parameters.Add "PROJ_ID",   dbPARproj_id,           ORAPARM_INPUT, ORATYPE_NUMBER 
                OraDatabase.Parameters.Add "BRANCH_ID", dbPARbranch_id,         ORAPARM_INPUT, ORATYPE_NUMBER 
                Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("BomStatesMain.sql") , ORADYN_DEFAULT )
                Dim tempCnt
                tempCnt = 0
                
                While ((NOT rsQry.BOF) AND (NOT rsQry.EOF) AND (tempCnt < 50))
                        StateId = rsQry("state_id")
                        StateTypeEnum = rsQry("state_type_enum")
                        
                        Call NewState ( rsQry )
                        
                        rsQry.MoveNext
                        tempCnt = tempCnt + 1
                WEnd
                
                'Response.write tempCnt
                rsQry.Close
                Set rsQry = Nothing
                OraDatabase.Parameters.Remove "PROJ_ID"
                OraDatabase.Parameters.Remove "BRANCH_ID"
                %>

      </tr>
    </table>
        <%End If%>
        <!-- STATES END +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
        <br><br>
        <!-- PAGE DETAILS END ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
        </td>
  </tr>
  <tr>
    <td valign="bottom"><img src="images/ill_bom_location.jpg" width="146" height="300"></td>
  </tr>
</table>

<table width="100%"  border="0" cellspacing="0" cellpadding="0">
  <tr>
    <td><img src="images/spacer.gif" width="8" height="20"></td>
  </tr>
</table>
<!-- FOOTER ++++++++++++++++ -->
<!--#include file="_footer.asp"-->
<!-- +++++++++++++++++++++++ -->
</body>
</html>
Subversion Repositories DevTools

(root)/ManagerSuite/Deployment_Manager/trunk/web/BomStates.asp – Rev 6663
