Subversion Repositories DevTools

# Function        : ConvertFiles

#

# Description     : This sub-routine is used to remove all carrage return\line

#                   feeds from a line and replace them with the platform

#                   specific equivalent chars.

#

#                   We let PERL determine what characters are written to the

#                   file base on the  platform you are running on.

#

#                   i.e. LF    for unix

#                        CR\LF for win32

#

# Inputs          : outPath                 - Output directory

#                   flist                   - List of files in that directory

#                   or

#                   SearchOptions           - Search options to find files

#                                           --Recurse

#                                           --NoRecurse

#                                           --FilterIn=xxx

#                                           --FilterInRe=xxx

#                                           --FilterOut=xxx

#                                           --FilterOutRe=xxx

#                   Common options

#                                           --Dos

#                                           --Unix

#

#

# Returns         : 1

#

sub ConvertFiles

{

    my @uargs;

    my $lineEnding = "\n";

    my ($dosSet, $unixSet);

    my $search =  JatsLocateFiles->new( '--NoRecurse' );

    #

    #   Process user arguments extracting options

    #

    foreach  ( @_ )

    {

        if ( m~^--Recurse~ ) {

            $search->recurse(1);

        } elsif ( m~^--NoRecurse~) {

            $search->recurse(0);

        } elsif ( /^--FilterOut=(.*)/ ) {

            $search->filter_out($1);

        } elsif ( /^--FilterOutRe=(.*)/ ) {

            $search->filter_out_re($1);

        } elsif ( /^--FilterIn=(.*)/ ) {

            $search->filter_in($1);

        } elsif ( /^--FilterInRe=(.*)/ ) {

            $search->filter_in_re($1);

        } elsif ( m~^--Dos~) {

            $lineEnding = "\r\n";

            $dosSet = 1;

        } elsif ( m~^--Unix~) {

            $lineEnding = "\n";

            $unixSet = 1;

        } elsif ( m~^--~) {

            Error ("ConvertFile: Unknown option: $_");

        } else {

            push @uargs, $_;

        }

    }

    #

    #   Process non-option arguments

    #       - Base dir

    #       - List of files

    #

    my ($outPath, @flist) = @uargs;

    Error ("ConvertFiles: Target Dir must be specified" ) unless ( $outPath );

    #

    #   Sanity Tests

    #

    Error ("ConvertFiles: --Dos and --Unix are mutually exclusive" ) if ( $dosSet && $unixSet );

    #

    # Convert output path to physical path

    #

    my $topDir = catdir($DebianWorkDir, $outPath);

    Verbose("ConvertFiles: topDir: $topDir");

    Error ("ConvertFiles: Path does not exist", $topDir) unless ( -e $topDir );

    Error ("ConvertFiles: Path is not a directory", $topDir) unless ( -d $topDir );

    #

    #   Need to determine if we are searching or simply using a file list

    #   There are two forms of the functions. If any of the search options have

    #   been used then we assume that we are searchine

    #

    if ( $search->has_filter() )

    {

        Error ("ConvertFiles: Cannot mix search options with named files") if ( @flist );

        @flist = $search->search($topDir);

    }

    Error ("ConvertFiles: No files specified") unless ( @flist );

    #

    #   Process all named files

    #

    foreach my $file ( @flist )

    {

        # this is our file that we want to clean.

        my ($ifileLoc) = "$topDir/$file";

        my ($tfileLoc) = "$topDir/$file\.tmp";

        Verbose("ConvertFile: $file");

        # we will check to see if the file exists.

        #

        my $ifile;

        my $tfile;

        if ( -f "$ifileLoc" )

        {

            open ($ifile, "< $ifileLoc" ) or

                Error("Failed to open file [$ifileLoc] : $!");

            open ($tfile, "> $tfileLoc" ) or

                Error("Failed to open file [$tfileLoc] : $!");

            binmode $tfile;

            while ( <$ifile> ) 

            {

                s~[\n\r]+$~~;               # Chomp

                print $tfile "$_" . $lineEnding;

            }

        }

        else

        {

            Error("ConvertFiles [$ifileLoc] does not exist.");

        }

        close $ifile;

        close $tfile;

        # lets replace our original file with the new one

        #

        if(File::Copy::move("$tfileLoc", "$ifileLoc"))

        {

            Verbose2("ConvertFiles: Renamed [$tfileLoc] to [$ifileLoc] ...");

        }

        else

        {

            Error("ConvertFiles: Failed to rename file [$tfileLoc] to [$ifileLoc]: $!");

        }

    }

    return 1;

}

#-------------------------------------------------------------------------------