Subversion Repositories DevTools

package HTML::Table;

use strict;

use warnings;

use vars qw($VERSION $AUTOLOAD);

$VERSION = '2.08a';

use overload	'""'	=>	\&getTable,

				fallback => undef;

=head1 NAME

HTML::Table - produces HTML tables

=head1 SYNOPSIS

  use HTML::Table;

  $table1 = new HTML::Table($rows, $cols);

    or

  $table1 = new HTML::Table(-rows=>26,

                            -cols=>2,

                            -align=>'center',

                            -rules=>'rows',

                            -border=>0,

                            -bgcolor=>'blue',

                            -width=>'50%',

                            -spacing=>0,

                            -padding=>0,

                            -style=>'color: blue',

                            -class=>'myclass',

                            -evenrowclass=>'even',

                            -oddrowclass=>'odd',

                            -head=> ['head1', 'head2'],

                            -data=> [ ['1:1', '1:2'], ['2:1', '2:2'] ] );

   or

  $table1 = new HTML::Table( [ ['1:1', '1:2'], ['2:1', '2:2'] ] );

  $table1->setCell($cellrow, $cellcol, 'This is Cell 1');

  $table1->setCellBGColor('blue');

  $table1->setCellColSpan(1, 1, 2);

  $table1->setRowHead(1);

  $table1->setColHead(1);

  $table1->print;

  $table2 = new HTML::Table;

  $table2->addRow(@cell_values);

  $table2->addCol(@cell_values2);

  $table1->setCell(1,1, "$table2->getTable");

  $table1->print;

=head1 REQUIRES

Perl5.002

=head1 EXPORTS

Nothing

=head1 DESCRIPTION

HTML::Table is used to generate HTML tables for

CGI scripts.  By using the methods provided fairly

complex tables can be created, manipulated, then printed

from Perl scripts.  The module also greatly simplifies

creating tables within tables from Perl.  It is possible

to create an entire table using the methods provided and

never use an HTML tag.

HTML::Table also allows for creating dynamically sized

tables via its addRow and addCol methods.  These methods

automatically resize the table if passed more cell values

than will fit in the current table grid.

Methods are provided for nearly all valid table, row, and

cell tags specified for HTML 3.0.

A Japanese translation of the documentation is available at:

	http://member.nifty.ne.jp/hippo2000/perltips/html/table.htm

=head1 METHODS

  [] indicate optional parameters. default value will

     be used if no value is specified

  row_num indicates that a row number is required.  

  	Rows are numbered from 1.  To refer to the last row use the value -1.

  col_num indicates that a col number is required.  

  	Cols are numbered from 1.  To refer to the last col use the value -1.

=head2 Sections

=over 4

From version 2.07 onwards HTML::Table supports table sections (THEAD, TFOOT & TBODY).

Each section can have its own attributes (id, class, etc) set, and will contain 1 or more 

rows.  Section numbering starts at 0, only tbody is allowed to have more than one section.

Methods for manipultaing sections and their data are available and have the general form:

  setSectionCell ( section, section_num, row_num, col_num, data );

  For example, the following adds a row to the first body section:

  addSectionRow ( 'tbody', 0, "Cell 1", "Cell 2", "Cell 3" );

For backwards compatibility, methods with Section in their name will default to manipulating 

the first body section.  

  For example, the following sets the class for the first row in the 

  first body section:

  setRowClass ( 1, 'row_class' );

  Which is semantically equivalent to:

  setSectionRowClass ( 'tbody', 0, 1, 'row_class' );

=back

=head2 Creation

=over 4

=item new HTML::Table([num_rows, num_cols])

Creates a new HTML table object.  If rows and columns

are specified, the table will be initialized to that

size.  Row and Column numbers start at 1,1.  0,0 is

considered an empty table.

=item new HTML::Table([-rows=>num_rows, 

		 -cols=>num_cols, 

		 -border=>border_width,

		 -align=>table_alignment,

		 -style=>table_style,

 		 -class=>table_class,

 		 -evenrowclass=>'even',

         -oddrowclass=>'odd',

		 -bgcolor=>back_colour, 

		 -width=>table_width, 

		 -spacing=>cell_spacing, 

		 -padding=>cell_padding])

Creates a new HTML table object.  If rows and columns

are specified, the table will be initialized to that

