Subversion Repositories DevTools

Rev

Rev 2 | Blame | Compare with Previous | Last modification | View Log | RSS feed 

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|                                wAddApplicationUser                    |
'|                                                   |
'=====================================================
%>
<%
Option explicit
Response.Expires = 0
%>
<!--#include file="common/globals.asp"-->
<!--#include file="common/config.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/_popup_window_common.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_general.asp"-->
<%
'------------ VARIABLE DEFINITION -------------
Dim rsUser
Dim objFormCollector
'------------ CONSTANTS DECLARATION -----------
Const LIMG_USER = "<img src='images/i_user.gif' width='16' height='16' hspace='2' border='0' align='absmiddle'>"
Const LIMG_USER_DISABLED = "<img src='images/i_user_disabled.gif' width='16' height='16' hspace='2' border='0' align='absmiddle'>"
Const LIMG_ROLE = "<img src='images/i_role.gif' width='16' height='16' hspace='2' border='0' align='absmiddle'>"
'------------ VARIABLE INIT -------------------
Set objFormCollector = CreateObject("Scripting.Dictionary")
'------------ CONDITIONS ----------------------
'----------------------------------------------
%>
<%
'--------------------------------------------------------------------------------------------------------------------------
Sub AddApplicationUser ()
        On Error Resume Next
        
        OraDatabase.Parameters.Add "USER_ID_LIST",              Request("user_id_list"),        ORAPARM_INPUT, ORATYPE_VARCHAR2
        OraDatabase.Parameters.Add "APP_ID",                    Request("app_id"),                      ORAPARM_INPUT, ORATYPE_NUMBER
        OraDatabase.Parameters.Add "INCLUDE_EVERYONE",  Request("everyone"),            ORAPARM_INPUT, ORATYPE_CHAR
        
        
        objEH.TryORA ( OraSession )
        
        OraDatabase.ExecuteSQL _
        "BEGIN pk_User.Add_Application_User ( :USER_ID_LIST, :APP_ID, :INCLUDE_EVERYONE ); END;"        
        
        objEH.CatchORA ( OraSession )
        
        
        OraDatabase.Parameters.Remove "USER_ID_LIST"
        OraDatabase.Parameters.Remove "APP_ID"
        OraDatabase.Parameters.Remove "INCLUDE_EVERYONE"
        
End Sub
'--------------------------------------------------------------------------------------------------------------------------
%>
<%
'------------ RUN BEFORE PAGE RENDER ----------
' --- Get Form details from DB (for edit forms only) ---
'-------------------------------------------------------

' --- Load Validation Rules ---


' --- Enter Form Validation Rule Changes here... ----
'----------------------------------------------------

If CBool(Request("action")) Then
        If objForm.IsValidOnPostBack Then
                ' --- Form is Valid ---
                Call AddApplicationUser()
                
                If objEH.Finally Then
                        Call OpenInParentWindow ( Request("rfile") &"?"& objPMod.ComposeURL() )
                        Call CloseWindow()
                End If
                
        End If
End If
'----------------------------------------------
%>
<html>
<head>
<title>Access Manager</title>
<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link href="scripts/access_manager.css" rel="stylesheet" type="text/css">
<script language="JavaScript" src="scripts/common.js"></script>
</head>

<body bgcolor="#FFFFFF" leftmargin="0" topmargin="0" onLoad="self.focus();">
<table width="100%"  border="0" cellspacing="0" cellpadding="10">
  <tr>
    <td bgcolor="#FFFFFF" class="body_txt"><span class="body_h1"><img src="images/i_user_lrg.gif" width="13" height="17" hspace="0" align="absmiddle">&nbsp;Add User </span> <br>
    Search for User or select from the list. </td>
  </tr>
  <form name="FormSearch" method="post" action="<%=SCRIPT_NAME%>">
  <tr>
    <td background="images/bg_quicksearch.gif" class="body_txt"><table width="100" border="0" cellspacing="3" cellpadding="0">
        <tr>
          <td nowrap class="body_txtw"><strong>User Search</strong> </td>
          <td><input name="filter" type="text" class="body_txt" size="20" value="<%=Request("filter")%>"></td>
          <td><input name="btn" type="image" src="images/b_search.gif" width="16" height="16" border="0"></td>
        </tr>
      </table></td>
  </tr>
  <%=objPMod.ComposeHiddenTags()%>
  </form>
  <form name="FormName" method="post" action="<%=SCRIPT_NAME%>">
  <tr>
    <td background="images/bg_drk_bage_pane.gif">
        <table width="100%"  border="0" cellspacing="0" cellpadding="0">
      <tr>
        <td>&nbsp;</td>
        <td align="right"><input name="btn" type="submit" class="form_btn" value="Add">
          <input name="btn" type="reset" class="form_btn" value="Cancel" onClick="self.close();"></td>
      </tr>
    </table></td>
  </tr>
  <tr>
    <td>

                <table width="300"  border="0" cellspacing="2" cellpadding="0">
          <!-- MESSAGE +++++++++++++++++++++++++++++++++++++++++++++++++++ -->
          <%If NOT objEH.Finally Then%>
          <tr>
            <td>
              <%objEH.DisplayMessage()%>
            </td>
          </tr>
          <%End If%>
          <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
        </table>
                
