Subversion Repositories DevTools

#

#   Pinched from ActiveState v5.8.8 , Binary build 822 [280952]

#   For the same reason as the other POD:: bits

#       Fix bugs

#       Ensure that they are fixed independently of the Perl Pelease

#

#   In this module

#       * Remove AvtiveState mailto:

#

package Pod::Html;

use strict;

require Exporter;

use vars qw($VERSION @ISA @EXPORT @EXPORT_OK);

$VERSION = "1.0801";

@ISA = qw(Exporter);

@EXPORT = qw(pod2html htmlify);

@EXPORT_OK = qw(anchorify);

use Carp;

use Config;

use Cwd;

use File::Spec;

use File::Spec::Unix;

use Getopt::Long;

use locale;     # make \w work right in non-ASCII lands

=head1 NAME

Pod::Html - module to convert pod files to HTML

=head1 SYNOPSIS

    use Pod::Html;

    pod2html([options]);

=head1 DESCRIPTION

Converts files from pod format (see L<perlpod>) to HTML format.  It

can automatically generate indexes and cross-references, and it keeps

a cache of things it knows how to cross-reference.

=head1 FUNCTIONS

=head2 pod2html

    pod2html("pod2html",

             "--podpath=lib:ext:pod:vms",

             "--podroot=/usr/src/perl",

             "--htmlroot=/perl/nmanual",

             "--libpods=perlfunc:perlguts:perlvar:perlrun:perlop",

             "--recurse",

             "--infile=foo.pod",

             "--outfile=/perl/nmanual/foo.html");

pod2html takes the following arguments:

=over 4

=item backlink

    --backlink="Back to Top"

Adds "Back to Top" links in front of every C<head1> heading (except for

the first).  By default, no backlinks are generated.

=item cachedir

    --cachedir=name

Creates the item and directory caches in the given directory.

=item css

    --css=stylesheet

Specify the URL of a cascading style sheet.  Also disables all HTML/CSS

C<style> attributes that are output by default (to avoid conflicts).

=item flush

    --flush

Flushes the item and directory caches.

=item header

    --header

    --noheader

Creates header and footer blocks containing the text of the C<NAME>

section.  By default, no headers are generated.

=item help

    --help

Displays the usage message.

=item hiddendirs

    --hiddendirs

    --nohiddendirs

Include hidden directories in the search for POD's in podpath if recurse

is set.

The default is not to traverse any directory whose name begins with C<.>.

See L</"podpath"> and L</"recurse">.

[This option is for backward compatibility only.

It's hard to imagine that one would usefully create a module with a

name component beginning with C<.>.]

=item htmldir

    --htmldir=name

Sets the directory in which the resulting HTML file is placed.  This

is used to generate relative links to other files. Not passing this

causes all links to be absolute, since this is the value that tells

Pod::Html the root of the documentation tree.

=item htmlroot

    --htmlroot=name

Sets the base URL for the HTML files.  When cross-references are made,

the HTML root is prepended to the URL.

=item index

    --index

    --noindex

Generate an index at the top of the HTML file.  This is the default

behaviour.

=item infile

    --infile=name

Specify the pod file to convert.  Input is taken from STDIN if no

infile is specified.

=item libpods

    --libpods=name:...:name

List of page names (eg, "perlfunc") which contain linkable C<=item>s.

=item netscape

    --netscape

    --nonetscape

B<Deprecated>, has no effect. For backwards compatibility only.

=item outfile

    --outfile=name

Specify the HTML file to create.  Output goes to STDOUT if no outfile

is specified.

=item podpath

    --podpath=name:...:name

Specify which subdirectories of the podroot contain pod files whose

HTML converted forms can be linked to in cross references.

=item podroot

    --podroot=name

Specify the base directory for finding library pods.

=item quiet

    --quiet

    --noquiet

Don't display I<mostly harmless> warning messages.  These messages

will be displayed by default.  But this is not the same as C<verbose>

mode.