size.  Row and Column numbers start at 1,1.  0,0 is

considered an empty table.

If evenrowclass or oddrowclass is specified, these 

classes will be applied to even and odd rows,

respectively, unless those rows have a specific class 

applied to it.

=back

=head2 Table Level Methods

=over 4

=item setBorder([pixels])

Sets the table Border Width

=item setWidth([pixels|percentofscreen])

Sets the table width

 	$table->setWidth(500);

  or

 	$table->setWidth('100%');

=item setCellSpacing([pixels])

=item setCellPadding([pixels])

=item setCaption("CaptionText" [, top|bottom])

=item setBGColor([colorname|colortriplet])

=item autoGrow([1|true|on|anything|0|false|off|no|disable])

Switches on (default) or off automatic growing of the table

if row or column values passed to setCell exceed current

table size.

=item setAlign ( [ left , center , right ] ) 

=item setRules ( [ rows , cols , all, both , groups  ] ) 

=item setStyle ( 'css style' ) 

Sets the table style attribute.

=item setClass ( 'css class' ) 

Sets the table class attribute.

=item setEvenRowClass ( 'css class' )

Sets the class attribute of even rows in the table.

=item setOddRowClass ( 'css class' )

Sets the class attribute of odd rows in the table.

=item setAttr ( 'user attribute' ) 

Sets a user defined attribute for the table.  Useful for when

HTML::Table hasn't implemented a particular attribute yet

=item sort ( [sort_col_num, sort_type, sort_order, num_rows_to_skip] )

        or 

  sort( -sort_col => sort_col_num, 

        -sort_type => sort_type,

        -sort_order => sort_order,

        -skip_rows => num_rows_to_skip,

        -strip_html => strip_html,

        -strip_non_numeric => strip_non_numeric,

        -presort_func => \&filter_func )

    sort_type in { ALPHA | NUMERIC }, 

    sort_order in { ASC | DESC },

    strip_html in { 0 | 1 }, defaults to 1,

    strip_non_numeric in { 0 | 1 }, defaults to 1

  Sort all rows on a given column (optionally skipping table header rows

  by specifiying num_rows_to_skip).

  By default sorting ignores HTML Tags and &nbsp, setting the strip_html parameter to 0 

  disables this behaviour.

  By default numeric Sorting ignores non numeric chararacters, setting the strip_non_numeric

  parameter to 0 disables this behaviour.

  You can provide your own pre-sort function, useful for pre-processing the cell contents 

  before sorting for example dates.

=item getTableRows

Returns the number of rows in the table.

=item getTableCols

Returns the number of columns in the table.

=item getStyle

Returns the table's style attribute.

=back

=head2 Section Level Methods

=over 4

=item setSectionId ( [tbody|thead|tfoot], section_num, 'id' )

Sets the id attribute for the section.

=item setSectionClass ( [tbody|thead|tfoot], section_num, 'class' )

Sets the class attribute for the section.

=item setSectionStyle ( [tbody|thead|tfoot], section_num, 'style' )

Sets the style attribute for the section.

=item setSectionAlign ( [tbody|thead|tfoot], section_num, [center|right|left] )

Sets the horizontal alignment for the section.

=item setSectionValign ( [tbody|thead|tfoot], section_num, [center|top|bottom|middle|baseline] )

Sets the vertical alignment for the section.

=item setSectionAttr ( [tbody|thead|tfoot], section_num, 'user attribute' )

Sets a user defined attribute for the cell.  Useful for when

HTML::Table hasn't implemented a particular attribute yet

=back

=head2 Cell Level Methods

=over 4

=item setCell(row_num, col_num, "content")

Sets the content of a table cell.  This could be any

string, even another table object via the getTable method.

If the row and/or column numbers are outside the existing table

boundaries extra rows and/or columns are created automatically.

=item setSectionCell([tbody|thead|tfoot], section_num, row_num, col_num, "content")

Same as setCell, but able to specify which section to act on.

=item setCellAlign(row_num, col_num, [center|right|left])

Sets the horizontal alignment for the cell.

=item setSectionCellAlign([tbody|thead|tfoot], section_num, row_num, col_num, [center|right|left])

Same as setCellAlign, but able to specify which section to act on.

=item setCellVAlign(row_num, col_num, [center|top|bottom|middle|baseline])

Sets the vertical alignment for the cell.

