Subversion Repositories DevTools

Rev

Rev 13 | Blame | Compare with Previous | Last modification | View Log | RSS feed 

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|                                NewBom                                                 |
'|                                                   |
'=====================================================
%>
<%
Option explicit
Response.Expires = 0
%>
<!--#include file="common/globals.asp"-->
<!--#include file="common/config.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/_form_window_common.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_general.asp"-->
<%
'------------ VARIABLE DEFINITION -------------
Dim rsQry
Dim isSelectDisabled
'------------ CONSTANTS DECLARATION -----------
Const enumBOM_EDITMODE  = "<img src='icons/bi_edit.gif' width='20' height='16' border='0' align='absmiddle' hspace='5' vspace='3' title='BOM is in edit mode.'>"
Const enumBOM_NEW       = "<img src='icons/bi_new.gif' width='20' height='16' border='0' align='absmiddle' hspace='5' vspace='3' title='New BOM available.'>"
Const enumBOM_ACCEPTED  = "<img src='icons/bi_accepted.gif' width='20' height='16' border='0' align='absmiddle' hspace='5' vspace='3' title='BOM is tested and Accepted.'>"
Const enumBOM_REJECTED  = "<img src='icons/bi_rejected.gif' width='20' height='16' border='0' align='absmiddle' hspace='5' vspace='3' title='BOM is tested and Rejected.'>"
'------------ VARIABLE INIT -------------------
parProj_id = Request("proj_id")
parBranch_id = Request("branch_id")
'------------ CONDITIONS ----------------------
'----------------------------------------------
%>
<%
'--------------------------------------------------------------------------------------------------------------------------
Sub GetRecentBoms ( nBranch_id )
        Dim rsQry, query
        OraDatabase.Parameters.Add "BRANCH_ID",         nBranch_id,             ORAPARM_INPUT, ORATYPE_NUMBER 
        
        Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("RecentBomsInBranch.sql"), ORADYN_DEFAULT )
        If rsQry.RecordCount < 1 Then
                Response.write "There are no recent BOMs found."
        End If
        
        While (NOT rsQry.BOF) AND (NOT rsQry.EOF)
                Response.write "<a href='AddBomFrom.asp?from_bom_id="& rsQry("bom_id") &"&"& objPMod.ComposeURL() &"' class='menu_link'>"&_
                                            BomIcon( rsQry("is_readonly"), rsQry("is_rejected") ) & rsQry("bom_name").Value &" "& rsQry("bom_version") &"."& rsQry("bom_lifecycle") &"</a><br>"
                rsQry.MoveNext
        WEnd
        
        OraDatabase.Parameters.Remove "BRANCH_ID"
        
        rsQry.Close
        Set rsQry = Nothing
End Sub
'--------------------------------------------------------------------------------------------------------------------------
Function GetProjectList ( nProjId )
        Dim rsQry, Selected, aComboItems, lastItem, i
        
        OraDatabase.Parameters.Add "PROJ_ID", nProjId,  ORAPARM_INPUT, ORATYPE_NUMBER
        
        Set rsQry = OraDatabase.DbCreateDynaset( GetQuery("ProjectsCombo.sql"), ORADYN_DEFAULT )
        
        If ((NOT rsQry.BOF) AND (NOT rsQry.EOF)) Then
                aComboItems = rsQry.GetRows()
                
        Else
                Err.Raise 8, "Sub GetProjectList", "Empty record set returned. nProjId="& nProjId
                
        End If
        
        OraDatabase.Parameters.Remove "PROJ_ID"
        
        rsQry.Close
        Set rsQry = Nothing
        
        
        '-- Alter combo item link column to work with OnChange javascript
        lastItem = Ubound( aComboItems, 2 )
        For i = 0 To lastItem
                aComboItems(0, i) = SCRIPT_NAME &"?from_proj_id="& aComboItems(0, i) &"&"& objPMod.ComposeURL()
        Next
        
        
        '-- Return Combo Items Array
        GetProjectList = aComboItems
        