=item recurse

    --recurse

    --norecurse

Recurse into subdirectories specified in podpath (default behaviour).

=item title

    --title=title

Specify the title of the resulting HTML file.

=item verbose

    --verbose

    --noverbose

Display progress messages.  By default, they won't be displayed.

=back

=head2 htmlify

    htmlify($heading);

Converts a pod section specification to a suitable section specification

for HTML. Note that we keep spaces and special characters except 

C<", ?> (Netscape problem) and the hyphen (writer's problem...).

=head2 anchorify

    anchorify(@heading);

Similar to C<htmlify()>, but turns non-alphanumerics into underscores.  Note

that C<anchorify()> is not exported by default.

=head1 ENVIRONMENT

Uses C<$Config{pod2html}> to setup default options.

=head1 AUTHOR

Tom Christiansen, E<lt>tchrist@perl.comE<gt>.

=head1 SEE ALSO

L<perlpod>

=head1 COPYRIGHT

This program is distributed under the Artistic License.

=cut

my($Cachedir);

my($Dircache, $Itemcache, $Toccache);

my @Begin_Stack;

my @Libpods;

my($Htmlroot, $Htmldir, $Htmlfile, $Htmlfileurl);

my($Podfile, @Podpath, $Podroot);

my $Css;

my $Recurse;

my $Quiet;

my $HiddenDirs;

my $Verbose;

my $Doindex;

my $Backlink;

my($Listlevel, @Listend);

my $After_Lpar;

use vars qw($Ignore);  # need to localize it later.

my(%Items_Named, @Items_Seen);

my($Title, $Header);

my $Top;

my $Paragraph;

my %Sections;

# Caches

my %Pages = ();                 # associative array used to find the location

                                #   of pages referenced by L<> links.

my %Items = ();                 # associative array used to find the location

                                #   of =item directives referenced by C<> links

my %Toc = ();                   # Hash of Table of content metadata

my %Local_Items;

my $Is83;

my $Curdir = File::Spec->curdir;

my $set_p_class;

init_globals();

sub init_globals {

    $Cachedir = ".";            # The directory to which item and directory

                                # caches will be written.

    $Dircache = "pod2htmd.tmp";

    $Itemcache = "pod2htmi.tmp";

    $Toccache = "pod2htmlt.tmp";

    @Begin_Stack = ();          # begin/end stack

    @Libpods = ();              # files to search for links from C<> directives

    $Htmlroot = "/";            # http-server base directory from which all

                                #   relative paths in $podpath stem.

    $Htmldir = "";              # The directory to which the html pages

                                # will (eventually) be written.

    $Htmlfile = "";             # write to stdout by default

    $Htmlfileurl = "" ;         # The url that other files would use to

                                # refer to this file.  This is only used

                                # to make relative urls that point to

                                # other files.

    $Podfile = "";              # read from stdin by default

    @Podpath = ();              # list of directories containing library pods.

    $Podroot = $Curdir;         # filesystem base directory from which all

                                #   relative paths in $podpath stem.

    $Css = '';                  # Cascading style sheet

    $Recurse = 1;               # recurse on subdirectories in $podpath.

    $Quiet = 0;                 # not quiet by default

    $Verbose = 0;               # not verbose by default

    $Doindex = 1;               # non-zero if we should generate an index

    $Backlink = '';             # text for "back to top" links

    $Listlevel = 0;             # current list depth

    @Listend = ();              # the text to use to end the list.

    $After_Lpar = 0;            # set to true after a par in an =item

    $Ignore = 1;                # whether or not to format text.  we don't

                                #   format text until we hit our first pod

                                #   directive.

    @Items_Seen = ();           # for multiples of the same item in perlfunc

    %Items_Named = ();

    $Header = 0;                # produce block header/footer

    $Title = '';                # title to give the pod(s)

    $Top = 1;                   # true if we are at the top of the doc.  used

                                #   to prevent the first <hr /> directive.

    $Paragraph = '';            # which paragraph we're processing (used

                                #   for error messages)

    %Sections = ();             # sections within this page

    %Local_Items = ();

    $Is83 = $^O eq 'dos';       # Is it an 8.3 filesystem?

#    $set_p_class = '';

}

