Subversion Repositories DevTools

#                       ConvertFile             - Convert file(s) to Unix or Dos Text

#                       ReplaceTags             - Replace Tags on target file

#                        chmodItem              - Set file or directory permissions

#----------------------------------------------------------------------------

# Function        : ReplaceTags

#

# Description     : This sub-routine is used to replace Tags in one or more files

#

# Inputs          : outPath                 - Output directory

#                   flist                   - List of files in that directory

#                   or

#                   SearchOptions           - Search options to find files

#                                           --Recurse

#                                           --NoRecurse

#                                           --FilterIn=xxx

#                                           --FilterInRe=xxx

#                                           --FilterOut=xxx

#                                           --FilterOutRe=xxx

#                   Common options

#                                           --Tag=Tag,Replace

#                                           

#

# Returns         : 1

#

sub ReplaceTags

{

    my @uargs;

    my $search =  JatsLocateFiles->new( '--NoRecurse' );

    my @tagsList;

    my $tagSep = ',';

    my @tagOrder;

    my %tagData;

    #

    #   Process user arguments extracting options

    #

    foreach  ( @_ )

    {

        if ( m~^--Recurse~ ) {

            $search->recurse(1);

        } elsif ( m~^--NoRecurse~) {

            $search->recurse(0);

        } elsif ( /^--FilterOut=(.*)/ ) {

            $search->filter_out($1);

        } elsif ( /^--FilterOutRe=(.*)/ ) {

            $search->filter_out_re($1);

        } elsif ( /^--FilterIn=(.*)/ ) {

            $search->filter_in($1);

        } elsif ( /^--FilterInRe=(.*)/ ) {

            $search->filter_in_re($1);

        } elsif ( m~^--Tag=(.*)~) {

            push @tagsList, $1;

        } elsif ( m~^--~) {

            Error ("ReplaceTags: Unknown option: $_");

        } else {

            push @uargs, $_;

        }

    }

    #

    #   Process non-option arguments

    #       - Base dir

    #       - List of files

    #

    my ($outPath, @flist) = @uargs;

    Error ("ReplaceTags: Target Dir must be specified" ) unless ( $outPath );

    #

    #   Sanity Tests

    #

    Error ("ReplaceTags: No tags specified" ) unless ( @tagsList );

    #

    # Convert output path to physical path

    #

    my $topDir = catdir($DebianWorkDir, $outPath);

    Verbose("ReplaceTags: topDir: $topDir");

    Error ("ReplaceTags: Path does not exist", $topDir) unless ( -e $topDir );

    Error ("ReplaceTags: Path is not a directory", $topDir) unless ( -d $topDir );

    #

    #   Convert Tags into pairs for latter use

    #

    my $sep = quotemeta ($tagSep );

    foreach my $tag ( @tagsList )

    {

        my ($tname,$tvalue) = split ( $sep, $tag );

        Error ("No tag value in: $tag" ) unless ( defined $tvalue );

        Error ("Duplicate Tag: $tname" ) if ( exists $tagData{$tname} );

        Verbose ("Tag: $tname :: $tvalue");

        push @tagOrder, $tname;

        $tagData{$tname} = $tvalue;

    }

    #

    #   Need to determine if we are searching or simply using a file list

    #   There are two forms of the functions. If any of the search options have

    #   been used then we assume that we are searchine

    #

    if ( $search->has_filter() )

    {

        Error ("ReplaceTags: Cannot mix search options with named files") if ( @flist );

        @flist = $search->search($topDir);

    }

    Error ("ReplaceTags: No files specified") unless ( @flist );

    #

    #   Process all named files

    #

    foreach my $file ( @flist )

    {

        # this is our file that we want to clean.

        my ($ifileLoc) = "$topDir/$file";

        my ($tfileLoc) = "$topDir/$file\.tmp";

        Verbose("ReplaceTags: $file");

        # we will check to see if the file exists.

        #

        my $ifile;

        my $tfile;

        if ( -f "$ifileLoc" )

        {

            open ($ifile, "< $ifileLoc" ) or

                Error("Failed to open file [$ifileLoc] : $!");

            open ($tfile, "> $tfileLoc" ) or

                Error("Failed to open file [$tfileLoc] : $!");

            while ( <$ifile> ) 

            {

                s~[\n\r]+$~~;               # Chomp

                #

                #   Perform tag replacement

                #

                foreach my $tag ( @tagOrder )

                {

                    my $value = $tagData{$tag};

                    if ( s~$tag~$value~g )

                    {

                        Verbose2("Replaced: $tag with $value");

                    }

                }

                print $tfile "$_\n";

            }

        }

        else

        {

            Error("ReplaceTags [$ifileLoc] does not exist.");

        }

        close $ifile;

        close $tfile;

        # lets replace our original file with the new one

        #

        if(File::Copy::move("$tfileLoc", "$ifileLoc"))

        {

            Verbose2("ReplaceTags: Renamed [$tfileLoc] to [$ifileLoc] ...");

        }

        else

        {

            Error("ReplaceTags: Failed to rename file [$tfileLoc] to [$ifileLoc]: $!");

        }

    }

    return 1;

}