Subversion Repositories DevTools

<%
'===================================================================
'                                                       User Common
'===================================================================
%>
<!--#include file="../class/classTemplateManager.asp"-->
<!--#include file="../class/classTabControl.asp"-->
<!--#include file="../class/classActionButtonControl.asp"-->
<%
'------------ VARIABLE DEFINITION -------------
Dim parApp_id
Dim parUser_id
Dim objUserCollector
Dim objBtnControl
Dim aTabBtnsDef
'------------ CONSTANTS DECLARATION -----------
Const PARENT_TITLE = "User Accounts"
Const LIMG_ROLE = "<img src='images/i_role.gif' width='16' height='16' hspace='2' border='0' align='absmiddle'>"
Const LIMG_SPEC_ROLE = "<img src='images/i_spec_role.gif' width='16' height='16' hspace='2' border='0' align='absmiddle'>"
Const LIMG_DRILL_DOWN = "<img src='images/i_drill_down.gif' width='12' hspace='2' height='14' border='0'>"
Const LIMG_CONTROL = "<img src='images/i_control.gif' width='16' height='16' hspace='2' border='0' align='absmiddle'>"
Const LIMG_USER_LRG = "<img src='images/i_user_lrg.gif' width='13' height='17' hspace='2' border='0' align='absmiddle'>"
Const LIMG_USER_DISABLED_LRG = "<img src='images/i_user_disabled_lrg.gif' width='17' height='18' hspace='2' border='0' align='absmiddle'>"
Const LIMG_USER = "<img src='images/i_user.gif' width='16' height='16' hspace='2' border='0' align='absmiddle'>"
Const LIMG_USER_DISABLED = "<img src='images/i_user_disabled.gif' width='16' height='16' hspace='2' border='0' align='absmiddle'>"
Const LIMG_DISK = "<img src='images/i_disk.gif' width='16' height='16' hspace='4' border='0' align='absmiddle'>"
Const LIMG_EDIT = "<img src='images/i_edit_no_border.gif' width='16' height='16' hspace='2' border='0' align='absmiddle'>"
Const LIMG_REMOVE = "<img src='images/i_remove_no_border.gif' width='16' height='16' hspace='2' border='0' align='absmiddle'>"
Const LIMG_DATA_TABLE = "<img src='images/i_data_table.gif' hspace='2' border='0' align='absmiddle' title='See this Control Data Filter (Filter is ON)'>"
Const LIMG_DATA_TABLE_OFF = "<img src='images/i_data_table_off.gif' hspace='2' border='0' align='absmiddle' title='See this Control Data Filter (Filter is OFF)'>"
Const LMINUTES_SINCE_LAST_REQUEST = 20 'minutes
'------------ VARIABLE INIT -------------------
parUser_id = Request("user_id")
parApp_id = Request("app_id")
Set objUserCollector = CreateObject("Scripting.Dictionary")
Set objBtnControl = New ActionButtonControl
'------------ CONDITIONS ----------------------
'----------------------------------------------
%>
<%
'------------ RUN BEFORE PAGE RENDER ----------
objPMod.PersistInQryString ("user_id")
objPMod.PersistInQryString ("app_id")
objPMod.PersistInQryString ("tree")
'----------------------------------------------
%>
<%
'-----------------------------------------------------------------------------------------------------------------
Sub GetUserDetails ( nUser_id, ByRef outobjDetails )
        Dim rsQry, query
        query = "SELECT *  FROM   USERS  WHERE user_id = "& nUser_id
        
        Set rsQry = OraDatabase.DbCreateDynaset( query , ORADYN_DEFAULT )
        
        If ((NOT rsQry.BOF) AND (NOT rsQry.EOF)) Then
                outobjDetails.Item ("user_id")   = rsQry("user_id")
                outobjDetails.Item ("full_name") = rsQry("full_name")
                outobjDetails.Item ("user_name") = rsQry("user_name")
                outobjDetails.Item ("domain") = rsQry("domain")
                outobjDetails.Item ("is_disabled") = rsQry("is_disabled")
                outobjDetails.Item ("user_email") = rsQry("user_email")         
                
        Else
                Err.Raise 8, "Sub GetUserDetails", "Empty record set returned. nUser_id="& nUser_id
                
        End If
        
        rsQry.Close
        Set rsQry = Nothing
End Sub
'-----------------------------------------------------------------------------------------------------------------
Sub RenderTitle ( objCollector )
        If objCollector.Item("is_disabled") = enumDB_YES Then
                Response.write LIMG_USER_DISABLED_LRG
        Else
                Response.write LIMG_USER_LRG
        End If
        
        Response.write "<b>"& objCollector.Item("full_name") &" ["& objCollector.Item("user_name") &"]</b>"
        
End Sub
'--------------------------------------------------------------------------------------------------------------------------
Function UserOnlineIcon ( sUserOnlineIcon, nLastRequest )
        If NOT IsNull( sUserOnlineIcon ) Then
                
                If NOT IsNull( nLastRequest ) Then
                        
                        
                        If (TIMER_VALUE - nLastRequest) < LMINUTES_SINCE_LAST_REQUEST Then
                                ' User is still online
                                UserOnlineIcon = sUserOnlineIcon
                        Else
                                ' User has not responded within MINUTES_SINCE_LAST_REQUEST
                                UserOnlineIcon = NULL
                        End If
                        
                Else
                        UserOnlineIcon = sUserOnlineIcon
                End If
                
        Else
                UserOnlineIcon = NULL
        End If
End Function
'--------------------------------------------------------------------------------------------------------------------------
Function LastRequest ( nLastRequest )
        Dim minDiff
        
        If NOT IsNull( nLastRequest ) Then
                minDiff = TIMER_VALUE - nLastRequest
                
                If minDiff < 60 Then
                        ' Show in Minutes
                        LastRequest =  minDiff &" minutes ago"
                        
                ElseIf minDiff < 1440 Then
                        ' Show in Hours
                        LastRequest =  (minDiff \ 60) &" hours ago"
                        
                ElseIf minDiff < 43800 Then
                        ' Show in Days
                        LastRequest =  (minDiff \ 1440) &" days ago"
                        
                ElseIf minDiff < 525600 Then
                        ' Show in Months
                        LastRequest =  (minDiff \ 43800) &" months ago"
                        
                Else
                        ' Show in Years
                        LastRequest =  (minDiff \ 525600) &" years ago"
                        
                End If
                
        Else
                LastRequest = NULL
        End If
End Function
'--------------------------------------------------------------------------------------------------------------------------
'-----------------------------------------------------------------------------------------------------------------
%>