=item setSectionCellVAlign([tbody|thead|tfoot], section_num, row_num, col_num, [center|top|bottom|middle|baseline])

Same as setCellVAlign, but able to specify which section to act on.

=item setCellWidth(row_num, col_num, [pixels|percentoftable])

Sets the width of the cell.

=item setSectionCellWidth([tbody|thead|tfoot], section_num, row_num, col_num, [pixels|percentoftable])

Same as setCellWidth, but able to specify which section to act on.

=item setCellHeight(row_num, col_num, [pixels])

Sets the height of the cell.

=item setSectionCellHeight([tbody|thead|tfoot], section_num, row_num, col_num, [pixels])

Same as setCellHeight, but able to specify which section to act on.

=item setCellHead(row_num, col_num, [0|1])

Sets cell to be of type head (Ie <th></th>)

=item setSectionCellHead([tbody|thead|tfoot], section_num, row_num, col_num, [0|1])

Same as setCellHead, but able to specify which section to act on.

=item setCellNoWrap(row_num, col_num, [0|1])

Sets the NoWrap attribute of the cell.

=item setSectionCellNoWrap([tbody|thead|tfoot], section_num, row_num, col_num, [0|1])

Same as setCellNoWrap, but able to specify which section to act on.

=item setCellBGColor(row_num, col_num, [colorname|colortriplet])

Sets the background colour for the cell.

=item setSectionCellBGColor([tbody|thead|tfoot], section_num, row_num, col_num, [colorname|colortriplet])

Same as setCellBGColor, but able to specify which section to act on.

=item setCellRowSpan(row_num, col_num, num_cells)

Causes the cell to overlap a number of cells below it.

If the overlap number is greater than number of cells 

below the cell, a false value will be returned.

=item setSectionCellRowSpan([tbody|thead|tfoot], section_num, row_num, col_num, num_cells)

Same as setCellRowSpan, but able to specify which section to act on.

=item setCellColSpan(row_num, col_num, num_cells)

Causes the cell to overlap a number of cells to the right.

If the overlap number is greater than number of cells to

the right of the cell, a false value will be returned.

=item setSectionCellColSpan([tbody|thead|tfoot], section_num, row_num, col_num, num_cells)

Same as setCellColSpan, but able to specify which section to act on.

=item setCellSpan(row_num, col_num, num_rows, num_cols)

Joins the block of cells with the starting cell specified.

The joined area will be num_cols wide and num_rows deep.

=item setSectionCellSpan([tbody|thead|tfoot], section_num, row_num, col_num, num_rows, num_cols)

Same as setCellSpan, but able to specify which section to act on.

=item setCellFormat(row_num, col_num, start_string, end_string)

Start_string should be a string of valid HTML, which is output before

the cell contents, end_string is valid HTML that is output after the cell contents.

This enables formatting to be applied to the cell contents.

	$table->setCellFormat(1, 2, '<b>', '</b>');

=item setSectionCellFormat([tbody|thead|tfoot], section_num, row_num, col_num, start_string, end_string)

Same as setCellFormat, but able to specify which section to act on.

=item setCellStyle (row_num, col_num, 'css style') 

Sets the cell style attribute.

=item setSectionCellStyle([tbody|thead|tfoot], section_num, row_num, col_num, 'css style')

Same as setCellStyle, but able to specify which section to act on.

=item setCellClass (row_num, col_num, 'css class') 

Sets the cell class attribute.

=item setSectionCellClass([tbody|thead|tfoot], section_num, row_num, col_num, 'css class')

Same as setCellClass, but able to specify which section to act on.

=item setCellAttr (row_num, col_num, 'user attribute') 

Sets a user defined attribute for the cell.  Useful for when

HTML::Table hasn't implemented a particular attribute yet

=item setSectionCellAttr([tbody|thead|tfoot], section_num, row_num, col_num, 'css class')

Same as setCellAttr, but able to specify which section to act on.

=item setLastCell*

All of the setCell methods have a corresponding setLastCell method which 

does not accept the row_num and col_num parameters, but automatically applies

to the last row and last col of the table.

NB.  Only works on the setCell* methods, not on the setSectionCell* methods.

=item getCell(row_num, col_num)

Returns the contents of the specified cell as a string.

=item getSectionCell([tbody|thead|tfoot], section_num, row_num, col_num)

