Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>
<%
'=====================================================
'|                                                   |
'|                         _SetRoleVariationPermissions                  |
'|                                                   |
'=====================================================
%>
<%
Option explicit
Response.Expires = 0
%>
<!--#include file="common/globals.asp"-->
<!--#include file="common/config.asp"-->
<!--#include file="common/common_subs.asp"-->
<!--#include file="common/_code_behind_common.asp"-->
<%
'------------ ACCESS CONTROL ------------------
%>
<!--#include file="_access_control_general.asp"-->
<%
'------------ VARIABLE DEFINITION -------------
'------------ CONSTANTS DECLARATION -----------
'------------ VARIABLE INIT -------------------
'------------ CONDITIONS ----------------------
'----------------------------------------------
%>
<%
'--------------------------------------------------------------------------------------------------------------------------
Sub SetRoleVariationPermissions ()
        Dim rsQry, aRoleAndObjects, i, LastRow, ObjId, RoleId, OraParameter
        
        On Error Resume Next
        
        OraDatabase.Parameters.Add "APP_ID",    Request("app_id"),              ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "USER_ID",   Request("user_id"),     ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "ROLE_ID",   NULL,                                   ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "OBJ_ID",    NULL,                                   ORAPARM_INPUT, ORATYPE_NUMBER 
        OraDatabase.Parameters.Add "IS_VISIBLE",NULL,                                   ORAPARM_INPUT, ORATYPE_VARCHAR2
        OraDatabase.Parameters.Add "IS_ACTIVE", NULL,                                   ORAPARM_INPUT, ORATYPE_VARCHAR2
        
        
        '--- Get All Role Controls Pairs for this Application and User ---
        Set OraParameter = OraDatabase.Parameters
        Set rsQry = OraDatabase.DbCreateDynaset( GetQuery ("RoleObjectPairsForUserPermissionUpdate.sql") , ORADYN_DEFAULT )
        aRoleAndObjects = rsQry.GetRows()
        LastRow = UBound( aRoleAndObjects, 2 )
        rsQry.Close
        Set rsQry = Nothing
        
        
        '--- Set Role Permissions ---
        objEH.TryORA ( OraSession )
                
                For i = 0 To LastRow
                        
                        RoleId = aRoleAndObjects( 0, i )
                        ObjId = aRoleAndObjects( 1, i )
                        
                        OraParameter("ROLE_ID").Value = RoleId
                        OraParameter("OBJ_ID").Value = ObjId
                        OraParameter("IS_VISIBLE").Value = Request( "VIS_"& RoleId &"_"& ObjId )
                        OraParameter("IS_ACTIVE").Value =  Request( "ACT_"& RoleId &"_"& ObjId )
                        
                        'Response.write OraParameter("ROLE_ID") &"-"& OraParameter("OBJ_ID") &"-"& OraParameter("IS_VISIBLE") &"-"& OraParameter("IS_ACTIVE") &"<br>"
                        OraDatabase.ExecuteSQL _
                        "BEGIN   pk_Role.Set_Role_Variation_Permissions ( :USER_ID, :APP_ID, :ROLE_ID, :OBJ_ID, :IS_VISIBLE, :IS_ACTIVE );   END;"
                        
                Next
                
                
                '--- Log Action ---
                'objEH.LogAction  _
                'objAccessControl.UserId, _
                'enumAT_EVENT_COMMENT, _
                '"Sub RemoveProductFromOs PROD_ID_LIST="& Request("prod_id_list") &", OS_ID="& Request("os_id") , _
                'SCRIPT_NAME, _
                '"Removed Products from OS.", _
                'OraDatabase 
                
        objEH.CatchORA ( OraSession )
        
        
        OraDatabase.Parameters.Remove "APP_ID"
        OraDatabase.Parameters.Remove "USER_ID"
        OraDatabase.Parameters.Remove "ROLE_ID"
        OraDatabase.Parameters.Remove "OBJ_ID"
        OraDatabase.Parameters.Remove "IS_VISIBLE"
        OraDatabase.Parameters.Remove "IS_ACTIVE"
        
End Sub
'--------------------------------------------------------------------------------------------------------------------------
%>
<%
'**************************** M  A  I  N ******************************
' --- Form is Valid ---
Call SetRoleVariationPermissions()

If objEH.Finally Then
        Call OpenInWindow ( Request("rfile") &"?"& objPMod.ComposeURL() )
End If
'**********************************************************************
%>
<%
'------------ RUN AFTER CODE RUN --------------
'----------------------------------------------
%><!--#include file="common/globals_destructor.asp"-->