#

# clean_data: global clean-up of pod data

#

sub clean_data($){

    my( $dataref ) = @_;

    for my $i ( 0..$#{$dataref} ) {

        ${$dataref}[$i] =~ s/\s+\Z//;

        ${$dataref}[$i] =~ s/^\n+(.+)/$1/;

        # have a look for all-space lines

      if( ${$dataref}[$i] =~ /^\s+$/m and $dataref->[$i] !~ /^\s/ ){

            my @chunks = split( /^\s+$/m, ${$dataref}[$i] );

            splice( @$dataref, $i, 1, @chunks );

        }

    }

}

sub pod2html {

    local(@ARGV) = @_;

    local($/);

    local $_;

    init_globals();

    $Is83 = 0 if (defined (&Dos::UseLFN) && Dos::UseLFN());

    # cache of %Pages and %Items from last time we ran pod2html

    #undef $opt_help if defined $opt_help;

    # parse the command-line parameters

    parse_command_line();

    # escape the backlink argument (same goes for title but is done later...)

    $Backlink = html_escape($Backlink) if defined $Backlink;

    # set some variables to their default values if necessary

    local *POD;

    unless (@ARGV && $ARGV[0]) {

        $Podfile  = "-" unless $Podfile;        # stdin

        open(POD, "<$Podfile")

                || die "$0: cannot open $Podfile file for input: $!\n";

    } else {

        $Podfile = $ARGV[0];  # XXX: might be more filenames

        *POD = *ARGV;

    }

    $Htmlfile = "-" unless $Htmlfile;   # stdout

    $Htmlroot = "" if $Htmlroot eq "/"; # so we don't get a //

    $Htmldir =~ s#/\z## ;               # so we don't get a //

    if (  $Htmlroot eq ''

       && defined( $Htmldir )

       && $Htmldir ne ''

       && substr( $Htmlfile, 0, length( $Htmldir ) ) eq $Htmldir

       )

    {

        # Set the 'base' url for this file, so that we can use it

        # as the location from which to calculate relative links

        # to other files. If this is '', then absolute links will

        # be used throughout.

        $Htmlfileurl= "$Htmldir/" . substr( $Htmlfile, length( $Htmldir ) + 1);

    }

    # read the pod a paragraph at a time

    warn "Scanning for sections in input file(s)\n" if $Verbose;

    $/ = "";

    my @poddata  = <POD>;

    close(POD);

    # be eol agnostic

    for (@poddata) {

        if (/\r/) {

            if (/\r\n/) {

                @poddata = map { s/\r\n/\n/g;

                                 /\n\n/ ?

                                     map { "$_\n\n" } split /\n\n/ :

                                     $_ } @poddata;

            } else {

                @poddata = map { s/\r/\n/g;

                                 /\n\n/ ?

                                     map { "$_\n\n" } split /\n\n/ :

                                     $_ } @poddata;

            }

            last;

        }

    }

    clean_data( \@poddata );

    # scan the pod for =head[1-6] directives and build an index

    my $index = scan_headings(\%Sections, @poddata);

    unless($index) {

        warn "No headings in $Podfile\n" if $Verbose;

    }

    # open the output file

    open(HTML, ">$Htmlfile")

            || die "$0: cannot open $Htmlfile file for output: $!\n";

    # put a title in the HTML file if one wasn't specified

    if ($Title eq '') {

        TITLE_SEARCH: {

            for (my $i = 0; $i < @poddata; $i++) {

                if ($poddata[$i] =~ /^=head1\s*NAME\b/m) {

                    for my $para ( @poddata[$i, $i+1] ) {

                        last TITLE_SEARCH

                            if ($Title) = $para =~ /(\S+\s+-+.*\S)/s;

                    }

                }

            }

        }

    }

    if (!$Title and $Podfile =~ /\.pod\z/) {

        # probably a split pod so take first =head[12] as title

        for (my $i = 0; $i < @poddata; $i++) {

            last if ($Title) = $poddata[$i] =~ /^=head[12]\s*(.*)/;

        }

        warn "adopted '$Title' as title for $Podfile\n"

            if $Verbose and $Title;

    }

    if ($Title) {

        $Title =~ s/\s*\(.*\)//;

    } else {

        warn "$0: no title for $Podfile.\n" unless $Quiet;

        $Podfile =~ /^(.*)(\.[^.\/]+)?\z/s;

        $Title = ($Podfile eq "-" ? 'No Title' : $1);

        warn "using $Title" if $Verbose;

    }

    $Title = html_escape($Title);

    my $csslink = '';

    my $bodystyle = ' style="background-color: white"';

    my $tdstyle = ' style="background-color: #cccccc"';

    if ($Css) {

      $csslink = qq(\n<link rel="stylesheet" href="$Css" type="text/css" />);

      $csslink =~ s,\\,/,g;

      $csslink =~ s,(/.):,$1|,;

      $bodystyle = '';

      $tdstyle = '';

    }

      my $block = $Header ? <<END_OF_BLOCK : '';

<table border="0" width="100%" cellspacing="0" cellpadding="3">

<tr><td class="block"$tdstyle valign="middle">

<big><strong><span class="block">&nbsp;$Title</span></strong></big>

</td></tr>

</table>

END_OF_BLOCK

    print HTML <<END_OF_HEAD;

<?xml version="1.0" ?>

<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">

<html xmlns="http://www.w3.org/1999/xhtml">

<head>

<title>$Title</title>$csslink

<meta http-equiv="content-type" content="text/html; charset=utf-8" />

</head>

<body$bodystyle>

$block

END_OF_HEAD

    # load/reload/validate/cache %Pages and %Items

    get_cache($Dircache, $Itemcache, $Toccache, \@Podpath, $Podroot, $Recurse);

    # scan the pod for =item directives

    scan_items( \%Local_Items, "", @poddata);

    scan_toc( \%Toc, $Podfile, @poddata);

    save_toc($Podroot);

    # put an index at the top of the file.  note, if $Doindex is 0 we

    # still generate an index, but surround it with an html comment.

    # that way some other program can extract it if desired.

    $index =~ s/--+/-/g;

    my $hr = ($Doindex and $index) ? qq(<hr name="index" />) : "";

    unless ($Doindex)

    {

        $index = qq(<!--\n$index\n-->\n);

    }

    print HTML << "END_OF_INDEX";

<!-- INDEX BEGIN -->

<div name="index"  class="index">

<p><a name=\"__index__\"></a></p>

$index

$hr

</div>

<!-- INDEX END -->

END_OF_INDEX

    # now convert this file

    my $after_item;             # set to true after an =item

    my $need_dd = 0;

    warn "Converting input file $Podfile\n" if $Verbose;

    foreach my $i (0..$#poddata){

        $_ = $poddata[$i];

        $Paragraph = $i+1;

        if (/^(=.*)/s) {        # is it a pod directive?

            $Ignore = 0;

            $after_item = 0;

            $need_dd = 0;

            $_ = $1;

            if (/^=begin\s+(\S+)\s*(.*)/si) {   # =begin

                process_begin($1, $2);

            } elsif (/^=end\s+(\S+)\s*(.*)/si) {# =end

                process_end($1, $2);

            } elsif (/^=cut/) {                 # =cut

                process_cut();

            } elsif (/^=pod/) {                 # =pod

                process_pod();

            } else {

                next if @Begin_Stack && $Begin_Stack[-1] ne 'html';

                if (/^=(head[1-6])\s+(.*\S)/s) {        # =head[1-6] heading

                    process_head( $1, $2, $Doindex && $index );

                } elsif (/^=item\s*(.*\S)?/sm) {        # =item text

                    $need_dd = process_item( $1 );

                    $after_item = 1;

                } elsif (/^=over\s*(.*)/) {             # =over N

                    process_over();

                } elsif (/^=back/) {                    # =back

                    process_back($need_dd);

                } elsif (/^=for\s+(\S+)\s*(.*)/si) {    # =for

                    process_for($1,$2);

                } else {

                    /^=(\S*)\s*/;

                    warn "$0: $Podfile: unknown pod directive '$1' in "

                       . "paragraph $Paragraph.  ignoring.\n" unless $Quiet;

                }

            }

            $Top = 0;

        }

        else {

            next if $Ignore;

            next if @Begin_Stack && $Begin_Stack[-1] ne 'html';

            print HTML and next if @Begin_Stack && $Begin_Stack[-1] eq 'html';

            print HTML "<dd>\n" if $need_dd;

            my $text = $_;

            if( $text =~ /\A\s+/ ){

                process_pre( \$text );

                print HTML "<pre>\n$text</pre>\n";

            } else {

                process_text( \$text );

                # experimental: check for a paragraph where all lines

                # have some ...\t...\t...\n pattern

                if( $text =~ /\t/ ){

                    my @lines = split( "\n", $text );

                    if( @lines > 1 ){

                        my $all = 2;

                        foreach my $line ( @lines ){

                            if( $line =~ /\S/ && $line !~ /\t/ ){

                                $all--;

                                last if $all == 0;

                            }

                        }

                        if( $all > 0 ){

                            $text =~ s/\t+/<td>/g;

                            $text =~ s/^/<tr><td>/gm;

                            $text = '<table cellspacing="0" cellpadding="0">' .

                                    $text . '</table>';

                        }

                    }

                }

                ## end of experimental

                if( $after_item ){

                    $After_Lpar = 1;

                }

        if ( $set_p_class )

        {

                print HTML "<p class=\"$set_p_class\">$text</p>\n";

            $set_p_class = 0;

        }

        else

        {

                    print HTML "<p>$text</p>\n";

        }

            }

            print HTML "</dd>\n" if $need_dd;

            $after_item = 0;

        }

    }

    # finish off any pending directives

    finish_list();

    # link to page index

    print HTML "<p><a href=\"#__index__\"><small>$Backlink</small></a></p>\n"

        if $Doindex and $index and $Backlink;

    print HTML <<END_OF_TAIL;

$block

</body>

</html>

END_OF_TAIL

    # close the html file

    close(HTML);

    warn "Finished\n" if $Verbose;

}