Same as getCell, but able to specify which section to act on.

=item getCellStyle(row_num, col_num)

Returns cell's style attribute.

=item getSectionCellStyle([tbody|thead|tfoot], section_num, row_num, col_num)

Same as getCellStyle, but able to specify which section to act on.

=back

=head2 Column Level Methods

=over 4

=item addCol("cell 1 content" [, "cell 2 content",  ...])

Adds a column to the right end of the table.  Assumes if

you pass more values than there are rows that you want

to increase the number of rows.

=item addSectionCol([tbody|thead|tfoot], section_num, "cell 1 content" [, "cell 2 content",  ...])

Same as addCol, but able to specify which section to act on.

=item setColAlign(col_num, [center|right|left])

Applies setCellAlign over the entire column.

=item setSectionColAlign([tbody|thead|tfoot], section_num, col_num, [center|right|left])

Same as setColAlign, but able to specify which section to act on.

=item setColVAlign(col_num, [center|top|bottom|middle|baseline])

Applies setCellVAlign over the entire column.

=item setSectionColVAlign([tbody|thead|tfoot], section_num, col_num, [center|top|bottom|middle|baseline])

Same as setColVAlign, but able to specify which section to act on.

=item setColWidth(col_num, [pixels|percentoftable])

Applies setCellWidth over the entire column.

=item setSectionColWidth([tbody|thead|tfoot], section_num, col_num, [pixels|percentoftable])

Same as setColWidth, but able to specify which section to act on.

=item setColHeight(col_num, [pixels])

Applies setCellHeight over the entire column.

=item setSectionColHeight([tbody|thead|tfoot], section_num, col_num, [pixels])

Same as setColHeight, but able to specify which section to act on.

=item setColHead(col_num, [0|1])

Applies setCellHead over the entire column.

=item setSectionColHead([tbody|thead|tfoot], section_num, col_num, [0|1])

Same as setColHead, but able to specify which section to act on.

=item setColNoWrap(col_num, [0|1])

Applies setCellNoWrap over the entire column.

=item setSectionColNoWrap([tbody|thead|tfoot], section_num, col_num, [0|1])

Same as setColNoWrap, but able to specify which section to act on.

=item setColBGColor(row_num, [colorname|colortriplet])

Applies setCellBGColor over the entire column.

=item setSectionColBGColor([tbody|thead|tfoot], section_num, col_num, [colorname|colortriplet])

Same as setColBGColor, but able to specify which section to act on.

=item setColFormat(col_num, start_string, end_sting)

Applies setCellFormat over the entire column.

=item setSectionColFormat([tbody|thead|tfoot], section_num, col_num, start_string, end_sting)

Same as setColFormat, but able to specify which section to act on.

=item setColStyle (col_num, 'css style') 

Applies setCellStyle over the entire column.

=item setSectionColStyle([tbody|thead|tfoot], section_num, col_num, 'css style')

Same as setColStyle, but able to specify which section to act on.

=item setColClass (col_num, 'css class') 

Applies setCellClass over the entire column.

=item setSectionColClass([tbody|thead|tfoot], section_num, col_num, 'css class')

Same as setColClass, but able to specify which section to act on.

=item setColAttr (col_num, 'user attribute') 

Applies setCellAttr over the entire column.

=item setSectionColAttr([tbody|thead|tfoot], section_num, col_num, 'user attribute')

Same as setColAttr, but able to specify which section to act on.

=item setLastCol*

All of the setCol methods have a corresponding setLastCol method which 

does not accept the col_num parameter, but automatically applies

to the last col of the table.

NB.  Only works on the setCol* methods, not on the setSectionCol* methods.

=item getColStyle(col_num)

Returns column's style attribute.  Only really useful after setting a column's style via setColStyle().

=item getSectionColStyle([tbody|thead|tfoot], section_num, col_num)

Same as getColStyle, but able to specify which section to act on.

=back

=head2 Row Level Methods

=over 4

=item addRow("cell 1 content" [, "cell 2 content",  ...])

Adds a row to the bottom of the first body section of the table.  

Adds a row to the bottom of the table.  Assumes if you

pass more values than there are columns that you want

to increase the number of columns.

=item addSectionRow([tbody|thead|tfoot], section_num, "cell 1 content" [, "cell 2 content",  ...])

Same as addRow, but able to specify which section to act on.