End Function
'--------------------------------------------------------------------------------------------------------------------------
Function GetBranchList ( nProjId, nBranch_id )
        Dim rsQry, Selected, aComboItems, lastItem, i
        
        
        OraDatabase.Parameters.Add "PROJ_ID", nProjId,  ORAPARM_INPUT, ORATYPE_NUMBER
        OraDatabase.Parameters.Add "BRANCH_ID", nBranch_id,     ORAPARM_INPUT, ORATYPE_NUMBER
        
        Set rsQry = OraDatabase.DbCreateDynaset( GetQuery("BranchesCombo.sql"), ORADYN_DEFAULT )
        
        If ((NOT rsQry.BOF) AND (NOT rsQry.EOF)) Then
                aComboItems = rsQry.GetRows()
                
        End If
        
        OraDatabase.Parameters.Remove "PROJ_ID"
        OraDatabase.Parameters.Remove "BRANCH_ID"
        
        rsQry.Close
        Set rsQry = Nothing
        
        If IsArray(aComboItems) Then
                '-- Alter combo item link column to work with OnChange javascript
                lastItem = Ubound( aComboItems, 2 )
                For i = 0 To lastItem
                        aComboItems(0, i) = SCRIPT_NAME &"?from_proj_id="& nProjId &"&from_branch_id="& aComboItems(0, i) &"&"& objPMod.ComposeURL()
                Next
        End If
        
        
        '-- Return Combo Items Array
        GetBranchList = aComboItems
        
End Function
'--------------------------------------------------------------------------------------------------------------------------
Function GetBomList ( nProjId, nBranch_id )
        Dim rsQry, Selected, aComboItems, lastItem, i
        
        
        OraDatabase.Parameters.Add "PROJ_ID", nProjId,  ORAPARM_INPUT, ORATYPE_NUMBER
        OraDatabase.Parameters.Add "BRANCH_ID", nBranch_id,     ORAPARM_INPUT, ORATYPE_NUMBER
        OraDatabase.Parameters.Add "BOM_ID", 0, ORAPARM_INPUT, ORATYPE_NUMBER
        
        Set rsQry = OraDatabase.DbCreateDynaset( GetQuery("BomsCombo.sql"), ORADYN_DEFAULT )
        
        If ((NOT rsQry.BOF) AND (NOT rsQry.EOF)) Then
                GetBomList = rsQry.GetRows()
                
        End If
        
        OraDatabase.Parameters.Remove "PROJ_ID"
        OraDatabase.Parameters.Remove "BRANCH_ID"
        OraDatabase.Parameters.Remove "BOM_ID"
        
        rsQry.Close
        Set rsQry = Nothing
End Function
'--------------------------------------------------------------------------------------------------------------------------
%>
<%
'------------ RUN BEFORE PAGE RENDER ----------
'-- Redirect if known from_bom_id
If Request("bom_id_list") <> "" Then
        Call OpenInWindow ( "AddBomFrom.asp?from_bom_id="& Request("bom_id_list") &"&"& objPMod.ComposeURL() )
End If

'----------------------------------------------
%>
<html>
<head>
<title>Deployment Manager</title>
<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link href="scripts/deployment_manager.css" rel="stylesheet" type="text/css">
<script language="JavaScript" src="scripts/common.js"></script>