##############################################################################

sub usage {

    my $podfile = shift;

    warn "$0: $podfile: @_\n" if @_;

    die <<END_OF_USAGE;

Usage:  $0 --help --htmlroot=<name> --infile=<name> --outfile=<name>

           --podpath=<name>:...:<name> --podroot=<name>

           --libpods=<name>:...:<name> --recurse --verbose --index

           --netscape --norecurse --noindex --cachedir=<name>

  --backlink     - set text for "back to top" links (default: none).

  --cachedir     - directory for the item and directory cache files.

  --css          - stylesheet URL

  --flush        - flushes the item and directory caches.

  --[no]header   - produce block header/footer (default is no headers).

  --help         - prints this message.

  --hiddendirs   - search hidden directories in podpath

  --htmldir      - directory for resulting HTML files.

  --htmlroot     - http-server base directory from which all relative paths

                   in podpath stem (default is /).

  --[no]index    - generate an index at the top of the resulting html

                   (default behaviour).

  --infile       - filename for the pod to convert (input taken from stdin

                   by default).

  --libpods      - colon-separated list of pages to search for =item pod

                   directives in as targets of C<> and implicit links (empty

                   by default).  note, these are not filenames, but rather

                   page names like those that appear in L<> links.

  --outfile      - filename for the resulting html file (output sent to

                   stdout by default).

  --podpath      - colon-separated list of directories containing library

                   pods (empty by default).

  --podroot      - filesystem base directory from which all relative paths

                   in podpath stem (default is .).

  --[no]quiet    - suppress some benign warning messages (default is off).

  --[no]recurse  - recurse on those subdirectories listed in podpath

                   (default behaviour).

  --title        - title that will appear in resulting html file.

  --[no]verbose  - self-explanatory (off by default).

  --[no]netscape - deprecated, has no effect. for backwards compatibility only.

END_OF_USAGE

}