=item delRow(row_num)

Deletes a row from the first body section of the table.  If -1 is passed as row_num, the 

last row in the section will be deleted.

=item delSectionRow([tbody|thead|tfoot], section_num, row_num)

Same as delRow, but able to specify which section to act on.

=item setRowAlign(row_num, [center|right|left])

Sets the Align attribute of the row.

=item setSectionRowAlign([tbody|thead|tfoot], section_num, row_num, [center|right|left])

Same as setRowAlign, but able to specify which section to act on.

=item setRowVAlign(row_num, [center|top|bottom|middle|baseline])

Sets the VAlign attribute of the row.

=item setSectionRowVAlign([tbody|thead|tfoot], section_num, row_num, [center|top|bottom|middle|baseline])

Same as setRowVAlign, but able to specify which section to act on.

=item setRowNoWrap(col_num, [0|1])

Sets the NoWrap attribute of the row.

=item setSectionRowNoWrap([tbody|thead|tfoot], section_num, row_num, [0|1])

Same as setRowNoWrap, but able to specify which section to act on.

=item setRowBGColor(row_num, [colorname|colortriplet])

Sets the BGColor attribute of the row.

=item setSectionRowBGColor([tbody|thead|tfoot], section_num, row_num, [colorname|colortriplet])

Same as setRowBGColor, but able to specify which section to act on.

=item setRowStyle (row_num, 'css style') 

Sets the Style attribute of the row.

=item setSectionRowStyle([tbody|thead|tfoot], section_num, row_num, 'css style')

Same as setRowStyle, but able to specify which section to act on.

=item setRowClass (row_num, 'css class') 

Sets the Class attribute of the row.

=item setSectionRowClass([tbody|thead|tfoot], section_num, row_num, 'css class')

Same as setRowClass, but able to specify which section to act on.

=item setRowAttr (row_num, 'user attribute') 

Sets the Attr attribute of the row.

=item setSectionRowAttr([tbody|thead|tfoot], section_num, row_num, 'user attribute')

Same as setRowAttr, but able to specify which section to act on.

=item setRCellsWidth(row_num, [pixels|percentoftable])

=item setRowWidth(row_num, [pixels|percentoftable])  ** Deprecated **

Applies setCellWidth over the entire row.

=item setSectionRCellsWidth([tbody|thead|tfoot], section_num, row_num, [pixels|percentoftable])

=item setSectionRowWidth([tbody|thead|tfoot], section_num, row_num, [pixels|percentoftable])   ** Deprecated **

Same as setRowWidth, but able to specify which section to act on.

=item setRCellsHeight(row_num, [pixels])

=item setRowHeight(row_num, [pixels])   ** Deprecated **

Applies setCellHeight over the entire row.

=item setSectionRCellsHeight([tbody|thead|tfoot], section_num, row_num, [pixels])

=item setSectionRowHeight([tbody|thead|tfoot], section_num, row_num, [pixels])  ** Deprecated **

Same as setRowHeight, but able to specify which section to act on.

=item setRCellsHead(row_num, [0|1])

=item setRowHead(row_num, [0|1])  ** Deprecated **

Applies setCellHead over the entire row.

=item setSectionRCellsHead([tbody|thead|tfoot], section_num, row_num, [0|1])

=item setSectionRowHead([tbody|thead|tfoot], section_num, row_num, [0|1])  ** Deprecated **

Same as setRowHead, but able to specify which section to act on.

=item setRCellsFormat(row_num, start_string, end_string)

=item setRowFormat(row_num, start_string, end_string)  ** Deprecated **

Applies setCellFormat over the entire row.

=item setSectionRCellsFormat([tbody|thead|tfoot], section_num, row_num, start_string, end_string)

=item setSectionRowFormat([tbody|thead|tfoot], section_num, row_num, start_string, end_string)  ** Deprecated **

Same as setRowFormat, but able to specify which section to act on.

=item setLastRow*

All of the setRow methods have a corresponding setLastRow method which 

does not accept the row_num parameter, but automatically applies

to the last row of the table.

NB.  Only works on the setRow* methods, not on the setSectionRow* methods.

=item getRowStyle(row_num)

Returns row's style attribute.

=item getSectionRowStyle([tbody|thead|tfoot], section_num, row_num)

Same as getRowStyle, but able to specify which section to act on.

=back