</head>
<body background="images/bg_lite_blue.gif" leftmargin="0" topmargin="0">
<!-- HEADER ++++++++++++++++ -->
<!--#include file="_header.asp"-->
<!-- +++++++++++++++++++++++ -->
<table width="100%"  border="0" cellspacing="0" cellpadding="0">
<%
'-- FROM START ---------------------------------------------------------------------------------------------------------
objFormComponent.FormName = "FormName"
objFormComponent.Action = "AddBomFrom.asp"
Call objFormComponent.FormStart()
%>
  <tr>
    <td bgcolor="#FFFFFF"><img src="images/spacer.gif" width="1" height="42"></td>
  </tr>
  <tr>
    <td align="center" valign="middle" bgcolor="#FFFFFF">
        <!-- FROM ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
    <table width="600" border="0" cellspacing="0" cellpadding="1">
        <tr>
          <td background="images/bg_bage_2.gif"><table width="100%"  border="0" cellspacing="0" cellpadding="0">
            <tr>
              <td bgcolor="#FFFFFF"><table width="100%"  border="0" cellspacing="0" cellpadding="10">
                <tr>
                                  <td bgcolor="#FFFFFF" class="body_txt"><span class="body_h1"><img src='icons/bi_new.gif' width='20' height='16' border='0' align='absmiddle' hspace='2'>New BOM </span> <br>
                                  Create New Bill of Materials (BOM) by selecting available options below.</td>
                                </tr>
                <tr>
                                 <td background="images/bg_bage_0.gif">
                                  <table width="100%"  border="0" cellspacing="10" cellpadding="0">
                                            <tr>
                                              <td width="33%" valign="top" class="body_txt">
                                                <strong>Create New</strong><br>
                                                <a href="AddBlankBom.asp?NEXT=OK&<%=objPMod.ComposeURL()%>" class="menu_link"><img src="icons/bi_new.gif" width="20" height="16" hspace="5" vspace="3" border="0" align="absmiddle">Blank </a><br><br>
                                                </td>
                                              <td width="1" background="images/bg_bage_2.gif"><img src="images/spacer.gif" width="1" height="250"></td>
                                              <td nowrap width="34%" valign="top" class="body_txt">
                                                <strong>Create from Recent </strong><br>
                                                <%Call GetRecentBoms ( parBranch_id )%>
                                        </td>
                                        <td width="1" background="images/bg_bage_2.gif"><img src="images/spacer.gif" width="1" height="1"></td>
                                        <td width="33%" valign="top" class="body_txt" nowrap>
                                                <strong>Create From Other</strong><br><br>
                                                <%=objFormComponent.Combo ( "from_proj_id", GetProjectList( Request("from_proj_id") ), TRUE, "class='form_ivalue' onChange=""MM_jumpMenu('parent',this,0)"" " )%><br>
                                                <%
                                                If Request("from_proj_id") <> "" Then 
                                                        Response.write objFormComponent.Combo ( "from_branch_id", GetBranchList( Request("from_proj_id"), Request("from_branch_id") ), TRUE, "class='form_ivalue' onChange=""MM_jumpMenu('parent',this,0)"" " )
                                                        Response.write "<br>"
                                                End If
                                                %>
                                                <%
                                                isSelectDisabled = "disabled"
                                                If Request("from_branch_id") <> "" Then 
                                                        Response.write objFormComponent.Combo ( "from_bom_id", GetBomList( Request("from_proj_id"), Request("from_branch_id") ), FALSE, "class='form_ivalue' " )
                                                        Response.write "<br>"
                                                        isSelectDisabled = ""
                                                End If
                                                %>
                                                <%=objFormComponent.SubmitButton ( "Select", "class='form_ivalue' "& isSelectDisabled )%>
                                        </td>
                                    </tr>
                                  </table>      
                                 </td>
                                </tr>
                                <tr>
                                  <td background="images/bg_login.gif"><table width="100%"  border="0" cellspacing="0" cellpadding="0">
                      <tr>
                        <td></td>
                        <td align="right">
                                                <%=objFormComponent.CancelButton ( "Cancel", "class='form_btn'", Request("rfile") &"?CANCEL=OK"& objPMod.ComposeURLWithout("rfile") )%></td>
                      </tr>
                  </table></td>
                                </tr>
                <%=objPMod.ComposeHiddenTags()%>
              </table></td>
            </tr>
          </table></td>
        </tr>
      </table>
          <!-- ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->   </td>
  </tr>
  <tr>
    <td bgcolor="#FFFFFF"><img src="images/spacer.gif" width="1" height="42"></td>
  </tr>
<%
Call objFormComponent.FormEnd()
'-- FROM END ----------------------------------------------------------------------------------------------------------------
%>      
</table>
<!-- FOOTER ++++++++++++++++++++++ -->
<!--#include file="_footer.asp"-->
<!-- +++++++++++++++++++++++++++++ -->
</body>
</html>
<%
'------------ RUN AFTER PAGE RENDER -----------
Set objPMod = Nothing
'----------------------------------------------
%>
<!--#include file="common/globals_destructor.asp"-->