<%
                Dim startPosition, pageNumber, navigator, totalRecords, lastRecord
                Const MAX_ROWS = 50     ' Maximum number of rows displayed
                
                OraDatabase.Parameters.Add "APP_ID",                    Request("app_id"),                      ORAPARM_INPUT, ORATYPE_NUMBER
                
                '--- Set filters ---
                If Request("filter") <> "" Then
                        OraDatabase.Parameters.Add "FULL_NAME",         "%"& Request("filter") &"%",    ORAPARM_INPUT, ORATYPE_VARCHAR2
                        OraDatabase.Parameters.Add "USER_NAME",         Request("filter") &"%",                 ORAPARM_INPUT, ORATYPE_VARCHAR2
                        OraDatabase.Parameters.Add "DOMAIN_NAME",       Request("filter") &"%",                 ORAPARM_INPUT, ORATYPE_VARCHAR2
                Else
                        OraDatabase.Parameters.Add "FULL_NAME",         NULL,   ORAPARM_INPUT, ORATYPE_VARCHAR2
                        OraDatabase.Parameters.Add "USER_NAME",         NULL,   ORAPARM_INPUT, ORATYPE_VARCHAR2
                        OraDatabase.Parameters.Add "DOMAIN_NAME",       NULL,   ORAPARM_INPUT, ORATYPE_VARCHAR2
                End If
                
                
                Set rsUser = OraDatabase.DbCreateDynaset( GetQuery ("GetApplicationUserList.sql") , ORADYN_DEFAULT )
                
                OraDatabase.Parameters.Remove "APP_ID"
                OraDatabase.Parameters.Remove "FULL_NAME"
                OraDatabase.Parameters.Remove "USER_NAME"
                OraDatabase.Parameters.Remove "DOMAIN_NAME"
                
                
                '--- Get page number ---
                pageNumber = 0
                If Request("pg") <> "" Then 
                pageNumber = CInt(Request("pg"))
                End If
                
                
                '--- Set Cursor start position ---
                startPosition = pageNumber * MAX_ROWS + 1
                If (NOT rsUser.BOF) AND (NOT rsUser.EOF) Then
                        rsUser.MoveTo ( startPosition )         ' Set starting cursor point
                        
                End If
                
                
                '--- Construct Navigator
                navigator = ""
                If (NOT rsUser.BOF) AND (NOT rsUser.EOF) Then
                        totalRecords = rsUser.RecordCount       ' Get total number of records
                        
                        '--- Create "Previous" link
                        If pageNumber > 0 Then
                                navigator = navigator &"<a href='"& SCRIPT_NAME &"?pg="& pageNumber - 1 &"&"& objPMod.ComposeURL &"' class='body_link' title='Show Previous Page'>&laquo; Previous</a>"
                        End If
                        
                        '--- Create "Next" link
                        If ( startPosition + MAX_ROWS ) < totalRecords Then
                                navigator = navigator &"&nbsp;&nbsp;<a href='"& SCRIPT_NAME &"?pg="& pageNumber + 1 &"&"& objPMod.ComposeURL &"' class='body_link' title='Show Next Page'>Next &raquo;</a>"
                        End If
                        
                End If
                
                
                '--- Calculate Last Record ---
                If totalRecords > 0 Then
                        lastRecord = ( startPosition - 1 + MAX_ROWS ) _
                                                + ( CInt( ( startPosition - 1 + MAX_ROWS )/totalRecords > 1) ) * ( ( startPosition - 1 + MAX_ROWS ) - totalRecords )
                End If
                %>
                <table width="100%"  border="0" cellspacing="0" cellpadding="0">
          <tr align="left">
            <td colspan="2" class="body_row">&nbsp;</td>
          </tr>
          <tr>
            <td align="left" class="body_row">
                        <%
                        If totalRecords > 0 Then 
                                Response.write "Showing "& startPosition &" - "& lastRecord &" of "& totalRecords
                        Else
                                Response.write "No Results."
                        End If
                        %></td>
            <td align="right" class="body_scol"><%=navigator%></td>
          </tr>
        </table>          
                 <!-- DETAILS ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
                 <table width="100%"  border="0" cellspacing="3" cellpadding="0">
          <tr>
                        <td width="1%" background="images/bg_table_col.gif"><img src="images/spacer.gif" width="16" height="16" hspace="2"></td>
            <td width="30%" background="images/bg_table_border.gif">
                        <table width="100%"  border="0" cellspacing="1" cellpadding="2">
              <tr>
                <td align="right" nowrap background="images/bg_table_col.gif" class="body_col">Full Name </td>
              </tr>
            </table></td>
            <td width="30%" align="right" nowrap background="images/bg_table_col.gif" class="body_col">User Name</td>
            <td width="40%" align="right" nowrap background="images/bg_table_col.gif" class="body_col">Domain</td>
          </tr>
                  <%If (Request("filter") = "") AND (rsUser.RecordCount > 0) Then%>
                  <tr>
                        <td align="center" background="images/bg_table_col.gif"><input type="checkbox" name="everyone" value="Y"></td>
            <td nowrap class="body_row" background="images/bg_table_col.gif"><img src="images/i_accounts.gif" width="16" height="14" border="0" hspace="4" align="absmiddle">Everyone</td>
            <td background="images/bg_table_col.gif"></td>
                        <td background="images/bg_table_col.gif"></td>
          </tr>
                  <%End If%>
                  <%
                  '--- Render rows ---
                  Do While (NOT rsUser.BOF) AND (NOT rsUser.EOF)
                                If rsUser.RowPosition => (startPosition + MAX_ROWS) Then Exit Do        ' Limit the number of rows displayed
                  %>
          <tr>
                        <td align="center"><input type="checkbox" name="user_id_list" value="<%=rsUser("user_id")%>" <%If rsUser("user_id") < 1 Then%>disabled<%End If%>></td>
            <td nowrap class="body_row"><%=Eval( rsUser("user_image") )  &  rsUser("full_name")%></td>
            <td class="body_rowg"><%=rsUser("user_name")%></td>
            <td class="body_rowg"><%=rsUser("domain")%></td>
          </tr>
                  <%rsUser.MoveNext%>
                  
                  <%If (NOT rsUser.BOF) AND (NOT rsUser.EOF) Then%>
          <tr>
            <td colspan="4" background="images/bg_table_border.gif"><img src="images/spacer.gif" width="1" height="1"></td>
          </tr>
                  <%End If%>
                  
                  <%
                  Loop
                  
                  
                  
                  rsUser.Close()
                  Set rsUser = Nothing
                  %>
          <tr>
            <td colspan="4" background="images/bg_table_border.gif">
                         <table width="100%"  border="0" cellspacing="1" cellpadding="2">
              <tr>
                <td nowrap background="images/bg_table_col.gif"><img src="images/spacer.gif" width="1" height="1"></td>
              </tr>
             </table>
                        </td>
          </tr>
         </table>        
                 <!-- +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ -->
                 <table width="100%"  border="0" cellspacing="0" cellpadding="0">
          <tr>
            <td align="right" class="body_scol"><%=navigator%></td>
          </tr>
        </table>                
                
                
        </td>
  </tr>
  <%=objPMod.ComposeHiddenTags()%>
  <input type="hidden" name="action" value="true">
  </form>
</table>
</body>
</html>
<%
'------------ RUN AFTER PAGE RENDER -----------
Set objFormCollector = Nothing
'----------------------------------------------
%>
<!--#include file="common/globals_destructor.asp"-->