=head2 Output Methods

=over 4

=item getTable

Returns a string containing the HTML representation

of the table.

The same effect can also be achieved by using the object reference 

in a string scalar context.

For example...

	This code snippet:

		$table = new HTML::Table(2, 2);

		print '<p>Start</p>';

		print $table->getTable;

		print '<p>End</p>';

	would produce the same output as:

		$table = new HTML::Table(2, 2);

		print "<p>Start</p>$table<p>End</p>";

=item print

Prints HTML representation of the table to STDOUT

=back

=head1 CLASS VARIABLES

=head1 HISTORY

This module was originally created in 1997 by Stacy Lacy and whose last 

version was uploaded to CPAN in 1998.  The module was adopted in July 2000 

by Anthony Peacock in order to distribute a revised version.  This adoption 

took place without the explicit consent of Stacy Lacy as it proved impossible 

to contact them at the time.  Explicit consent for the adoption has since been 

received.

=head1 AUTHOR

Anthony Peacock, a.peacock@chime.ucl.ac.uk

Stacy Lacy (Original author)

=head1 CONTRIBUTIONS

Douglas Riordan <doug.riordan@gmail.com>

For get methods for Style attributes.

Jay Flaherty, fty@mediapulse.com

For ROW, COL & CELL HEAD methods. Modified the new method to allow hash of values.

John Stumbles, john@uk.stumbles.org

For autogrow behaviour of setCell, and allowing alignment specifications to be case insensitive

Arno Teunisse, Arno.Teunisse@Simac.nl

For the methods adding rules, styles and table alignment attributes.

Ville Skyttä, ville.skytta@iki.fi

For general fixes

Paul Vernaza, vernaza@stwing.upenn.edu

For the setLast... methods

David Link, dvlink@yahoo.com

For the sort method

Tommi Maekitalo, t.maekitalo@epgmbh.de

For adding the 'head' parameter to the new method and for adding the initialisation from an array ref 

to the new method.

Chris Weyl, cweyl@alumni.drew.edu

For adding the even/odd row class support.

=head1 COPYRIGHT

Copyright (c) 2000-2007 Anthony Peacock, CHIME.

Copyright (c) 1997 Stacy Lacy

This library is free software; you can redistribute it and/or

modify it under the same terms as Perl itself.

=head1 SEE ALSO

perl(1), CGI(3)

=cut

#-------------------------------------------------------

# Subroutine:  	new([num_rows, num_cols])

#            or new([-rows=>num_rows,

#                   -cols=>num_cols,

#                   -border=>border_width,

#                   -bgcolor=>back_colour,

#                   -width=>table_width,

#                   -spacing=>cell_spacing,

#                   -padding=>cell_padding]); 

# Author:       Stacy Lacy	

# Date:		30 Jul 1997

# Modified:     30 Mar 1998 - Jay Flaherty

# Modified:     13 Feb 2001 - Anthony Peacock

# Modified:     30 Aug 2002 - Tommi Maekitalo

# Modified:     23 Oct 2003 - Anthony Peacock (Version 2 new data structure)

# Modified:     25 May 2007 - Chris Weyl (even/odd row class support) 

#-------------------------------------------------------

