Subversion Repositories DevTools

      <%repNum = 13%>

      <strong>Release DEVI Status</strong><br>

      Use this report to obtain a list of DEVIs for all packages in a given release.<br>

      <a href="rep_devi_status_for_release.asp?repnum=<%=repNum%>&group=<%=SSgroup%>" class="txt_linked">more...</a><br><br><hr size="1" noshade color="#DAD7C8">

 -->

Sub Get_Open_Release_Labels ( NNproj_id, NNrtag_id, BBallow_all )

   Dim rsTemp, Query_String

   Query_String = _

   "SELECT rtag_id, rtag_name FROM release_tags WHERE proj_id = "& NNproj_id &"AND official in ('N','C','R')  ORDER BY rtag_name ASC"

   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

   Response.write "<select name='FRrtag_id' onChange=""Cascaded_Menu('parent','"& scriptName &"?FRproj_id="& NNproj_id &"&group="& Request("group") &"&repnum="& Request("repnum") &"&FRrtag_id=',this,0)"" class='form_item'>"

   If BBallow_all Then

      Response.write "<option value='-1'>ALL</option>"

   Else

      Response.write "<option></option>"

   End If

      If NNproj_id <> -1 Then

         While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))

            If CDbl(NNrtag_id) = CDbl(rsTemp.Fields("rtag_id")) Then

                 Response.write "<option value='"& rsTemp.Fields("rtag_id") &"' selected>"& (rsTemp.Fields("rtag_name")) &"</option>"

              Else

               Response.write "<option value='"& rsTemp.Fields("rtag_id") &"'>"& (rsTemp.Fields("rtag_name")) &"</option>"

            End If

            rsTemp.MoveNext

         WEnd

      End If

   Response.write "</select>"

   rsTemp.Close

   Set rsTemp = nothing

End Sub

<%

'-------------------------------------------------------------------------------------------------------------------------------------------------------------------

Function  Get_CQ_Issues ( SSsql, OOrsCQ )

   If OOrsCQ.State = 1 Then

      OOrsCQ.Close()

   End If

   On Error Resume Next

   OOrsCQ.ActiveConnection = CQ_conn

   OOrsCQ.Source = SSsql

   OOrsCQ.CursorType = 0

   OOrsCQ.CursorLocation = 2

   OOrsCQ.LockType = 3

   OOrsCQ.Open()

   Get_CQ_Issues = Err.Number

End Function

'----------------------------------------------------------------------------------------------------------------------------------------

Function GetRMIssueState (NNpv_id, NNissId)

   Dim rsTemp, Query_String

   Dim s

   Query_String = _

   " SELECT (CASE WHEN iss_state = 0 THEN ' (O)' ELSE ' (F)' END) AS issState "&_

   "   FROM cq_issues cq "&_

   "  WHERE cq.pv_id = "& NNpv_id &_

   "    AND cq.iss_id = "& NNissId

   Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

   s = ""

   If ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF)) Then

      s = (rsTemp.Fields("issState"))

   End If

   rsTemp.Close

   Set rsTemp = nothing

   GetRMIssueState = s

End Function

'----------------------------------------------------------------------------------------------------------------------------------------

' Function returns the number of imported clearquest issues

' and builds a string suitable for querying the clearquest issues database

Function Get_Package_Issues ( NNpv_id, SSsql, DDfixedIss, DDnotesIssDict, nIssState )

   Dim rsTemp, sqlstr, DEVIiss, TDSEiss, VT5DMiss, VTSUPiss, retVal

   sqlstr = "SELECT iss_db, iss_id, iss_state, notes FROM CQ_ISSUES WHERE pv_id="& NNpv_id &"  AND iss_state IN (" & nIssState & ")"

   Set rsTemp = OraDatabase.DbCreateDynaset( sqlstr, cint(0))

   retVal = rsTemp.RecordCount

   DEVIiss  = "-1"

   TDSEiss  = "-1"

   VT5DMiss = "-1"

   VTSUPiss = "-1"

   While ((NOT rsTemp.BOF) AND (NOT rsTemp.EOF))

      If CInt(rsTemp("iss_db")) = CInt(enumCLEARQUEST_DEVI_ID) Then

         DEVIiss = DEVIiss &","& rsTemp("iss_id")

      ElseIf CInt(rsTemp("iss_db")) = CInt(enumCLEARQUEST_TDSE_ID) Then

         TDSEiss = TDSEiss &","& rsTemp("iss_id")

      ElseIf CInt(rsTemp("iss_db")) = CInt(enumCLEARQUEST_VT5DM_ID) Then

         VT5DMiss = VT5DMiss &","& rsTemp("iss_id")

      ElseIf CInt(rsTemp("iss_db")) = CInt(enumCLEARQUEST_VTSUP_ID) Then

         VTSUPiss = VTSUPiss &","& rsTemp("iss_id")

      End If

      rsTemp.MoveNext

   WEnd

   ' Construct SQL statement for CQ database

   SSsql = ReadFile( rootPath & "queries\cq_issues_rep1.sql" )

   SSsql = Replace( SSsql, "/*enumCLEARQUEST_DEVI_ID*/", enumCLEARQUEST_DEVI_ID)

   SSsql = Replace( SSsql, "/*enumCLEARQUEST_TDSE_ID*/", enumCLEARQUEST_TDSE_ID)

   SSsql = Replace( SSsql, "/*enumCLEARQUEST_VT5DM_ID*/", enumCLEARQUEST_VT5DM_ID)

   SSsql = Replace( SSsql, "/*enumCLEARQUEST_VTSUP_ID*/", enumCLEARQUEST_VTSUP_ID)

   SSsql = Replace( SSsql, "/*DEVIiss*/", DEVIiss)

   SSsql = Replace( SSsql, "/*TDSEiss*/", TDSEiss)

   SSsql = Replace( SSsql, "/*VT5DMiss*/", VT5DMiss)

   SSsql = Replace( SSsql, "/*VTSUPiss*/", VTSUPiss)

   rsTemp.Close()

   Set rsTemp = nothing

   Get_Package_Issues = retVal