sub parse_command_line {

    my ($opt_backlink,$opt_cachedir,$opt_css,$opt_flush,$opt_header,$opt_help,

        $opt_htmldir,$opt_htmlroot,$opt_index,$opt_infile,$opt_libpods,

        $opt_netscape,$opt_outfile,$opt_podpath,$opt_podroot,$opt_quiet,

        $opt_recurse,$opt_title,$opt_verbose,$opt_hiddendirs);

    unshift @ARGV, split ' ', $Config{pod2html} if $Config{pod2html};

    my $result = GetOptions(

                            'backlink=s' => \$opt_backlink,

                            'cachedir=s' => \$opt_cachedir,

                            'css=s'      => \$opt_css,

                            'flush'      => \$opt_flush,

                            'header!'    => \$opt_header,

                            'help'       => \$opt_help,

                            'hiddendirs!'=> \$opt_hiddendirs,

                            'htmldir=s'  => \$opt_htmldir,

                            'htmlroot=s' => \$opt_htmlroot,

                            'index!'     => \$opt_index,

                            'infile=s'   => \$opt_infile,

                            'libpods=s'  => \$opt_libpods,

                            'netscape!'  => \$opt_netscape,

                            'outfile=s'  => \$opt_outfile,

                            'podpath=s'  => \$opt_podpath,

                            'podroot=s'  => \$opt_podroot,

                            'quiet!'     => \$opt_quiet,

                            'recurse!'   => \$opt_recurse,

                            'title=s'    => \$opt_title,

                            'verbose!'   => \$opt_verbose,

                           );

    usage("-", "invalid parameters") if not $result;

    usage("-") if defined $opt_help;    # see if the user asked for help

    $opt_help = "";                     # just to make -w shut-up.

    @Podpath  = map { s/\|/:/g; $_ } split(":", $opt_podpath) if defined $opt_podpath;

    @Libpods  = split(":", $opt_libpods) if defined $opt_libpods;

    $Backlink = $opt_backlink if defined $opt_backlink;

    $Cachedir = $opt_cachedir if defined $opt_cachedir;

    $Css      = $opt_css      if defined $opt_css;

    $Header   = $opt_header   if defined $opt_header;

    $Htmldir  = $opt_htmldir  if defined $opt_htmldir;

    $Htmlroot = $opt_htmlroot if defined $opt_htmlroot;

    $Doindex  = $opt_index    if defined $opt_index;

    $Podfile  = $opt_infile   if defined $opt_infile;

    $HiddenDirs = $opt_hiddendirs if defined $opt_hiddendirs;

    $Htmlfile = $opt_outfile  if defined $opt_outfile;

    $Podroot  = $opt_podroot  if defined $opt_podroot;

    $Quiet    = $opt_quiet    if defined $opt_quiet;

    $Recurse  = $opt_recurse  if defined $opt_recurse;

    $Title    = $opt_title    if defined $opt_title;

    $Verbose  = $opt_verbose  if defined $opt_verbose;

    warn "Flushing item and directory caches\n"

        if $opt_verbose && defined $opt_flush;

    $Dircache = "$Cachedir/pod2htmd.tmp";

    $Itemcache = "$Cachedir/pod2htmi.tmp";

    $Toccache = "$Cachedir/pod2htmt.tmp";

    if (defined $opt_flush) {

        1 while unlink($Dircache, $Itemcache, $Toccache);

    }

}

