Subversion Repositories DevTools

'=============================================================================================================================

' MAKING A BULK REJECT from a list of PV_IDs for a specified release

'

' This section contains the new "Bulk Reject' code. This function is tied to the use of the make bulk reject button.

'

'=============================================================================================================================

'-----------------------------------------------------------------------------------------------------------------------------

' This public function is called from the make_bulk_reject.asp file, loaded when a user presses the Make Bulk Reject

' button when viewing items on the Pending Tab of a release area.

'

' The function processes a list of PV_ID's that cam from the pending tab of a release, formed from each item whose checkbox

' was checked. There are 3 different types of item to deal with:

'    1) Subtractive merge operations

'    2) Additive merge operations

'    3) Manual/Auto build items

'

'

' Parameters:

'   NNrtag_id       The release area

'   NN_pv_id_list   A list of PV_IDs representing pending items to be approved for release or merge.

'

Sub PUBLIC_MakeBulkReject (NNrtag_id, NN_pv_id_list)

   Dim initialList         ' holds all items

   Dim pvId

   Dim allowedToApproveMerge

   Dim errorSeen

   ' Init

   errorSeen = 0

   ' determine in advance if user is allowed to approve merges

   allowedToApproveMerge = PRIVATE_Is_Allowed_To_Approve_Merge(NNrtag_id)

   If allowedToApproveMerge Then

    ' Remove any spaces and split the pv_id list into a string array

    initialList = Split ( Replace(NN_pv_id_list, " ", "" ), "," )

    For Each pvId In initialList

        Call PRIVATE_MakeReject(NNrtag_id,pvId, errorSeen)

    Next

      If errorSeen <> 0 Then

        Call RaiseMsg( enum_MSG_ERROR & "?rtag_id="& request("rtag_id") & "&pv_id="& request("pv_id"), _ 

            "An error was encounted rejecting one or more of the packages.<p>Packages that have not been rejected are in the 'Pending' state." )

      End If

   Else

      Call RaiseMsg( enum_MSG_ERROR & "?rtag_id="& request("rtag_id") & "&pv_id="& request("pv_id"), _ 

            "You do not appear to have permissions to perform the Bulk Reject operation" )

   End If

End Sub

'-----------------------------------------------------------------------------------------------------------------------------

' This public function is called from the make_bulk_reject.asp file, loaded when a user presses the Make Bulk Reject

'   Private function to reject a package-version

Sub PRIVATE_MakeReject(NNrtag_id,NNpvId, ByRef NNerrorSeen)

       objEH.TryORA ( OraSession )

   On Error Resume Next

   OraDatabase.Parameters.Add "PV_ID",   NNpvId,                  ORAPARM_INPUT, ORATYPE_NUMBER

   OraDatabase.Parameters.Add "RTAG_ID", NNrtag_id,               ORAPARM_INPUT, ORATYPE_NUMBER

   OraDatabase.Parameters.Add "USER_ID", objAccessControl.UserId, ORAPARM_INPUT, ORATYPE_NUMBER

   OraDatabase.ExecuteSQL _

   "BEGIN "&_

   " PK_ENVIRONMENT.MAKE_REJECT ( :PV_ID, :RTAG_ID, :USER_ID ); "&_

   "END; "

   objEH.CatchORA ( OraSession )

   OraDatabase.Parameters.Remove "PV_ID"

   OraDatabase.Parameters.Remove "RTAG_ID"

   OraDatabase.Parameters.Remove "USER_ID"

End Sub 

'-----------------------------------------------------------------------------------------------------------------------------