End Function

'-------------------------------------------------------------------------------------------------------------------------------------------------------------------

Sub sdAdd( dict, key, value )

   if IsNull(value) Then

      dict.Add CStr(key),""

   else

      dict.Add CStr(key),CStr(value)

   End If

End Sub

Function sdItem( dict, i )

   Dim a

   Dim s

   a = dict.Items

   s = a(i)

   sdItem=s

End Function

Function sdKey( dict, i )

   Dim a

   a = dict.Keys

   sdKey = a(i)

End Function

'-------------------------------------------------------------------------------------------------------------------------------------------------------------------

Function ReleaseDeviStatus_ReportCheckbox( width, NameAndValue, Label, bCheck )

   Dim s

   If (IsNull(Request(NameAndValue)) OR (Request(NameAndValue) = "")) AND (not bCheck) Then

      s = "<td width=""" & width & """><INPUT Type=Checkbox  name=""" & NameAndValue & """ value=""" & NameAndValue & """>" & Label & "</td>"

   Else

      s = "<td width=""" & width & """><INPUT Type=Checkbox  CHECKED name=""" & NameAndValue & """ value=""" & NameAndValue & """>" & Label & "</td>"

   End If

   ReleaseDeviStatus_ReportCheckbox = s

End Function

'-------------------------------------------------------------------------------------------------------------------------------------------------------------------

Function GetCQIssuesListFilter

   Dim s

   s = ""

   If not (IsNull(Request("CB_FILTER_FIXED")) OR (Request("CB_FILTER_FIXED") = "")) Then

      s = CStr(enumISSUES_STATE_FIXED)

      If not (IsNull(Request("CB_FILTER_OUTSTANDING")) OR (Request("CB_FILTER_OUTSTANDING") = "")) Then

         s = s & "," & CStr(enumISSUES_STATE_IMPORTED)

      End If

   Else

      If not (IsNull(Request("CB_FILTER_OUTSTANDING")) OR (Request("CB_FILTER_OUTSTANDING") = "")) Then

         s = CStr(enumISSUES_STATE_IMPORTED)

      End If

   End If

   GetCQIssuesListFilter = s

End Function

'-------------------------------------------------------------------------------------------------------------------------------------------------------------------

Function GetPkgNameAndVersion(SSPvId, SSPkgNameAndVer)

   Dim SSpkgID, SSpkgName, SSpkgVersion, SSsrc_path, SSpkgDesc, BBdlocked

   SSpkgID      = ""

   SSpkgName    = ""

   SSpkgVersion = ""

   SSsrc_path   = ""

   SSpkgDesc    = ""

   BBdlocked    = 0

   Call Get_Pkg_Short_Info( SSPvId, SSpkgID, SSpkgName, SSpkgVersion, SSsrc_path, SSpkgDesc, BBdlocked )

   If not ((SSpkgName = "") and (SSpkgVersion = "")) Then

      SSPkgNameAndVer = SSpkgName & " " & SSpkgVersion

      GetPkgNameAndVersion = True

   Else

      SSPkgNameAndVer = ""

      GetPkgNameAndVersion = False

   End If

End Function

'-------------------------------------------------------------------------------------------------------------------------------------------------------------------

'==================================================================================

' Report Name      :   ReleaseDeviStatus_Report

' Description      :   List DEVIs for all Package Versions in a Release

' INPUT            :

'==================================================================================

Sub ReleaseDeviStatus_Report ( SSsection, NNproj_id, NNrtag_id)

   Dim rsCQQry                   ' Query for the CLEARQUEST database

   Dim rsRMQry                   ' Query for the RELEASE MANAGER database

   Dim SQLstr                    ' String to contain a query

   Dim issueCnt                  ' Records how many CQ issues were found for a given RM package version

   Dim retVal                    ' General return value

   Dim isFirstDeviRow            ' HTML rendering helper

   Dim isRowOpen                 ' HTML rendering helper

   Dim dict_Iss_Id_to_Iss_Num    ' Dictionaries populated during the formation of the package DEVI list

   Dim dict_Iss_Id_to_Iss_DB     '   creation, supporting the generation of the DEVI details list.

   Dim dict_Iss_Id_to_Risk

   Dim dict_Iss_Id_to_Summary

   Dim dict_Iss_Id_to_CodeRev

   Dim dict_Iss_Id_to_IntNotes

   Dim dict_Iss_Id_to_RelDBPatches

   Dim dict_Iss_Id_to_Pkg

   Dim dict_Iss_Id_to_PvId

   Dim dict_Iss_Id_to_Iss_Status

   Dim dict_Iss_Id_to_Iss_Type

   Dim dict_Iss_Id_to_Aff_Pkg

   Dim i,j,k                     ' General loop vars

   Dim s,strIn,strOut,sDisplay   ' General string vars

   Dim a                         ' General array var

   Dim pkgArr                    ' Holds an array of CSV strings listing RM package names, 1 array element per unique CQ issue found

   Dim pkgCsv                    ' Holds a single CSV string listing RM package names, related to a single unique CQ issue

   Dim pvIdArr                   ' Holds an array of CSV strings listing RM package PV IDs, 1 array element per unique CQ issue found

   Dim pvIdCsv                   ' Holds a single CSV string listing RM package PV IDs, related to a single unique CQ issue

   Dim crRefArr                  ' Holds an array of code review reference strings

   Dim relDbPatchArr             ' Holds an array of related DB patch strings

   Dim sqlTblCnt                 ' Counts the number of tables in the RM query string

   Dim FSO                       ' File System Object

   Dim NewTextFile               ' File Object

   Dim emailReport               ' Boolean flag signalling email generation

   Dim cqFilterStr               ' Fixed and/or Outstanding Issues Filter for RM Query

   Dim cbWIPChecked              ' Default checkbox states

   Dim cbPendingChecked

   Dim cbReleasedChecked

   Dim cbFixed

   Dim cbOutstanding

   Dim cbWithoutIssues

   Dim cbTraverseRipples

   Dim reObj                     ' regular expression object

   Dim reObjMatch

   Dim NumPkgsListed             ' Stats collection vars

   Dim NumIssuesListed

   Dim parRipDate                ' traverse ripple limit date

   Dim lastNonRipplePvId         ' pv_id after ripple version traversal

   Dim cqIssId                   ' clearquest database ID for a given issue (not a human readable number)

   Const Allow_All = TRUE

   Const Disallow_All = FALSE

   NumPkgsListed = 0

   NumIssuesListed = 0

   If NNproj_id = "" Then NNproj_id = -1

   If NNrtag_id = "" Then NNrtag_id = -1

   If SSsection = "TITLE" Then

      Response.write "Release DEVI Status"

      Exit Sub

   End If

   ' Determine if we have to assert default check status on one of the checkboxes

   cbWIPChecked      = False

   cbPendingChecked  = False

   cbReleasedChecked = False

   cbFixed           = False

   cbOutstanding     = False

   cbWithoutIssues   = False

   cbTraverseRipples = False

   If  (IsNull(Request("CB_FILTER_WIP")) OR (Request("CB_FILTER_WIP") = "")) _

   and (IsNull(Request("CB_FILTER_PENDING")) OR (Request("CB_FILTER_PENDING") = "")) _

   and (IsNull(Request("CB_FILTER_RELEASED")) OR (Request("CB_FILTER_RELEASED") = "")) Then

      cbWIPChecked = True

   End If

   If  (IsNull(Request("CB_FILTER_FIXED")) OR (Request("CB_FILTER_FIXED") = "")) _

   and (IsNull(Request("CB_FILTER_OUTSTANDING")) OR (Request("CB_FILTER_OUTSTANDING") = "")) Then

      cbFixed = True

   End If

   If (IsNull(Request("FRripdate")) OR (Request("FRripdate") = "")) Then

      parRipDate = EuroDate(DateAdd("d",-31,Date))

   Else

      parRipDate = Request("FRripdate")

   End If

   If SSsection = "FORM" Then

      %>

      <script language="JavaScript" src="images/calendar.js"></script>

      <table width="100%" border="0" cellpadding="2" cellspacing="1">

         <form action="<%=scriptName%>" method="post" name="repform" onSubmit="MM_validateForm('FRproj_id','Project','R','FRvtree_id','Version Tree','R','FRrtag_id','Release','R');return document.MM_returnValue">

            <table width="100%" border="0" cellpadding="2" cellspacing="1">

               <tr>

                  <td width="50%">

                     <table width="100%" border="0" cellpadding="2" cellspacing="1">

                        <tr>

                           <td width="10%" align="left" valign="top" nowrap class="form_field">Project</td>

                           <td width="90%" valign="top"><%Call Get_Projects( NNproj_id, Disallow_All )%></td>

                        </tr>

                        <tr>

                           <td align="left" nowrap class="form_field">Release</td>

                           <td><%Call Get_Open_Release_Labels ( NNproj_id,  NNrtag_id, Disallow_All )%></td>

                        </tr>

                        <tr><td colspan="2" height="130px"><img src="images/spacer.gif" width="1" height="1"></td></tr>

                        <tr>

                           <td>

                              <input name="btn" type="submit" class="form_btn" value="Submit"            >

                           </td>

                           <td>

                              <input name="btn" type="submit" class="form_btn" value="Mail Me CSV Report">

                              <input type="hidden" name="group" value="<%=parGroup%>">

                              <input type="hidden" name="repnum" value="<%=parRepNum%>">

                              <input type="hidden" name="action" value="true">

                           </td>

                        </tr>

                     </table>

                  </td>

                  <td width="50%">

                     <table width="100%" border="0" cellpadding="2" cellspacing="1">

                        <tr>

                           <td width="60%" valign="top">

                              <fieldset>

                                 <legend><a href="javascript:;" class="body_scol" >Include&nbsp;Package&nbsp;Versions<%=Quick_Help("RepRDS_pv")%>&nbsp;</a></legend>

                                 <table width="100%" border="0" cellpadding="2" cellspacing="1">

                                    <tr><%=ReleaseDeviStatus_ReportCheckbox("25%", "CB_FILTER_WIP", "From Work-in-progress", cbWIPChecked)%></tr>

                                    <tr><%=ReleaseDeviStatus_ReportCheckbox("17%", "CB_FILTER_PENDING", "From Pending", cbPendingChecked)%></tr>

                                    <tr><%=ReleaseDeviStatus_ReportCheckbox("20%", "CB_FILTER_RELEASED", "From Released", cbReleasedChecked)%></tr>

                                    <tr><%=ReleaseDeviStatus_ReportCheckbox("100%", "CB_FILTER_WITHOUT_ISSUES", "Without Issues", cbWithoutIssues)%></tr>

                                 </table>

                              </fieldset>

                           </td>

                           <td width="40%" valign="top">

                              <fieldset>

                                 <legend><a href="javascript:;" class="body_scol" >&nbsp;Include&nbsp;Issues<%=Quick_Help("RepRDS_iss")%>&nbsp;</a></legend>

                                 <table width="100%" border="0" cellpadding="2" cellspacing="1">

                                    <tr><%=ReleaseDeviStatus_ReportCheckbox("100%", "CB_FILTER_FIXED",       "Fixed", cbFixed)%></tr>

                                    <tr><%=ReleaseDeviStatus_ReportCheckbox("100%", "CB_FILTER_OUTSTANDING", "Outstanding", cbOutstanding)%></tr>

                                 </table>

                              </fieldset>

                           </td>

                        </tr>

                        <tr>

                           <td width="60%" valign="top" colspan="2">

                              <fieldset>

                                 <legend><a href="javascript:;" class="body_scol" >&nbsp;From&nbsp;Released<%=Quick_Help("RepRDS_trav")%>&nbsp;</a></legend>

                                 <table width="100%" border="0" cellpadding="0" cellspacing="0">

                                    <tr>

                                       <%=ReleaseDeviStatus_ReportCheckbox("60%", "CB_FILTER_TRAVERSE_RIPPLES", "Traverse Ripples as far back as", cbTraverseRipples)%>

                                       <td>

                                          <input type="text" name="FRripdate" maxlength="10" size="12" value="<%=parRipDate%>"><A onmouseover="window.status='Select a date';return true;" onmouseout="window.status='';return true;" href="javascript:show_calendar('repform.FRripdate',null,null,null);"><img src="images/i_calendar.gif" width="16" height="16" border="0"></a>

                                       </td>

                                    </tr>

                                 </table>

                              </fieldset>

                           </td>

                        </tr>

                     </table>

                  </td>

               </tr>

            </table>

         </form>

      </table>

      <%

      Exit Sub

   End If

   If SSsection = "BODY" Then

      emailReport = false

      If Request("btn") = "Mail Me CSV Report" Then

         emailReport = true

      End If

      If NOT CBool(Request("action")) Then Exit Sub

      If NNrtag_id = -1 then Exit Sub

      ' Construct Release Manager Query based upon form settings (rtag and checkbox states)

      sqlTblCnt = 0

      SQLstr = "SELECT * FROM ( "

      If not (IsNull(Request("CB_FILTER_WIP")) OR (Request("CB_FILTER_WIP") = "")) Then

         sqlTblCnt = sqlTblCnt + 1

         SQLstr = SQLstr & " SELECT p.PROJ_ID,   rt.RTAG_ID,   v.VIEW_ID,   pk.PKG_ID,   pv.PV_ID,"&_

                           "        p.PROJ_NAME, rt.RTAG_NAME, v.VIEW_NAME, pk.PKG_NAME, pv.PKG_VERSION, pv.PKG_LABEL, pv.BUILD_TYPE, pv.DLOCKED, 'WIP' as STATE"&_

                           "   FROM PACKAGE_VERSIONS pv,"&_

                           "        PACKAGES pk,"&_

                           "        RELEASE_TAGS rt,"&_

                           "        PROJECTS p,"&_

                           "        VIEWS v," &_

                           "        WORK_IN_PROGRESS wip"&_

                           "  WHERE wip.RTAG_ID =   :RTAG_ID"&_

                           "    AND wip.RTAG_ID = rt.RTAG_ID"&_

                           "    AND wip.PV_ID   = pv.PV_ID"&_

                           "    AND wip.VIEW_ID = v.VIEW_ID"&_

                           "    AND pv.PKG_ID   = pk.PKG_ID"&_

                           "    AND rt.PROJ_ID  = p.PROJ_ID"

      End If

      If not (IsNull(Request("CB_FILTER_PENDING")) OR (Request("CB_FILTER_PENDING") = "")) Then

         If sqlTblCnt > 0 Then

            SQLstr = SQLstr & " UNION ALL "

         End If

         sqlTblCnt = sqlTblCnt + 1

         SQLstr = SQLstr & " SELECT p.PROJ_ID,   rt.RTAG_ID,   v.VIEW_ID,   pk.PKG_ID,   pv.PV_ID,"&_

                           "        p.PROJ_NAME, rt.RTAG_NAME, v.VIEW_NAME, pk.PKG_NAME, pv.PKG_VERSION, pv.PKG_LABEL, pv.BUILD_TYPE, pv.DLOCKED, 'Pending' as STATE"&_

                           "   FROM PACKAGE_VERSIONS pv,"&_

                           "        PACKAGES pk,"&_

                           "        RELEASE_TAGS rt,"&_

                           "        PROJECTS p,"&_

                           "        VIEWS v," &_

                           "        PLANNED pl"&_

                           "  WHERE pl.RTAG_ID  =   :RTAG_ID"&_

                           "    AND pl.RTAG_ID  = rt.RTAG_ID"&_

                           "    AND pl.PV_ID    = pv.PV_ID"&_

                           "    AND pl.VIEW_ID  = v.VIEW_ID"&_

                           "    AND pv.PKG_ID   = pk.PKG_ID"&_

                           "    AND rt.PROJ_ID  = p.PROJ_ID"

      End If

      If not (IsNull(Request("CB_FILTER_RELEASED")) OR (Request("CB_FILTER_RELEASED") = "")) Then

         If sqlTblCnt > 0 Then

            SQLstr = SQLstr & " UNION ALL "

         End If

         sqlTblCnt = sqlTblCnt + 1

         SQLstr = SQLstr & " SELECT p.PROJ_ID,   rt.RTAG_ID,   v.VIEW_ID,   pk.PKG_ID,   pv.PV_ID,"&_

                           "        p.PROJ_NAME, rt.RTAG_NAME, v.VIEW_NAME, pk.PKG_NAME, pv.PKG_VERSION, pv.PKG_LABEL, pv.BUILD_TYPE, pv.DLOCKED, 'Released' as STATE"&_

                           "   FROM PACKAGE_VERSIONS pv,"&_

                           "        PACKAGES pk,"&_

                           "        RELEASE_TAGS rt,"&_

                           "        PROJECTS p,"&_

                           "        VIEWS v," &_

                           "        RELEASE_CONTENT rc"&_

                           "  WHERE rc.RTAG_ID      =   :RTAG_ID"&_

                           "    AND rc.RTAG_ID      = rt.RTAG_ID"&_

                           "    AND rc.PV_ID        = pv.PV_ID"&_

                           "    AND rc.BASE_VIEW_ID = v.VIEW_ID"&_

                           "    AND pv.PKG_ID       = pk.PKG_ID"&_

                           "    AND rt.PROJ_ID      = p.PROJ_ID"

      End If

      SQLstr = SQLstr & " )"

      SQLstr = SQLstr & " ORDER BY UPPER(PKG_NAME), PKG_VERSION"

      ' Exit if nothing to do

      If sqlTblCnt = 0 Then

         Response.Write "Select one or more of Work-in-progress/Pending/Released package version states to be considered"

         Exit Sub

      End If

      ' Get SQL string for querying the CLEARQUEST database for this package version's fixed issues  enumISSUES_STATE_IMPORTED or enumISSUES_STATE_FIXED

      cqFilterStr = GetCQIssuesListFilter()

      If cqFilterStr = "" Then

         Response.Write "Select one or both of Fixed/Outstanding issues lists to be considered"

         Exit Sub

      End If

      ' Create ADODB recordset for CLEARQUEST query

      Set rsCQQry = Server.CreateObject("ADODB.Recordset")

      ' Query RELEASE MANAGER for Package versions

      OraDatabase.Parameters.Add "RTAG_ID", NNrtag_id, ORAPARM_INPUT, ORATYPE_NUMBER

      Set rsRMQry = OraDatabase.DbCreateDynaset( SQLstr, cint(0))

      OraDatabase.Parameters.Remove "RTAG_ID"

      ' If no records returned issue a message to user and exit

      If rsRMQry.RecordCount = 0 Then

         Response.Write "No records returned - try including additional package version states"

         Exit Sub

      End If

      ' Create a downloadable file

      Set FSO = Server.CreateObject("Scripting.FileSystemObject")

      Set NewTextFile = FSO.CreateTextFile(Server.MapPath("docs\ReleaseDEVIStatus_"&objAccessControl.UserName&".csv"), true)

      ' Create some dictionaries

      set dict_Iss_Id_to_Iss_Num      = CreateObject("Scripting.Dictionary")

      set dict_Iss_Id_to_Iss_DB       = CreateObject("Scripting.Dictionary")

      set dict_Iss_Id_to_Pkg          = CreateObject("Scripting.Dictionary")

      set dict_Iss_Id_to_Risk         = CreateObject("Scripting.Dictionary")

      set dict_Iss_Id_to_Summary      = CreateObject("Scripting.Dictionary")

      set dict_Iss_Id_to_CodeRev      = CreateObject("Scripting.Dictionary")

      set dict_Iss_Id_to_IntNotes     = CreateObject("Scripting.Dictionary")

      set dict_Iss_Id_to_RelDBPatches = CreateObject("Scripting.Dictionary")

      set dict_Iss_Id_to_PvId         = CreateObject("Scripting.Dictionary")

      set dict_Iss_Id_to_Iss_Status   = CreateObject("Scripting.Dictionary")

      set dict_Iss_Id_to_Iss_Type     = CreateObject("Scripting.Dictionary")

      set dict_Iss_Id_to_Aff_Pkg      = CreateObject("Scripting.Dictionary")

      set reObj  = new RegExp

      NewTextFile.WriteLine(DoubleQuotes("Release DEVI Status Report for " & Get_Proj_Name(Request("FRproj_id")) & ", release " & Get_Release_Name(Request("FRrtag_id"))))

      NewTextFile.WriteLine("")

      NewTextFile.WriteLine("Package DEVI List")

      NewTextFile.WriteLine("")

      NewTextFile.WriteLine("""Package"",""Label"",""State"",""Issue Number"",""Issue Summary""")

      %>

      <H3>Release DEVI Status Report for

      &nbsp;project&nbsp;<a href="rtree.asp?proj_id=<%=NNproj_id%>" class="txt_linked"><%=Get_Proj_Name(Request("FRproj_id"))%></a>,

      &nbsp;release&nbsp;<a href="dependencies.asp?rtag_id=<%=NNrtag_id%>" class="txt_linked"><%=Get_Release_Name(Request("FRrtag_id"))%></a>

      </H3>

      <H4>Contents</H4>

      <table width="100%" border="0" cellspacing="0" cellpadding="1">

         <tr>

            <td valign="top" nowrap width="15%"><a href="#C1">Package DEVI List</a></td>

            <td valign="top" width="85%">This contains the list of package versions in the release, along with the CLEARQUEST issues assigned to them.</td>

         </tr>

         <tr><td>&nbsp;</td><td>&nbsp;</td></tr>

         <tr>

            <td valign="top"><a href="#C2">DEVI Details List</a></td>

            <td valign="top">This contains the list of CLEARQUEST issues for the release, along with selected details for each, and a reference back to the package versions to which they have been assigned.</td>

         </tr>

         <tr>

            <td valign="top"><a href="#C3">Statistics</a></td>

            <td valign="top">This contains some statistics collected during the report generation.</td>

         </tr>

         <tr>

            <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

            <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

         </tr>

      </table>

      <H5><a name="C1">Package DEVI List</a></H5>

      <table width="100%" border="0" cellspacing="0" cellpadding="1">

         <tr>

            <td width="10%" nowrap class="body_colb">Package&nbsp;&nbsp;&nbsp;</td>

            <td width="10%" nowrap class="body_colb">Label&nbsp;&nbsp;&nbsp;</td>

            <td width="10%" nowrap class="body_colb">State&nbsp;&nbsp;&nbsp;</td>

            <td width="10%" class="body_colb">Issue Number<br>(F)=Fixed<br>(O)=Outstanding</td>

            <td width="60%" nowrap class="body_colb">Issue Summary&nbsp;&nbsp;&nbsp;</td>

         </tr>

         <tr>

            <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

            <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

            <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

            <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

            <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

         </tr>

         <%

         while ((NOT rsRMQry.BOF) AND (NOT rsRMQry.EOF))

            isFirstDeviRow = 1

            isRowOpen = 1

            ' If this package version is a ripple, try and find its non-ripple predecessor in order to get at the

            ' issues that were addressed

            lastNonRipplePvId = rsRMQry("PV_ID")

            If not (IsNull(Request("CB_FILTER_TRAVERSE_RIPPLES")) OR (Request("CB_FILTER_TRAVERSE_RIPPLES") = "")) Then

               if ((rsRMQry("BUILD_TYPE") = "Y") and (rsRMQry("DLOCKED") = "Y")) Then

                  If (IsNull(Request("FRripdate")) OR (Request("FRripdate") = "")) Then

                     lastNonRipplePvId = getLastNonRippleVersionPVID(rsRMQry("PV_ID"))

                  Else

                     lastNonRipplePvId = getLastNonRippleVersionPVIDLimitedByDate(rsRMQry("PV_ID"), Request("FRripdate"))

                  End If

                  If IsNull(lastNonRipplePvId) or (lastNonRipplePvId = "") Then

                     lastNonRipplePvId = rsRMQry("PV_ID")

                  End If

               End If

            End If

            issueCnt = Get_Package_Issues (lastNonRipplePvId, SQLstr, NULL, NULL, cqFilterStr )

            if (issueCnt > 0) _

            or not(IsNull(Request("CB_FILTER_WITHOUT_ISSUES")) OR (Request("CB_FILTER_WITHOUT_ISSUES") = "")) Then

               NumPkgsListed = NumPkgsListed + 1

               %>

               <tr>

                  <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

                  <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

                  <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

                  <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

                  <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

               </tr>

               <%

               NewTextFile.Write(DoubleQuotes(rsRMQry("PKG_NAME")) & ",")

               NewTextFile.Write(DoubleQuotes(rsRMQry("PKG_LABEL")) & ",")

               NewTextFile.Write(DoubleQuotes(rsRMQry("STATE")) & ",")

               %>

               <tr>

               <td valign="top"><a href="fixed_issues.asp?rtag_id=<%=NNrtag_id%>&pv_id=<%=rsRMQRy("PV_ID")%>" class="txt_linked"><%=rsRMQry("PKG_NAME")%></a></td>

               <td valign="top"><%=rsRMQry("PKG_LABEL")%></td>

               <td valign="top"><%=rsRMQry("STATE")%></td>

               <%

               ' Complete the row immediately if this package version has no issues, else process the issues.

               if issueCnt = 0 Then

                  NewTextFile.WriteLine(",")

                  %>

                  <td><img src="images/spacer.gif" width="1" height="1"></td>

                  <td><img src="images/spacer.gif" width="1" height="1"></td>

                  </tr>

                  <%

                  isRowOpen = 0

               Else

                  ' Query the CLEARQUEST database

                  retVal = Get_CQ_Issues ( SQLstr, rsCQQry )

                  If retVal = 0 Then

                     While ((NOT rsCQQry.BOF) AND (NOT rsCQQry.EOF))

                        Dim issueNumber

                        issueNumber = rsCQQry("ISS_NUM") & GetRMIssueState (lastNonRipplePvId, rsCQQry("ISS_ID"))

                        ' Keep dictionary of issue IDs to human readable issue numbers, plus other info we will need later on for the report

                        If not dict_Iss_Id_to_Iss_Num.Exists(CStr(rsCQQry("ISS_ID"))) Then

                           sdAdd dict_Iss_Id_to_Iss_Num,      rsCQQry("ISS_ID"), issueNumber

                           sdAdd dict_Iss_Id_to_Iss_DB,       rsCQQry("ISS_ID"), rsCQQry("ISS_DB")

                           sdAdd dict_Iss_Id_to_Risk,         rsCQQry("ISS_ID"), rsCQQry("RISK")

                           sdAdd dict_Iss_Id_to_Summary,      rsCQQry("ISS_ID"), rsCQQry("SUMMARY")

                           sdAdd dict_Iss_Id_to_CodeRev,      rsCQQry("ISS_ID"), rsCQQry("CR_REF")

                           sdAdd dict_Iss_Id_to_IntNotes,     rsCQQry("ISS_ID"), rsCQQry("INT_NOTES")

                           sdAdd dict_Iss_Id_to_RelDBPatches, rsCQQry("ISS_ID"), rsCQQry("DB_PATCHES")

                           sdAdd dict_Iss_Id_to_Iss_Type,     rsCQQry("ISS_ID"), rsCQQry("ISSUE_TYPE")

                           sdAdd dict_Iss_Id_to_Iss_Status,   rsCQQry("ISS_ID"), rsCQQry("STATUS")

                           sdAdd dict_Iss_Id_to_Aff_Pkg,      rsCQQry("ISS_ID"), rsCQQry("AFFECTED_PACKAGES")

                        End If

                        ' Keep dictionary of issue IDs to release manager package names (latter is a comma separated list)

                        If dict_Iss_Id_to_Pkg.Exists(CStr(rsCQQry("ISS_ID"))) Then

                           dict_Iss_Id_to_Pkg.Item(CStr(rsCQQry("ISS_ID"))) = dict_Iss_Id_to_Pkg.Item(CStr(rsCQQry("ISS_ID"))) & "," & CStr(rsRMQry("PKG_NAME")) & " " & CStr(rsRMQry("PKG_VERSION"))

                        Else

                           sdAdd dict_Iss_Id_to_Pkg, rsCQQry("ISS_ID"), rsRMQry("PKG_NAME") & " " & CStr(rsRMQry("PKG_VERSION"))

                        End If

                        ' Keep dictionary of issue IDs to release manager package version IDs (latter is a comma separated list)

                        If dict_Iss_Id_to_PvId.Exists(CStr(rsCQQry("ISS_ID"))) Then

                           dict_Iss_Id_to_PvId.Item(CStr(rsCQQry("ISS_ID"))) = dict_Iss_Id_to_PvId.Item(CStr(rsCQQry("ISS_ID"))) & "," & CStr(rsRMQry("PV_ID"))

                        Else

                           sdAdd dict_Iss_Id_to_PvId, rsCQQry("ISS_ID"), rsRMQry("PV_ID")

                        End If

                        ' Begin new row if needed

                        if isRowOpen = 0 Then

                           isRowOpen = 1

                           %><tr><%

                        End If

                        ' If first row, no need to pad since those columns have already been filled in outer loop

                        If isFirstDeviRow = 1 Then

                           isFirstDeviRow = 0

                           NewTextFile.Write(DoubleQuotes(issueNumber) & ",")

                           NewTextFile.WriteLine(DoubleQuotes(rsCQQry("SUMMARY")))

                           %>

                           <td valign="top"><a class="txt_linked"  href="#<%=rsCQQry("ISS_ID")%>"><%=issueNumber%></a></td>

                           <td valign="top"><%=rsCQQry("SUMMARY")%></td>

                           <%

                        Else

                           NewTextFile.Write(",,," & DoubleQuotes(issueNumber) & ",")

                           NewTextFile.WriteLine(DoubleQuotes(rsCQQry("SUMMARY")))

                           %>

                           <td valign="top"><img src="images/spacer.gif" width="1" height="1"></td>

                           <td valign="top"><img src="images/spacer.gif" width="1" height="1"></td>

                           <td valign="top"><img src="images/spacer.gif" width="1" height="1"></td>

                           <td valign="top"><a class="txt_linked" href="#<%=rsCQQry("ISS_ID")%>"><%=issueNumber%></a></td>

                           <td valign="top"><%=rsCQQry("SUMMARY")%></td>

                           <%

                        End If

                        ' End this row

                        isRowOpen = 0

                        %></tr><%

                        rsCQQry.MoveNext

                     Wend  ' end of loop processing each issue

                     rsCQQry.Close

                  Else

                     NewTextFile.WriteLine("," & DoubleQuotes("ERROR - could not get issue details from CLEARQUEST"))

                     %>

                     <td><img src="images/spacer.gif" width="1" height="1"></td>

                     <td>ERROR - could not get issue details from CLEARQUEST</td>

                     <%

                  End If

                  ' Complete the row if needed

                  if isRowOpen = 1 Then

                     if (isFirstDeviRow = 1) Then

                        NewTextFile.WriteLine(",")

                        %>

                        <td><img src="images/spacer.gif" width="1" height="1"></td>

                        <td><img src="images/spacer.gif" width="1" height="1"></td>

                        <%

                     End If

                     isRowOpen = 0

                     %></tr><%

                  End If

               End If

            End If

            rsRMQry.MoveNext

         Wend  ' End of loop processing each package version

         set rsCQQry = nothing

         %>

         <tr>

            <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

            <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

            <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

            <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

            <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

         </tr>

      </table>

      <%

      NewTextFile.WriteLine("")

      NewTextFile.WriteLine("DEVI Details List")

      NewTextFile.WriteLine("")

      NewTextFile.WriteLine("""Issue Number"",""Property"",""Details""")

      %>

      <H5><a name="C2">DEVI Details List</a></H5>

      <table width="100%" border="0" cellspacing="0" cellpadding="1">

         <tr>

            <td width="10%" nowrap class="body_colb">Issue Number&nbsp;&nbsp;&nbsp;</td>

            <td width="20%" nowrap class="body_colb">Property&nbsp;&nbsp;&nbsp;</td>

            <td width="70%" nowrap class="body_colb">Details&nbsp;&nbsp;&nbsp;</td>

         </tr>

         <tr>

            <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

            <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

            <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

         </tr>

         <%

         For i = 0 To (dict_Iss_Id_to_Iss_Num.Count - 1)

            cqIssId = sdKey(dict_Iss_Id_to_Iss_Num, i)

            NumIssuesListed = NumIssuesListed + 1

            %>

            <tr>

               <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

               <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

               <td background="images/bg_rep_line.gif"><img src="images/spacer.gif" width="1" height="1"></td>

            </tr>

            <%

            '-------------------------------------------------------------------------------------------------------------------------------

            ' First line is the DEVI Number, and its summary info

            s = sdItem(dict_Iss_Id_to_Summary,i)   ' Prepare for CSV

            s = Replace(s,"""","""""")

            NewTextFile.WriteLine(DoubleQuotes(sdItem(dict_Iss_Id_to_Iss_Num,i)) & ",Issue Summary," & DoubleQuotes(s))

            s = sdItem(dict_Iss_Id_to_Summary,i)   ' Prepare for HTML

            s = NewLine_To_BR(To_HTML(s))

            %>

            <tr>

            <td valign="top"><a name="<%=cqIssId%>" class="txt_linked" onclick="MM_openBrWindow('_wform_issues_details.asp?iss_db=<%=sdItem(dict_Iss_Id_to_Iss_DB,i)%>&iss_id=<%=sdKey(dict_Iss_Id_to_Iss_Num,i)%>','IssueDetails','resizeable=yes,width=580,height=500')" href="javascript:;"><%=sdItem(dict_Iss_Id_to_Iss_Num,i)%></a></td>

            <td valign="top">Issue Summary:</td>

            <td valign="top"><%=s%></td>

            </tr><%

            '-------------------------------------------------------------------------------------------------------------------------------

            ' Next line is the DEVI Type Value (ie Defect, Future Enhancement, etc)

            NewTextFile.WriteLine(",Type," & DoubleQuotes(sdItem(dict_Iss_Id_to_Iss_Type,i)))

            %>

            <tr>

            <td valign="top"><img src="images/spacer.gif" width="1" height="1"></td>

            <td valign="top">Type:</td>

            <td valign="top"><%=sdItem(dict_Iss_Id_to_Iss_Type, i)%></td>

            </tr>

            <%

            '-------------------------------------------------------------------------------------------------------------------------------

            ' Next line is the DEVI Status Value

            NewTextFile.WriteLine(",Status," & DoubleQuotes(sdItem(dict_Iss_Id_to_Iss_Status,i)))

            %>

            <tr>

            <td valign="top"><img src="images/spacer.gif" width="1" height="1"></td>

            <td valign="top">Status:</td>

            <td valign="top"><%=sdItem(dict_Iss_Id_to_Iss_Status, i)%></td>

            </tr>

            <%

            '-------------------------------------------------------------------------------------------------------------------------------

            ' Next line is the DEVI Risk Value

            NewTextFile.WriteLine(",Risk," & DoubleQuotes(sdItem(dict_Iss_Id_to_Risk,i)))

            %>

            <tr>

            <td valign="top"><img src="images/spacer.gif" width="1" height="1"></td>

            <td valign="top">Risk:</td>

            <td valign="top"><%=sdItem(dict_Iss_Id_to_Risk, i)%></td>

            </tr>

            <%

            '-------------------------------------------------------------------------------------------------------------------------------

            ' Next line is the DEVI's code review reference

            a = dict_Iss_Id_to_CodeRev.Items  ' Get collection into an array

            s = a(i)                          ' Get array element into a string

            s = Replace(s, chr(13), "+")      ' Replace possible delimiters with a single delimiter ("+")

            s = Replace(s, chr(10), "+")

            s = Replace(s, " ", "+")

            crRefArr = Split(s,"+")           ' Split on our contrived delimiter and iterate through results

            NewTextFile.Write(",Code Review Ref,""")

            %>

            <tr>

            <td valign="top"><img src="images/spacer.gif" width="1" height="1"></td>

            <td valign="top">Code Review Ref:</td>

            <td valign="top">

            <%

            For j = 0 To UBOUND(crRefArr)

               if not ((crRefArr(j) = "+") or (crRefArr(j) = ",") or (Trim(crRefArr(j)) = "")) Then

                  if j = 0 Then

                     NewTextFile.Write(Trim(crRefArr(j)))

                     %>

                     <a href="<%=Trim(crRefArr(j))%>" class="txt_linked"><%=Trim(crRefArr(j))%></a>

                     <%

                  Else

                     NewTextFile.Write("," & Trim(crRefArr(j)))

                     %>

                     <a href="<%=Trim(crRefArr(j))%>" class="txt_linked"><br><%=Trim(crRefArr(j))%></a>

                     <%

                  End If

               End If

            Next

            NewTextFile.WriteLine("""")

            %>

            </td>

            </tr>

            <%

            '-------------------------------------------------------------------------------------------------------------------------------

            ' Next line is the DEVI's related DB Patches

            '  This is quite complicated but at the end of the day, we are aiming to convert the free form text in

            '  the CLEARQUEST devi into a list of hyperlinks to the actual package versions in RM, based on the assumption

            '  that the free form text contains PV_ID numbers somewhere therein.

            a = dict_Iss_Id_to_RelDBPatches.Items  ' Get collection into an array

            s = a(i)                               ' Get array element into a string

            s = Replace(s, chr(13), "+")           ' Replace possible delimiters with a single delimiter ("+")

            s = Replace(s, chr(10), "+")

            s = Replace(s, " ", "+")

            relDbPatchArr = Split(s,"+")           ' Split on our contrived delimiter and iterate through results

            NewTextFile.Write(",Related DB Patches,""")

            %>

            <tr>

            <td valign="top"><img src="images/spacer.gif" width="1" height="1"></td>

            <td valign="top">Related DB Patches:</td>

            <td valign="top">

            <%

            For j = 0 To UBOUND(relDbPatchArr)

               if not ((relDbPatchArr(j) = "+") or (relDbPatchArr(j) = ",") or (Trim(relDbPatchArr(j)) = "")) Then

                  ' Given that the Related DB Patches is a free form text field in a CLEARQUEST DEVI,

                  ' it can contain a variety of text. Normally it contains a list of PV_ID's but it

                  ' can also contain the patch file names (eg. orahops.467229_patch.xml) which normally

                  ' contains PV_IDs embedded within them. We have to cater for both approaches and

                  ' somehow extract those PV_IDs. We have already split the string so we know we are

                  ' now dealing with a single item, but sometimes users name their packages or files with

                  ' numbers as well as letters. The code below looks for the longest numeric sequence

                  ' and assumes that is the PV_ID

                  Dim lenMax,lenThis,objMatch

                  lenMax  = 0