my $Saved_Cache_Key;

sub get_cache {

    my($dircache, $itemcache, $toccache, $podpath, $podroot, $recurse) = @_;

    my @cache_key_args = @_;

    # A first-level cache:

    # Don't bother reading the cache files if they still apply

    # and haven't changed since we last read them.

    my $this_cache_key = cache_key(@cache_key_args);

    return if $Saved_Cache_Key and $this_cache_key eq $Saved_Cache_Key;

    # load the cache of %Pages and %Items if possible.  $tests will be

    # non-zero if successful.

    my $tests = 0;

    if (-f $dircache && -f $itemcache && -f $toccache) {

        warn "scanning for item cache\n" if $Verbose;

        $tests = load_cache($dircache, $itemcache, $toccache, $podpath, $podroot);

    }

    # if we didn't succeed in loading the cache then we must (re)build

    #  %Pages and %Items.

    if (!$tests) {

        warn "scanning directories in pod-path\n" if $Verbose;

        scan_podpath($podroot, $recurse, 0);

    }

    $Saved_Cache_Key = cache_key(@cache_key_args);

}

sub cache_key {

    my($dircache, $itemcache, $toccache, $podpath, $podroot, $recurse) = @_;

    return join('!', $dircache, $itemcache, $toccache, $recurse,

        @$podpath, $podroot, stat($dircache), stat($itemcache), stat($toccache));

}