sub new {

# Creates new table instance

my $type = shift;

my $class = ref($type) || $type;

my $self = {};

bless( $self, $class); 

# If paramter list is a hash (of the form -param=>value, ...)

if (defined $_[0] && $_[0] =~ /^-/) {

    my %flags = @_;

    $self->{border} = defined $flags{-border} && _is_validnum($flags{-border}) ? $flags{-border} : undef;

    $self->{align} = $flags{-align} || undef;

    $self->{rules} = $flags{-rules} || undef;

    $self->{style} = $flags{-style} || undef;

    $self->{class} = $flags{-class} || undef;

    $self->{bgcolor} = $flags{-bgcolor} || undef;

    $self->{background} = $flags{-background} || undef;

    $self->{width} = $flags{-width} || undef;

    $self->{cellspacing} = defined $flags{-spacing} && _is_validnum($flags{-spacing}) ? $flags{-spacing} : undef;

    $self->{cellpadding} = defined $flags{-padding} && _is_validnum($flags{-padding}) ? $flags{-padding} : undef;

    $self->{last_col} = $flags{-cols} || 0;

    $self->{evenrowclass} = $flags{-evenrowclass} || undef;

    $self->{oddrowclass} = $flags{-oddrowclass} || undef;

    if ($flags{-head})

    {

      $self->addRow(@{$flags{-head}});

      $self->setRowHead(1);

    }

    if ($flags{-data})

    {

      foreach (@{$flags{-data}})

      {

        $self->addRow(@$_);

      }

    }

	if ($self->{tbody}[0]->{last_row}) {

		$self->{tbody}[0]->{last_row} = $flags{-rows} if (defined $flags{-rows} && $self->{tbody}[0]->{last_row} < $flags{-rows});

	} else {

	    $self->{tbody}[0]->{last_row} = $flags{-rows} || 0;

	}

}

elsif (ref $_[0])

{

    # Array-reference [ ['row0col0', 'row0col1'], ['row1col0', 'row1col1'] ]

    $self->{tbody}[0]->{last_row} = 0;

    $self->{last_col} = 0;

    foreach (@{$_[0]})

    {

      $self->addRow(@$_);

    }

}

else # user supplied row and col (or default to 0,0)

{

    $self->{tbody}[0]->{last_row} = shift || 0;

    $self->{last_col} = shift || 0;

}

# Table Auto-Grow mode (default on)

$self->{autogrow} = 1;

return $self;

}	

#-------------------------------------------------------

# Subroutine:  	getTable

# Author:       Stacy Lacy

# Date:			30 July 1997

# Modified:     19 Mar 1998 - Jay Flaherty

# Modified:     13 Feb 2001 - Anthony Peacock

# Modified:		23 Oct 2001 - Terence Brown

# Modified:		05 Jan 2002 - Arno Teunisse

# Modified:		10 Jan 2002 - Anthony Peacock

# Modified:     23 Oct 2003 - Anthony Peacock (Version 2 new data structure)

# Modified:     25 May 2007 - Chris Weyl (add even/odd row class support)

# Modified:		10 Sept 2007 - Anthony Peacock

#-------------------------------------------------------

sub getTable {

	my $self = shift;

	my $html="";

	# this sub returns HTML version of the table object

	if ((! $self->{tbody}[0]{last_row}) || (! $self->{last_col})) {

		return ;  # no rows or no cols

	}

	# Table tag

	$html .="\n<table";

	$html .=" border=\"$self->{border}\"" if defined $self->{border};

	$html .=" cellspacing=\"$self->{cellspacing}\"" if defined $self->{cellspacing};

	$html .=" cellpadding=\"$self->{cellpadding}\"" if defined $self->{cellpadding};

	$html .=" width=\"$self->{width}\"" if defined $self->{width};

	$html .=" bgcolor=\"$self->{bgcolor}\"" if defined $self->{bgcolor};

	$html .=" background=\"$self->{background}\"" if defined $self->{background};

	$html .=" rules=\"$self->{rules}\"" if defined $self->{rules} ;		# add rules for table

	$html .=" align=\"$self->{align}\"" if defined $self->{align} ; 		# alignment of the table

	$html .=" style=\"$self->{style}\"" if defined $self->{style} ; 		# style for the table

	$html .=" class=\"$self->{class}\"" if defined $self->{class} ; 		# class for the table

	$html .=" $self->{attr}" if defined $self->{attr} ;		 		# user defined attribute string

	$html .=">\n";

	if (defined $self->{caption}) {

		$html .="<caption";

		$html .=" align=\"$self->{caption_align}\"" if (defined $self->{caption_align});

		$html .=">$self->{caption}</caption>\n";

	}

	# thead tag (if defined)

	if (defined $self->{thead}) {

		$html .= $self->getSection ( 'thead', 0 );

	}

	# TFOOT tag (if defined)

	if (defined $self->{tfoot}) {

		$html .= $self->getSection ( 'tfoot', 0 );

	}

	# Body sections

	my $num_sections = @{$self->{tbody}} - 1;

	for my $j ( 0..$num_sections ) {

		$html .= $self->getSection ( 'tbody', $j );

	}

   	# Close TABLE tag

   	$html .="</table>\n";

   	return ($html);

}

#-------------------------------------------------------

# Subroutine:  	getRow

# Author:       Anthony Peacock

# Date:			10 September 2007

# Description:  Gets the HTML to form a row, based on code taken from getTable

#-------------------------------------------------------

