Subversion Repositories DevTools

<%@LANGUAGE="VBSCRIPT"%>

<%

'=====================================================

'|                                                   |

'|                   wAddProc                        |

'|                                                   |

'=====================================================

%>

<%

Option explicit

Response.Expires = 0

%>

<!--#include file="common/conf.asp"-->

<!--#include file="common/globals.asp"-->

<!--#include file="common/formating.asp"-->

<!--#include file="common/qstr.asp"-->

<!--#include file="common/common_subs.asp"-->

<!--#include file="common/_popup_window_common.asp"-->

<!--#include file="common/_form_window_common.asp"-->

<%

'------------ ACCESS CONTROL ------------------

%>

<!--#include file="_access_control_login.asp"-->

<!--#include file="_access_control_general.asp"-->

<%

'------------ VARIABLE DEFINITION -------------

Dim rsQry

Dim sMessage

Dim GBE_MACHTYPE

Dim GBE_MACHCLASS

Dim Query_String

'------------ CONSTANTS DECLARATION -----------

'------------ VARIABLE INIT -------------------

sMessage = NULL

Set objFormCollector = CreateObject("Scripting.Dictionary")

'------------ CONDITIONS ----------------------

'----------------------------------------------

%>

<%

' Populate a form selection with Machine Classes

'   sbm_id - Select this bm_id