#

# load_cache - tries to find if the caches stored in $dircache and $itemcache

#  are valid caches of %Pages and %Items.  if they are valid then it loads

#  them and returns a non-zero value.

#

sub load_cache {

    my($dircache, $itemcache, $toccache, $podpath, $podroot) = @_;

    my($tests);

    local $_;

    $tests = 0;

    open(CACHE, "<$itemcache") ||

        die "$0: error opening $itemcache for reading: $!\n";

    $/ = "\n";

    # is it the same podpath?

    $_ = <CACHE>;

    chomp($_);

    $tests++ if (join(":", @$podpath) eq $_);

    # is it the same podroot?

    $_ = <CACHE>;

    chomp($_);

    $tests++ if ($podroot eq $_);

    # load the cache if its good

    if ($tests != 2) {

        close(CACHE);

        return 0;

    }

    warn "loading item cache\n" if $Verbose;

    while (<CACHE>) {

        /(.*?) (.*)$/;

        $Items{$1} = $2;

    }

    close(CACHE);

    warn "scanning for directory cache\n" if $Verbose;

    open(CACHE, "<$dircache") ||

        die "$0: error opening $dircache for reading: $!\n";

    $/ = "\n";

    $tests = 0;

    # is it the same podpath?

    $_ = <CACHE>;

    chomp($_);

    $tests++ if (join(":", @$podpath) eq $_);

    # is it the same podroot?

    $_ = <CACHE>;

    chomp($_);

    $tests++ if ($podroot eq $_);

    # load the cache if its good

    if ($tests != 2) {

        close(CACHE);

        return 0;

    }

    warn "loading directory cache\n" if $Verbose;

    while (<CACHE>) {

        /(.*?) (.*)$/;

        $Pages{$1} = $2;

    }

    close(CACHE);

    #

    #   Load Toc Cache

    #

    open(CACHE, "<$toccache") ||

        die "$0: error opening $toccache for reading: $!\n";

    $/ = "\n";

    $tests = 0;

    # is it the same podpath?

    $_ = <CACHE>;

    chomp($_);

    $tests++ if (join(":", @$podpath) eq $_);

    # is it the same podroot?

    $_ = <CACHE>;

    chomp($_);

    $tests++ if ($podroot eq $_);

    # load the cache if its good

    if ($tests != 2) {

        close(CACHE);

        return 0;

    }

    warn "loading toc cache\n" if $Verbose;

    while (<CACHE>) {

        /(.*?) (.*)$/;

        $Toc{$1} = $2;

    }

    close(CACHE);

    return 1;

}

#

# scan_podpath - scans the directories specified in @podpath for directories,

#  .pod files, and .pm files.  it also scans the pod files specified in