sub getRow {

	my $self = shift;

	my $section = lc(shift);

	my $sect_num = shift;

	my $row_num = shift;

	my $html="";

	# Print each row of the table   

	$html .="<tr" ;		

	# Set the row attributes (if any)

	$html .= ' bgcolor="' . $self->{$section}[$sect_num]->{rows}[$row_num]->{bgcolor} . '"' if defined $self->{$section}[$sect_num]->{rows}[$row_num]->{bgcolor};

	$html .= ' align="' . $self->{$section}[$sect_num]->{rows}[$row_num]->{align} . '"'  if defined $self->{$section}[$sect_num]->{rows}[$row_num]->{align};	

	$html .= ' valign="' . $self->{$section}[$sect_num]->{rows}[$row_num]->{valign} . '"'  if defined $self->{$section}[$sect_num]->{rows}[$row_num]->{valign} ;

	$html .= ' style="' . $self->{$section}[$sect_num]->{rows}[$row_num]->{style} . '"'  if defined $self->{$section}[$sect_num]->{rows}[$row_num]->{style} ;

	$html .= defined $self->{$section}[$sect_num]->{rows}[$row_num]->{class}             ? ' class="' . $self->{$section}[$sect_num]->{rows}[$row_num]->{class} . '"'  

              : defined $self->{evenrowclass} && ($row_num % 2 == 0) ? ' class="' .  $self->{evenrowclass} . '"'

              : defined $self->{oddrowclass}  && ($row_num % 2 == 1) ? ' class="' .  $self->{oddrowclass} . '"'

              :                                                  q{};

	$html .= ' nowrap="' . $self->{$section}[$sect_num]->{rows}[$row_num]->{nowrap} . '"'  if defined $self->{$section}[$sect_num]->{rows}[$row_num]->{nowrap} ;

	$html .= " $self->{$section}[$sect_num]->{rows}[$row_num]->{attr}" if defined $self->{$section}[$sect_num]->{rows}[$row_num]->{attr} ;

	$html .= ">" ; 	# Closing tr tag

	my $j;

	for ($j=1; $j <= ($self->{last_col}); $j++) {

		if (defined $self->{$section}[$sect_num]->{rows}[$row_num]->{cells}[$j]->{colspan} && $self->{$section}[$sect_num]->{rows}[$row_num]->{cells}[$j]->{colspan} eq "SPANNED"){

			$html.="<!-- spanned cell -->";

			next

		}

		# print cell

		# if head flag is set print <th> tag else <td>

		if (defined $self->{$section}[$sect_num]->{rows}[$row_num]->{cells}[$j]->{head}) {

			$html .="<th";

		} else { 

			$html .="<td";

		}

		# if alignment options are set, add them in the cell tag

		$html .=' align="' . $self->{$section}[$sect_num]->{rows}[$row_num]->{cells}[$j]->{align} . '"'

			if defined $self->{$section}[$sect_num]->{rows}[$row_num]->{cells}[$j]->{align};

		$html .=" valign=\"" . $self->{$section}[$sect_num]->{rows}[$row_num]->{cells}[$j]->{valign} . "\""

			if defined $self->{$section}[$sect_num]->{rows}[$row_num]->{cells}[$j]->{valign};

		# apply custom height and width to the cell tag

		$html .=" width=\"" . $self->{$section}[$sect_num]->{rows}[$row_num]->{cells}[$j]->{width} . "\""

			if defined $self->{$section}[$sect_num]->{rows}[$row_num]->{cells}[$j]->{width};

		$html .=" height=\"" . $self->{$section}[$sect_num]->{rows}[$row_num]->{cells}[$j]->{height} . "\""

			if defined $self->{$section}[$sect_num]->{rows}[$row_num]->{cells}[$j]->{height};

		# apply background color if set

		$html .=" bgcolor=\"" . $self->{$section}[$sect_num]->{rows}[$row_num]->{cells}[$j]->{bgcolor} . "\""

			if defined $self->{$section}[$sect_num]->{rows}[$row_num]->{cells}[$j]->{bgcolor};

		# apply style if set

		$html .=" style=\"" . $self->{$section}[$sect_num]->{rows}[$row_num]->{cells}[$j]->{style} . "\""

			if defined $self->{$section}[$sect_num]->{rows}[$row_num]->{cells}[$j]->{style};

		# apply class if set