Subversion Repositories DevTools

<%
'===================================================================
'                                                       Role Common
'===================================================================
%>
<!--#include file="../class/classTemplateManager.asp"-->
<!--#include file="../class/classTabControl.asp"-->
<!--#include file="../class/classActionButtonControl.asp"-->
<!--#include file="../class/classRepeater.asp"-->
<%
'------------ VARIABLE DEFINITION -------------
Dim parApp_id
Dim parRole_id
Dim objRoleCollector
Dim objBtnControl
Dim aTabBtnsDef
Dim objRepeater
'------------ CONSTANTS DECLARATION -----------
Const PARENT_TITLE = "Role"
'------------ VARIABLE INIT -------------------
parRole_id = Request("role_id")
parApp_id = Request("app_id")
Set objBtnControl = New ActionButtonControl
Set objRepeater = New Repeater
Set objRoleCollector = CreateObject("Scripting.Dictionary")
'------------ CONDITIONS ----------------------
'----------------------------------------------
%>
<%
'------------ RUN BEFORE PAGE RENDER ----------
objPMod.PersistInQryString ("role_id")
objPMod.PersistInQryString ("app_id")
objPMod.PersistInQryString ("tree")
'----------------------------------------------
%>
<%
'-----------------------------------------------------------------------------------------------------------------
Sub GetRoleDetails ( nRole_id, nApp_id, ByRef outobjDetails )
        Dim rsQry, query
        query = "SELECT *  FROM   ROLES  WHERE role_id = "& nRole_id &" AND app_id = "& nApp_id
        
        Set rsQry = OraDatabase.DbCreateDynaset( query , ORADYN_DEFAULT )
        
        If ((NOT rsQry.BOF) AND (NOT rsQry.EOF)) Then
                outobjDetails.Item ("role_id")   = rsQry("role_id")
                outobjDetails.Item ("role_name") = rsQry("role_name")
                outobjDetails.Item ("role_comments") = rsQry("comments")
                outobjDetails.Item ("is_role_variation") = rsQry("is_role_variation")
                
        Else
                Err.Raise 8, "Sub GetRoleDetails", "Empty record set returned. nRole_id="& nRole_id &", nApp_id="& nApp_id
                
        End If
        
        rsQry.Close
        Set rsQry = Nothing
End Sub
'-----------------------------------------------------------------------------------------------------------------
Sub RenderTitle ( objCollector )
        If IsNull(objCollector.Item("is_role_variation")) Then
                Response.write LIMG_ROLE_LRG
        Else
                Response.write LIMG_SPEC_ROLE_LRG
        End If
        Response.write "<b>"& objCollector.Item("role_name") &"</b>"
End Sub
'-----------------------------------------------------------------------------------------------------------------
%>