#  @Libpods for =item directives.

#

sub scan_podpath {

    my($podroot, $recurse, $append) = @_;

    my($pwd, $dir);

    my($libpod, $dirname, $pod, @files, @poddata);

    unless($append) {

        %Items = ();

        %Pages = ();

        %Toc = ();

    }

    # scan each directory listed in @Podpath

    $pwd = getcwd();

    chdir($podroot)

        || die "$0: error changing to directory $podroot: $!\n";

    foreach $dir (@Podpath) {

        scan_dir($dir, $recurse);

    }

    # scan the pods listed in @Libpods for =item directives

    foreach $libpod (@Libpods) {

        # if the page isn't defined then we won't know where to find it

        # on the system.

        next unless defined $Pages{$libpod} && $Pages{$libpod};

        # if there is a directory then use the .pod and .pm files within it.

        # NOTE: Only finds the first so-named directory in the tree.

#       if ($Pages{$libpod} =~ /([^:]*[^(\.pod|\.pm)]):/) {

        if ($Pages{$libpod} =~ /([^:]*(?<!\.pod)(?<!\.pm)(?<!\.pl)):/) {

            #  find all the .pod and .pm files within the directory

            $dirname = $1;

            opendir(DIR, $dirname) ||

                die "$0: scan_podpath:error opening directory $dirname: $!\n";

            @files = grep(/(\.pod|\.pm)\z/ && ! -d $_, readdir(DIR));

            closedir(DIR);

            # scan each .pod and .pm file for =item directives

            foreach $pod (@files) {

                open(POD, "<$dirname/$pod") ||

                    die "$0: error opening(pod) $dirname/$pod for input: $!\n";

                @poddata = <POD>;

                close(POD);

                clean_data( \@poddata );

                scan_items( \%Items, "$dirname/$pod", @poddata);

            }

            # use the names of files as =item directives too.

### Don't think this should be done this way - confuses issues.(WL)

###         foreach $pod (@files) {

###             $pod =~ /^(.*)(\.pod|\.pm)$/;

###             $Items{$1} = "$dirname/$1.html" if $1;

###         }

        } elsif ($Pages{$libpod} =~ /([^:]*\.pod):/ ||

                 $Pages{$libpod} =~ /([^:]*\.p[ml]):/) {

            # scan the .pod or .pm file for =item directives

            $pod = $1;

            open(POD, "<$pod") ||

                die "$0: error opening(pod1) $pod for input: $!\n";

            @poddata = <POD>;

            close(POD);

            clean_data( \@poddata );

            scan_items( \%Items, "$pod", @poddata);

        } else {

            warn "$0: shouldn't be here (line ".__LINE__."\n" unless $Quiet;

        }

    }

    @poddata = ();      # clean-up a bit

    #

    #   Scan all POD for TOC metadata

    #

    foreach my $libpod ( keys %Pages )

    {

        if ($Pages{$libpod} =~ /([^:]*\.pod):/ ||

                 $Pages{$libpod} =~ /([^:]*\.p[ml]):/) {

            # scan the .pod or .pm file for =for directives

            $pod = $1;

            next if ($pod =~ m~\.keep\.pod~);

            open(POD, "<$pod") ||

                die "$0: error opening(pod2) $pod for input: $!\n";

            @poddata = <POD>;

            close(POD);

            clean_data( \@poddata );

            scan_toc( \%Toc, "$pod", @poddata);

        }

    }

    @poddata = ();      # clean-up a bit

    chdir($pwd)

        || die "$0: error changing to directory $pwd: $!\n";

    # cache the item list for later use

    warn "caching items for later use\n" if $Verbose;

    open(CACHE, ">$Itemcache") ||

        die "$0: error open $Itemcache for writing: $!\n";

    print CACHE join(":", @Podpath) . "\n$podroot\n";

    foreach my $key (keys %Items) {

        print CACHE "$key $Items{$key}\n";

    }

    close(CACHE);