sub getMachineClassOptions( sbm_id )

    Dim rsQry

    Dim bm_id, bm_name, selected

    Response.write("<option value="""">- Select One -</option>")

    Set rsQry = OraDatabase.DbCreateDynaset( "SELECT * FROM BUILD_MACHINES BM ORDER BY BM_NAME", ORADYN_DEFAULT )

    While (NOT rsQry.BOF) AND (NOT rsQry.EOF)

        bm_id = rsQry("BM_ID")

        bm_name = rsQry("BM_NAME")

        If bm_id = sbm_id Then

            selected = " selected"

        Else

            selected = ""

        End If

        %>

          <option value="<%=bm_id%>"<%=selected%>><%=bm_name%></option>

        <%

        rsQry.MoveNext()

    Wend

    rsQry.Close()

end sub

%>

<%

'------------ RUN BEFORE PAGE RENDER ----------

If CBool(Request("action")) Then

   ' Update an existing entry

   If Request("gbe_id") <> "" Then

      Query_String = _

      "SELECT * FROM GBE_MACHTYPE WHERE GBE_ID <> " & Request("gbe_id") & " AND GBE_VALUE = '"& Request("GBE_MACHTYPE") &"'"

      Set rsQry = OraDatabase.DbCreateDynaset( Query_String, cint(0))

      If rsQry.RecordCount = 0 Then

         OraDatabase.Parameters.Add "GBE_ID",       Request("GBE_ID"),       ORAPARM_INPUT, ORATYPE_NUMBER

         OraDatabase.Parameters.Add "GBE_MACHTYPE", Request("GBE_MACHTYPE"), ORAPARM_INPUT, ORATYPE_VARCHAR2

         OraDatabase.Parameters.Add "GBE_MACHCLASS", Request("GBE_MACHCLASS"), ORAPARM_INPUT, ORATYPE_VARCHAR2

         objEH.TryORA ( OraSession )

         On Error Resume Next

         OraDatabase.ExecuteSQL _

         "BEGIN  PK_BUILDAPI.UPDATE_GBE_MACHTYPE(:GBE_ID, :GBE_MACHTYPE, :GBE_MACHCLASS);  END;"

         objEH.CatchORA ( OraSession )

         OraDatabase.Parameters.Remove "GBE_MACHCLASS"

         OraDatabase.Parameters.Remove "GBE_MACHTYPE"

         OraDatabase.Parameters.Remove "GBE_ID"

         If objEH.Finally Then

            Call OpenInParentWindow ("admin_gbe_machtype.asp")

            Call CloseWindow()

         End If

      Else

         sMessage = "A Machine of that name already exists"

      End If

      rsQry.Close

      Set rsQry = nothing

   Else

      ' Create a new entry

      '

      Query_String = _

      "SELECT * FROM GBE_MACHTYPE WHERE GBE_VALUE = '"& Request("GBE_MACHTYPE") &"'"

      Set rsQry = OraDatabase.DbCreateDynaset( Query_String, cint(0))

      If rsQry.RecordCount = 0 Then

         OraDatabase.Parameters.Add "GBE_VALUE",   Request("GBE_MACHTYPE"),    ORAPARM_INPUT, ORATYPE_VARCHAR2

         OraDatabase.Parameters.Add "GBE_CLASS",   Request("GBE_MACHCLASS"),    ORAPARM_INPUT, ORATYPE_VARCHAR2

         objEH.TryORA ( OraSession )

         On Error Resume Next

         OraDatabase.ExecuteSQL _

         "BEGIN  PK_BUILDAPI.ADD_GBE_MACHTYPE(:GBE_VALUE,:GBE_CLASS);  END;"

         objEH.CatchORA ( OraSession )

         OraDatabase.Parameters.Remove "GBE_VALUE"

         OraDatabase.Parameters.Remove "GBE_CLASS"

         If objEH.Finally Then

            Call OpenInParentWindow ("admin_gbe_machtype.asp")

            Call CloseWindow()

         End If

      Else

         sMessage = "A Machine of that name already exists"

      End If

      rsQry.Close

      Set rsQry = nothing

   End If

End If

'----------------------------------------------

%>

<html>

<head>

<title>Release Manager</title>

<link rel="shortcut icon" href="<%=FavIcon%>"/>

<meta HTTP-EQUIV="Pragma" CONTENT="no-cache">

<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">

<link href="images/release_manager_style.css?ver=<%=VixVerNum%>" rel="stylesheet" type="text/css">

<script language="JavaScript" src="images/common.js?ver=<%=VixVerNum%>"></script>

</head>

<body background="images/bg_bage_0.gif" leftmargin="0" topmargin="0" onLoad="self.focus();FormName.GBE_MACHTYPE.focus();">

<div id='divProgressBar' class='vixSpinner' style='visibility:hidden;'></div>

<table class="full_table" border="0" cellspacing="0" cellpadding="10">

   <tr>

      <td bgcolor="#FFFFFF" class="body_txt">

        Add or Edit a new GBE_MACHTYPE.

      </td>

   </tr>

   <%

   '-- FROM START --------------------------------------------------------------------------------------------------------------

   objFormComponent.FormName = "FormName"

   objFormComponent.FormClass = "form_tight"

   objFormComponent.Action = ScriptName

   objFormComponent.OnSubmit = "MM_validateForm(""GBE_MACHTYPE"",""Machine Type"",""RisCleanStrinLength4:"",""GBE_MACHCLASS"",""Machine Class"",""R"");return document.MM_returnValue"

   Call objFormComponent.FormStart()

   %>

   <tr>

      <td>

         <!-- NEW PRODUCT +++++++++++++++++++++++++++++++++++++++++++++++ -->

         <%Call Messenger ( sMessage , 1, "100%" )%>

         <!-- MESSAGE +++++++++++++++++++++++++++++++++++++++++++++++++++ -->

         <!--#include file="messages/_msg_inline.asp"-->

         <table width="50%" border="0">

            <%

            GBE_MACHTYPE = Request("GBE_MACHTYPE")

            GBE_MACHCLASS = Request("GBE_MACHCLASS")

            If Request("gbe_id") <> "" AND GBE_MACHTYPE = "" Then

               %>

               <input type="hidden" name="gbe_id" value="<%=Request("gbe_id")%>">

               <%

               Dim rsTemp

               Query_String = "SELECT * FROM GBE_MACHTYPE MT, BUILD_MACHINES BM WHERE MT.BM_ID=BM.BM_ID(+) AND GBE_ID = "& Request("gbe_id")

               Set rsTemp = OraDatabase.DbCreateDynaset( Query_String, cint(0))

               GBE_MACHTYPE = rsTemp("gbe_value")

               GBE_MACHCLASS = rsTemp("BM_ID")

               rsTemp.Close()

               Set rsTemp = Nothing

            End   If

            %>

            <tr>

               <td><span class="body_txt nowrap">Machine Type</span></td>

               <td><input name="GBE_MACHTYPE" type="text" class="body_txt" value="<%=GBE_MACHTYPE%>"></td>

            </tr>

            <tr>

               <td><span class="body_txt nowrap">Machine Class</span></td>

               <td>

                    <select id="FRmachClass"  name="GBE_MACHCLASS" class="form_item">

                    <%getMachineClassOptions(GBE_MACHCLASS)%>

                    </select>

               </td>

            </tr>

         </table>

      </td>

   </tr>

   <tr>

      <td bgcolor="#FFFFFF">

         <table class=full_table >

            <tr>

               <td align="right">

                  <input name="btn" type="submit" class="form_btn" value="Add/Update">

                  <input name="btn" type="reset" class="form_btn" value="Cancel" onclick="parent.closeIFrame();">

               </td>

            </tr>

         </table>

      </td>

   </tr>

   <%=objPMod.ComposeHiddenTags()%>

   <input type="hidden" name="action" value="true">

   <%

   Call objFormComponent.FormEnd()

   '-- FROM END ----------------------------------------------------------------------------------------------------------------

   %>

</table>

</body>

</html>

<%

'------------ RUN AFTER PAGE RENDER -----------

Set objFormCollector = Nothing

'----------------------------------------------

Call Destroy_All_Objects

%>